Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>

<%

Option explicit

Response.Expires = 0   ' always load the page, dont store

%>

<%

'=====================================================

'   _wform_change_in_manifest.asp

'=====================================================

%>

<!--#include file="common/conf.asp"-->

<!--#include file="common/globals.asp"-->

<!--#include file="common/qstr.asp"-->

<!--#include file="common/common_subs.asp"-->

<!--#include file="common/common_dbedit.asp"-->

<!--#include file="common/_popup_window_common.asp"-->

<%

'------------ ACCESS CONTROL ------------------

%>

<!--#include file="_access_control_login.asp"-->

<!--#include file="_access_control_general.asp"-->

<!--#include file="_access_control_project.asp"-->

<%

'------------ Variable Definition -------------

Dim parPv_id

Dim sMessage, sMessageType

Dim bCanEdit, submitDisabled

'------------ Constants Declaration -----------

'------------ Variable Init -------------------

Set pkgInfoHash = CreateObject("Scripting.Dictionary")

parPv_id = QStrPar("pv_id")

sMessage = NULL

sMessageType = 3

submitDisabled = ""

bCanEdit = canActionControlInProject("ConfigureRelease") OR canActionControlInProject("EditNonCriticalInfoForLockedPackage") OR canActionControlInProject ("EditInManifest") OR canActionControl("MSMaintainer")

'----------------------------------------------

%>

<%

'------------------------------------------------------------------------------------------------------------------------------------------

'

' Add a line of text to the System Message

'   eLevel - 1 == Critical, 2==Warning, 3==Note

Sub sMessageAdd(eLevel, text)

    If NOT isNull(sMessage) Then

        sMessage = sMessage & "<br>"

    End If

    sMessage = sMessage & text

    If eLevel < sMessageType  Then

        sMessageType = eLevel

    End If

End Sub

Sub Get_Pkg_Info_With_Data ( NNpv_id )

   Dim rsTemp, Query_String

   Query_String = _

   " SELECT pkg.pkg_name, pv.pkg_version, NVL(rc.IN_MANIFEST, 'N') as inManifest"&_

   "   FROM packages pkg, package_versions pv, Release_Content rc"&_

   "  WHERE pkg.pkg_id = pv.pkg_id"&_

   "    AND pv.pv_id = "& NNpv_id &_

   "    AND rc.pv_id(+) = pv.pv_id" &_

   "    AND rtag_id = " & DB_RTAG_ID

   Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))

   If ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF)) Then

      pkgInfoHash.Add "pkg_name", (rsTemp.Fields("pkg_name"))

      pkgInfoHash.Add "pkg_version", (rsTemp.Fields("pkg_version"))

      pkgInfoHash.Add "inManifest", (rsTemp.Fields("inManifest"))

   End If

   rsTemp.Close

   Set rsTemp = nothing

End Sub

Sub Update_Data ( NNpv_id, cState )

   Dim rsTemp, Query_String, sComments

   Dim bUpdated

   '-- Update database to change the eRef

   objEH.TryORA ( OraSession )

   On Error Resume Next

    Query_String = "Select IN_MANIFEST from Release_Content where rtag_id = " & DB_RTAG_ID & " AND pv_id = " & NNpv_id

    Set rsTemp = OraDatabase.CreateDynaset( Query_String, cint(0))

    Dim Data: Data = rsTemp("IN_MANIFEST")

    If IsNull(Data) Then Data = "N"

    cState = Iif( cState = 1 ,"Y", "N")

    Scomments = cState

    bUpdated = ( UCase(cState) <> UCase( Data ) )

    If bUpdated Then

        rsTemp.Edit

        rsTemp.Fields("IN_MANIFEST").Value = UCase(cState)

        rsTemp.Update

        '   Indicate change to the build system

        '   May be overkill - perhaps a seperate field

        OraDatabase.ExecuteSQL ("BEGIN PK_RELEASE.SET_RELEASE_MODIFIED("& DB_RTAG_ID & "); END; ")

    End If

   objEH.CatchORA ( OraSession )

   On Error Goto 0

   If bUpdated AND objEH.LastOraFailed = FALSE Then

        '-- Log the change

        sComments = "Set: "& sComments

        call Log_Action ( NNpv_id, "inManifest", sComments )

   End If

   rsTemp.Close

   Set rsTemp = nothing

