Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>

<%

'=====================================================

'|                                                   |

'|				    	New Release				     |

'|                                                   |

'=====================================================

%>

<%

Option explicit

' Good idea to set when using redirect

Response.Expires = 0	' always load the page, dont store

%>

<!--#include file="common/conf.asp"-->

<!--#include file="common/globals.asp"-->

<!--#include file="common/formating.asp"-->

<!--#include file="common/qstr.asp"-->

<!--#include file="common/common_subs.asp"-->

<!--#include file="common/_rtree_common.asp"-->

<!--#include file="common/_form_window_common.asp"-->

<%

' Set rfile parameter. This is a return page after Login

Call objPMod.StoreParameter ( "rfile", "rtree.asp" )

objPMod.PersistInQryString("proj_id")

objPMod.PersistInQryString("branch")

'------------ ACCESS CONTROL ------------------

%>

<!--#include file="_access_control_login.asp"-->

<!--#include file="_access_control_general.asp"-->

<!--#include file="_access_control_project.asp"-->

<%

'------------ Variable Definition -------------

Dim objSortHelper

Dim rsQry

Dim parProjId

Dim isSelectDisabled

'------------ Constants Declaration -----------

'------------ Variable Init -------------------

parProjId = Request("proj_id")

'----------------------------------------------

%>

<%

'--------------------------------------------------------------------------------------------------------------------------

Sub GetWipReleaseList ( nProjId )

	Dim rsQry, query

	OraDatabase.Parameters.Add "PROJ_ID", 	nProjId,		ORAPARM_INPUT, ORATYPE_NUMBER 

	Set rsQry = OraDatabase.DbCreateDynaset( GetQuery ("WipReleaseList.sql"), ORADYN_DEFAULT )

	OraDatabase.Parameters.Remove "PROJ_ID"

	If rsQry.RecordCount < 1 Then

		Response.write "No recent releases found."

	End If

	While (NOT rsQry.BOF) AND (NOT rsQry.EOF)

		Response.write "<a href='form_add_release.asp?source_rtag_id="& rsQry("rtag_id") &"&"& objPMod.ComposeURL() &"' class='body_link'>"&_

					    ReleaseIcon( rsQry("official") ) & rsQry("rtag_name").Value &" ["& rsQry("version") &"]</a><br>"

		rsQry.MoveNext

	WEnd

	rsQry.Close

	Set rsQry = Nothing

End Sub

'--------------------------------------------------------------------------------------------------------------------------

Function GetReleaseList ( nProjId, nRtagId )

	Dim rsQry, Selected, aComboItems, lastItem, i

	OraDatabase.Parameters.Add "PROJ_ID", nProjId,	ORAPARM_INPUT, ORATYPE_NUMBER

	OraDatabase.Parameters.Add "RTAG_ID", 	nRtagId,	ORAPARM_INPUT, ORATYPE_NUMBER 

	Set rsQry = OraDatabase.DbCreateDynaset( GetQuery("ReleasesCombo.sql"), ORADYN_DEFAULT )

	OraDatabase.Parameters.Remove "PROJ_ID"

	OraDatabase.Parameters.Remove "RTAG_ID"

	If ((NOT rsQry.BOF) AND (NOT rsQry.EOF)) Then

		aComboItems = rsQry.GetRows()

	Else

		Err.Raise 8, "Sub GetReleaseList", "Empty record set returned. nProjId="& nProjId

	End If

	rsQry.Close

	Set rsQry = Nothing

	'-- Return Combo Items Array

	GetReleaseList = aComboItems

End Function

'--------------------------------------------------------------------------------------------------------------------------

Function GetProjectList ( nProjId )

	Dim rsQry, Selected, aComboItems, lastItem, i

	OraDatabase.Parameters.Add "PROJ_ID", nProjId,	ORAPARM_INPUT, ORATYPE_NUMBER

	Set rsQry = OraDatabase.DbCreateDynaset( GetQuery("ProjectsCombo.sql"), ORADYN_DEFAULT )

	OraDatabase.Parameters.Remove "PROJ_ID"

	If ((NOT rsQry.BOF) AND (NOT rsQry.EOF)) Then

		aComboItems = rsQry.GetRows()

	Else

		Err.Raise 8, "Sub GetProjectList", "Empty record set returned. nProjId="& nProjId

	End If

	rsQry.Close

	Set rsQry = Nothing

	'-- Alter combo item link column to work with OnChange javascript

	lastItem = Ubound( aComboItems, 2 )

	For i = 0 To lastItem

		aComboItems(0, i) = ScriptName &"?from_proj_id="& aComboItems(0, i) &"&"& objPMod.ComposeURL()

	Next

	'-- Return Combo Items Array

	GetProjectList = aComboItems

End Function

'--------------------------------------------------------------------------------------------------------------------------

%>

<%

'------------ RUN BEFORE PAGE RENDER ----------

'-- Redirect if known from_bom_id

If Request("rtag_id_list") <> "" Then

	Call OpenInWindow ( "form_add_release.asp?source_rtag_id="& Request("rtag_id_list") &"&"& objPMod.ComposeURL() )

End If

'----------------------------------------------

%>

<html>

<head>

<title>Release Manager</title>

<link rel="shortcut icon" href="<%=FavIcon%>"/>

<meta HTTP-EQUIV="Pragma" CONTENT="no-cache">

<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">

<link rel="stylesheet" href="images/release_manager_style.css" type="text/css">

<link rel="stylesheet" href="images/navigation.css" type="text/css">

<script language="JavaScript" src="images/common.js"></script>