End Sub

%>

<%

'Process submition

If CBool(QStrPar("action")) AND objAccessControl.UserLogedIn Then

   Call Update_Data ( parPv_id, Request("inManifest") )

   If isNULL(sMessage) AND NOT objEH.LastOraFailed Then

       Call ReloadParentWindow

       Call CloseWindow

   End If

End If

%>

<%

Call Get_Pkg_Info_With_Data ( parPv_id )

If NOT bCanEdit Then

    Call sMessageAdd(1, "User does not have permission to edit this field")

    submitDisabled = " disabled"

End If

%>

<html>

<head>

<title>Release Manager</title>

<link rel="shortcut icon" href="<%=FavIcon%>"/>

<meta HTTP-EQUIV="Pragma" CONTENT="no-cache">

<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">

<link rel="stylesheet" href="images/release_manager_style.css?ver=<%=VixVerNum%>" type="text/css">

<link rel="stylesheet" href="images/navigation.css?ver=<%=VixVerNum%>" type="text/css">

<script language="JavaScript" src="images/tipster.js?ver=<%=VixVerNum%>"></script>

<script language="JavaScript" src="images/_help_tips.js?ver=<%=VixVerNum%>"></script>

<script language="JavaScript" src="images/common.js?ver=<%=VixVerNum%>"></script>

</head>

<body bgcolor="#FFFFFF" text="#000000" leftmargin="0" topmargin="0" onload="self.focus();">

<form name="chowner" method="post" action="<%=scriptName%>" class="form_tight">

  <table border="0" cellspacing="0" cellpadding="2" width="100%">

    <tr>

      <td valign="top" nowrap colspan="3" class="wform_ttl" background="images/bg_form_lightgray.gif">

         <!-- MESSAGE +++++++++++++++++++++++++++++++++++++++++++++++++++ -->

         <%Call Messenger ( sMessage , sMessageType, "100%" )%>

         <!-- MESSAGE +++++++++++++++++++++++++++++++++++++++++++++++++++ -->

         <!--#include file="messages/_msg_inline.asp"-->

        <table width="100%" border="0" cellspacing="1" cellpadding="2">

          <tr>

            <td width="1%" nowrap class="form_field" background="images/bg_form_lightbluedark.gif">Package</td>

            <td nowrap width="100%" background="images/bg_form_lightbluedark.gif" class="form_txt">

              <%=pkgInfoHash.Item ("pkg_name") &" "& pkgInfoHash.Item ("pkg_version")%></td>

          </tr>

          <tr>

            <td width="1%" nowrap class="form_field" background="images/bg_form_lightbluedark.gif">External Reference</td>

            <%

            Dim FRinManifestYES, FRinManifestNO

            If pkgInfoHash.Item ("inManifest") = "Y" Then

                FRinManifestYES = "checked"

            Else

                FRinManifestNO = "checked"

            End If

            %>

            <td nowrap width="100%" class="form_txt" background="images/bg_form_lightbluedark.gif">

                  &nbsp;Yes<input name="inManifest" type="radio" value="1" <%=FRinManifestYES%> <%=submitDisabled%>>

                  &nbsp;No <input name="inManifest" type="radio" value="0" <%=FRinManifestNO%> <%=submitDisabled%>>

            </td>

          </tr>

        </table>

      </td>

    </tr>

    <tr>

      <td align="right">

        <input type="submit" name="btn" value="Update" class="form_btn_comp" <%=submitDisabled%>>

        <input type="reset" name="btn" value="Cancel" class="form_btn_comp" onclick="parent.closeIFrame();">

        <input type="hidden" name="pv_id" value="<%=parPv_id%>">

        <input type="hidden" name="rtag_id" value="<%=parRtag_id%>">

        <input type="hidden" name="action" value="true">

      </td>

    </tr>

  </table>

</form>

</body>

</html>

<!-- DESTRUCTOR ------->

<!--#include file="common/destructor.asp"-->