<!--#include file="_jquery_includes.asp"-->

<!-- DROPDOWN MENUS -->

<!--#include file="_menu_def.asp"-->

<script language="JavaScript1.2" src="images/popup_menu.js"></script>

</head>

<body bgcolor="#FFFFFF" text="#000000" leftmargin="0" topmargin="0" >

<!-- HEADER -->

<!--#include file="_header.asp"-->

<!-- BODY ---->

<table width="100%" border="0" cellspacing="0" cellpadding="0">

<%

'-- FROM START ---------------------------------------------------------------------------------------------------------

objFormComponent.FormName = "FormName"

objFormComponent.Action = "form_add_release.asp?proj_id="&Request("proj_id")

Call objFormComponent.FormStart()

%>

  <tr> 

    <td width="1" background="images/bg_home_orange.gif" valign="top">

	</td>

	<td width="100%" rowspan="2" align="center" valign="top" bgcolor="#EEEFEF"><table width="10" border="0" cellspacing="0" cellpadding="0">

      <tr>

        <td width="1%"></td>

        <td width="100%">

          <table width="100%" border="0" cellspacing="0" cellpadding="0">

            <tr>

              <td nowrap class="form_ttl">NEW RELEASE </td>

              <td align="right" valign="bottom"></td>

            </tr>

        </table></td>

        <td width="1%"></td>

      </tr>

      <tr>

        <td align="left" valign="top" background="images/lbox_bg_blue.gif"><img src="images/lbox_tl_cnr_b.gif" width="13" height="13"></td>

        <td background="images/lbox_bg_blue.gif" class="lbox_ttl_w"><img src="images/h_trsp_dot.gif" width="600" height="15"></td>

        <td align="right" valign="top"  background="images/lbox_bg_blue.gif"><img src="images/lbox_tr_cnr_b.gif" width="13" height="13"></td>

      </tr>

      <tr>

        <td bgcolor="#FFFFFF"><img src="images/h_trsp_dot.gif" width="10" height="100"></td>

        <td bgcolor="#FFFFFF" valign="top">

          <table width="100%"  border="0" cellspacing="10" cellpadding="0">

            <tr>

              <td width="33%" valign="top" class="body_txt"> <strong>Create New</strong><br><br>

                  <a href="form_add_release.asp?NEXT=OK&<%=objPMod.ComposeURL()%>" class="body_link" title="Create release without any contents."><img src="images/i_rtag_new.gif" width="17" height="15" hspace="5" vspace="3" border="0" align="absmiddle">Blank </a><br>

                  <br>

              </td>

              <td width="1" background="images/bg_bage_2.gif"><img src="images/spacer.gif" width="1" height="250"></td>

              <td nowrap width="34%" valign="top" class="body_txt"> <strong>Create from Recent </strong><br><br>

                  <%Call GetWipReleaseList ( parProjId )%>

              </td>

              <td width="1" background="images/bg_bage_2.gif"><img src="images/spacer.gif" width="1" height="1"></td>

              <td width="33%" valign="top" class="body_txt" nowrap> <strong>Create From Other</strong><br>

                  <br>

              	<%=objFormComponent.Combo ( "from_proj_id", GetProjectList( Request("from_proj_id") ), TRUE, "class='form_ivalue' onChange=""MM_jumpMenu('parent',this,0)"" " )%><br>

				<%

				isSelectDisabled = "disabled"

				If Request("from_proj_id") <> "" Then 

					Response.write objFormComponent.Combo ( "source_rtag_id", GetReleaseList( Request("from_proj_id"), Request("source_rtag_id") ), FALSE, "class='form_ivalue' " )

					Response.write "<br>"

					isSelectDisabled = ""

				End If

				%>				

				  <%=objFormComponent.SubmitButton ( "Select", "class='form_ivalue' "& isSelectDisabled )%>

				  </td>

            </tr>

          </table>

        </td>

        <td background="images/lbox_bgside_white.gif">&nbsp;</td>

      </tr>

	  <tr>

        <td background="images/bg_action_norm.gif" ></td>

        <td align="right" background="images/bg_action_norm.gif" ><input type="reset" name="btn" value="Cancel" class="form_btn" onClick="history.back();"></td>

        <td background="images/bg_action_norm.gif" ><img src="images/h_trsp_dot.gif" width="5" height="30"></td>

      </tr>

      <tr>

        <td background="images/lbox_bg_blue.gif" valign="bottom"><img src="images/lbox_bl_cnr_b.gif" width="13" height="13"></td>

        <td background="images/lbox_bg_blue.gif"></td>

        <td background="images/lbox_bg_blue.gif" valign="bottom" align="right"><img src="images/lbox_br_cnr_b.gif" width="13" height="13"></td>

      </tr>

    </table>

	<!-- ACTION BUTTONS ---------------------------------------------->

	<!-- ACTION BUTTONS END  ------------------------------------------></td>

	<td width="1" valign="top"><img src="images/h_trsp_dot.gif" width="1" height="1"></td>

  </tr>

  <tr> 

    <td valign="bottom" align="center" background="images/bg_home_orange.gif"><img src="images/img_vtree.gif" width="86" height="99" vspace="20" hspace="30"></td>

    <td background="images/bg_lght_gray.gif" valign="top"><img src="images/h_trsp_dot.gif" width="1" height="500"></td>

  </tr>

 <%

Call objFormComponent.FormEnd()

'-- FROM END ----------------------------------------------------------------------------------------------------------------

%>	

</table>

<!-- FOOTER -->

<!--#include file="_footer.asp"-->

</body>

</html>