Subversion Repositories DevTools

<%

'=====================================================

'                MENU DEFINITION

'=====================================================

%>

<%

'------------ CONSTANTS -----------------------

Const MenuHeaderDefined = 1

Const LMENU_TICK = "<img src=""images/i_boxtick_on.gif"" width=""13"" height=""13"" border=""0"" vspace=""2"" align=""absmiddle"">"

Const LMENU_BLANK = "<img src=""images/spacer.gif"" width=""13"" height=""13"" border=""0"" vspace=""2"" align=""absmiddle"">"

'------------ Variable Definition -------------

Dim TABarray1, TABarray2, TABarray3, TABarray4, TABarray5, TABarray5D, TABarray6, TABarray6D

Dim ppClick

Dim imgDependenciesIcon, imgReleaseNotesIcon, imgPatchesIcon

Dim ReleaseMode

'-- GLOBAL VARIABLES --------------------------

imgDependenciesIcon = "<img src='images/i_dependency.gif' border='0' align='absmiddle' hspace='3'>"

imgReleaseNotesIcon = "<img src='images/i_release_note.gif' border='0' align='absmiddle' hspace='3'>"

imgPatchesIcon = "<img src='images/i_patch_small.gif' border='0' align='absmiddle' hspace='3'>"

' Used for cancel button history

If Request("click") <> "" Then

   ppClick = Request("click")

Else

   ppClick = 1

End If

ReleaseMode = GetReleaseMode( Request("rtag_id") )

'----------------------------------------------

If IsObject(pkgInfoHash) Then

   If IsNull(pkgInfoHash.Item ("is_patch")) Then

      If CInt(pkgInfoHash.Item ("base_view_id")) = enumBASE_VIEW_PRODUCTS  OR CInt(pkgInfoHash.Item ("base_view_id")) = enumAUTOPRODUCTS_BASE_VIEW_ID Then

         ' Tab for PRODUCTS

         TABarray1 = Array ( imgDependenciesIcon &"Dependencies@dependencies.asp?"& Persists_Query_String( Empty ), _

                             "Runtime@runtime_dependencies.asp?"& Persists_Query_String( Empty ), _

                             "Used by@used_by.asp?"& Persists_Query_String( Empty ), _

                             "Processes@process_dependencies.asp?"& Persists_Query_String( Empty ), _

                             imgPatchesIcon &"Patches@patches.asp?"& Persists_Query_String( Empty ), _

                             imgReleaseNotesIcon &"Release Notes@fixed_issues.asp?"& Persists_Query_String( Empty ), _

                             "Documentation@documentation.asp?" & Persists_Query_String( Empty ), _

                             "Files and Folders@files_and_folders.asp?" & Persists_Query_String( Empty ), _

                             "Action Log@action_log.asp?"& Persists_Query_String( Empty ), _

                             "Unit Test@unit_test_log.asp?"& Persists_Query_String( Empty ), _

                             "Notifications@notifications.asp?"& Persists_Query_String( Empty ) )

      Else

         ' Tabs for other packages

         TABarray1 = Array ( imgDependenciesIcon &"Dependencies@dependencies.asp?"& Persists_Query_String( Empty ), _

                             "Runtime@runtime_dependencies.asp?"& Persists_Query_String( Empty ), _

                             "Used by@used_by.asp?"& Persists_Query_String( Empty ), _

                             "Processes@process_dependencies.asp?"& Persists_Query_String( Empty ), _

                             imgPatchesIcon &"Patches@patches.asp?"& Persists_Query_String( Empty ), _

                             imgReleaseNotesIcon &"Release Notes@fixed_issues.asp?"& Persists_Query_String( Empty ), _

                             "Documentation@documentation.asp?" & Persists_Query_String( Empty ), _

                             "Files and Folders@files_and_folders.asp?" & Persists_Query_String( Empty ), _

                             "Action Log@action_log.asp?"& Persists_Query_String( Empty ), _

                             "Unit Test@unit_test_log.asp?"& Persists_Query_String( Empty ) , _

                             "Notifications@notifications.asp?"& Persists_Query_String( Empty ) )

      End If

   Else

      ' Tabs for Patches

      TABarray1 = Array ( imgDependenciesIcon &"Dependencies@dependencies.asp?pv_id="& Request("pv_id") &"&rtag_id="& Request("rtag_id"), _

                          "Used by@used_by.asp?pv_id="& Request("pv_id") &"&rtag_id="& Request("rtag_id"), _

                          imgReleaseNotesIcon &"Release Notes@fixed_issues.asp?pv_id="& Request("pv_id") &"&rtag_id="& Request("rtag_id"), _

                          "Files and Folders@files_and_folders.asp?" & Persists_Query_String( Empty ), _

                          "Action Log@action_log.asp?pv_id="& Request("pv_id") &"&rtag_id="& Request("rtag_id"))

   End If

    ' Add a debug tab to show internal data

    If (IsEmpty(Application("LiveSystem"))) OR canActionControl("MSMaintainer") Then

        ReDim Preserve TABarray1(UBound(TABarray1) + 1)

        TABarray1(UBound(TABarray1)) = "Debug@pvdata.asp?"& Persists_Query_String( Empty )

    End If

End If

' Tabs for Import / Export Dependencies

TABarray2 = Array ( "JATS style@form_update_jats_dependencies.asp?click="& CInt(ppClick) + 1 &"&pv_id="& Request("pv_id") &"&rtag_id="& Request("rtag_id"), _

                    "ANT-using style@form_update_ant_dependencies.asp?click="& CInt(ppClick) + 1 &"&pv_id="& Request("pv_id") &"&rtag_id="& Request("rtag_id"))

TABarray3 = Array ( "JATS style@form_export_jats_dependencies.asp?pv_id="& Request("pv_id") &"&rtag_id="& Request("rtag_id"), _

                    "ClearCase style@form_export_clearcase_dependencies.asp?pv_id="& Request("pv_id") &"&rtag_id="& Request("rtag_id"), _

                    "ANT-using style@form_export_ant_dependencies.asp?pv_id="& Request("pv_id") &"&rtag_id="& Request("rtag_id"))

TABarray4 = Array ( "Details@_wform_issues_details.asp?iss_db="& Request("iss_db") &"&iss_id="& Request("iss_id") &"&iss_db_name="& Request("iss_db_name") &"&iss_id_num="& Request("iss_id_num") , _

                    "Notes@_wform_issues_notes.asp?iss_db="& Request("iss_db") &"&iss_id="& Request("iss_id") &"&iss_db_name="& Request("iss_db_name") &"&iss_id_num="& Request("iss_id_num"), _

                    "History@_wform_issues_history.asp?iss_db="& Request("iss_db") &"&iss_id="& Request("iss_id") &"&iss_db_name="& Request("iss_db_name") &"&iss_id_num="& Request("iss_id_num") )

' Tabs for History window

TABarray5 = Array ( imgDependenciesIcon &"Dependencies@_wform_versions_history_dependencies.asp?"& Persists_Query_String( Empty ), _

                    "Runtime@_wform_versions_history_runtime.asp?"& Persists_Query_String( Empty ), _

                    "Used by@_wform_versions_history_used_by.asp?"& Persists_Query_String( Empty ), _

                    "Patches@_wform_versions_history_patches.asp?" & Persists_Query_String( Empty ), _

                    imgReleaseNotesIcon &"Release Notes@_wform_versions_history_release_notes.asp?" & Persists_Query_String( Empty ), _

                    "Documentation@_wform_versions_history_documentation.asp?"& Persists_Query_String( Empty ), _

                    "Files and Folders@_wform_versions_history_files_and_folders.asp?" & Persists_Query_String( Empty ), _

                    "Action Log@_wform_versions_history_action_log.asp?"& Persists_Query_String( Empty ) ,_

                    "Unit Tests@_wform_versions_history_unit_test_log.asp?"& Persists_Query_String( Empty ) )

TABarray5D = Array ( imgDependenciesIcon &"Dependencies@#", _

                     "Runtime@#", _

                     "Patches@#", _

                     imgReleaseNotesIcon &"Release Notes@#", _

                     "Documentation@#", _

                     "Action Log@#",_

                     "Unit Tests@#" )

' Tabs for Unit Test window

TABarray6 = Array ( "Unit Test Details@_wform_update_unit_test.asp?rtag_id="& Request("rtag_id") &"&pv_id="& Request("pv_id") &"&test_id="& Request("test_id"), _

                    "Acceptance@_wform_update_unit_test_acceptance.asp?rtag_id="& Request("rtag_id") &"&pv_id="& Request("pv_id") &"&test_id="& Request("test_id"))

TABarray6D = Array ( "Unit Test Details@#", _

                     "Acceptance@#")

'----------------------------------------------

%>

<script language="JavaScript1.2">

// ---- Popup menu helper functions----

function destroyThisRelease()

{

    vixConfirm('This Release will be permanently destroyed.<p>Are you sure?', {

            button : 'Destroy Release', 

            title : 'Destroy Release', 

            icon : 'images/i_critical.gif',

            url :  '_destroy_release.asp?rtag_id_list=<%=parRtag_id%>&proj_id=<%=DB_PROJ_ID%>&rfile=rtree.asp'

    });

}

// Support function to copy package name into the users clipboard

// Would like to have used a <select>, but can't copy to clipboard in onChange under FireFox

<%Dim cpm_HavePkg :cpm_HavePkg = false

If IsObject(pkgInfoHash) Then

    If pkgInfoHash.Item ("pkg_name") <> "" Then cpm_HavePkg = true    

End If%>

var copyPackageMenu='';

<%If cpm_HavePkg Then %>

copyPackageMenu+='<div class="rex_clm" >&nbsp;Copy Text to Clipboard</div>';

copyPackageMenu+='<div class="menuitems clipThis"><a href="javascript:void(0)"><%=pkgInfoHash.Item ("pkg_name")%></a></div>';

copyPackageMenu+='<div class="menuitems clipThis"><a href="javascript:void(0)"><%=pkgInfoHash.Item ("pkg_version")%></a></div>';

copyPackageMenu+='<div class="menuitems clipThis"><a href="javascript:void(0)"><%=pkgInfoHash.Item ("pkg_name")%>\ <%=pkgInfoHash.Item ("pkg_version")%></a></div>';

copyPackageMenu+='<div class="menuitems clipThis"><a href="javascript:void(0)">LinkPkgArchive (\'<%=pkgInfoHash.Item ("pkg_name")%>\', \'<%=pkgInfoHash.Item ("pkg_version")%>\');</a></div>';

copyPackageMenu+='<div class="menuitems clipThis"><a href="javascript:void(0)">BuildPkgArchive (\'<%=pkgInfoHash.Item ("pkg_name")%>\', \'<%=pkgInfoHash.Item ("pkg_version")%>\');</a></div>';

copyPackageMenu+='<div class="menuitems clipThis"><a href="javascript:void(0)">BuildName (\'<%=pkgInfoHash.Item ("pkg_name")%>\', \'<%=pkgInfoHash.Item ("pkg_version")%>\');</a></div>';

<%End If%>

var copyReleaseMenu='';

copyReleaseMenu+='<div class="rex_clm" >&nbsp;Copy Text to Clipboard</div>';

<%If DB_PROJ_NAME <> "" Then %>

copyReleaseMenu+='<div class="menuitems clipThis"><a href="javascript:void(0)"><%=DB_PROJ_NAME%></a></div>';

<%End If%>

<%If DB_RTAG_NAME <> "" Then %>

copyReleaseMenu+='<div class="menuitems clipThis"><a href="javascript:void(0)"><%=DB_RTAG_NAME%></a></div>';

copyReleaseMenu+='<div class="menuitems clipThis"><a href="javascript:void(0)"><%=DB_PROJ_NAME%> > <%=DB_RTAG_NAME%></a></div>';

<%End If%>

// ---- Popup menu definition ----

var linkset=new Array()

linkset[0]=''

<%=Projects_Menu ( 0 )%>

linkset[1] = ''

linkset[1]+='<div class="menuitems"><a target="_blank" href="<%=ACCESS_MANAGER_URL%>">Access&nbsp;Manager</a></div>'

linkset[1]+='<div class="menuitems"><a target="_blank" href="<%=DEPLOYMENT_MANAGER_URL%>">Deployment&nbsp;Manager</a></div>'

//linkset[1]+='<div class="menuitems"><a target="_blank" href="<%=PRODUCTION_MANAGER_URL%>">Production&nbsp;Manager</a></div>'

linkset[1]+='<div class="menuitems"><a target="_blank" href="<%=RELEASE_MANAGER_URL%>">Release&nbsp;Manager</a></div>'

<%

'-------------------------------------------------

' Function:     genReleaseMode    

' Description:  Generate one line of the Release State dropdown menu

Function genReleaseMode(mode, emode, code, name, title)

    genReleaseMode = ""

    Dim href: href = ""

    Dim mclass : mclass = "menuitems"

        If mode = emode Then

            genReleaseMode = genReleaseMode & LMENU_TICK

            mclass="menuitemDisable"

        Else

            If canActionInProject() Then

                If ReleaseModeAccessCheck(mode, emode) Then

                    href = "<a href=""_change_release_mode.asp?mode_code=" & code & "&"& objPMod.ComposeURL() &""">"

                    genReleaseMode = genReleaseMode & href

                Else

                    mclass="menuitemDisable"

                End If

                genReleaseMode = genReleaseMode & LMENU_BLANK

            End If

        End If

        If genReleaseMode <> "" Then

            genReleaseMode = genReleaseMode & "<span title=""" & title & """>&nbsp;" & name &"</span>"

            If href <> "" Then genReleaseMode = genReleaseMode & "</a>"

            genReleaseMode = "<div class="""&mclass&""">" & genReleaseMode & "</div>"

        End If

    genReleaseMode = "'" & genReleaseMode & "'"

End Function

%>

linkset[2]=''

linkset[2]+=<%=genReleaseMode(ReleaseMode,enumDB_RELEASE_IN_OPEN_MODE,        1, "Open&nbsp;Mode" , "Packages can be released freely.")%>

linkset[2]+=<%=genReleaseMode(ReleaseMode,enumDB_RELEASE_IN_RESTRICTIVE_MODE, 2, "Restrictive&nbsp;Mode" , "Packages can only be released on approval.")%>

linkset[2]+=<%=genReleaseMode(ReleaseMode,enumDB_RELEASE_IN_CCB_MODE,         4, "CCB&nbsp;Mode" , "Packages can only be released on CCB approval.")%>

linkset[2]+=<%=genReleaseMode(ReleaseMode,enumDB_RELEASE_IN_CLOSED_MODE,      3, "Closed&nbsp;Mode" , "No changes allowed.")%>

linkset[2]+=<%=genReleaseMode(ReleaseMode,enumDB_RELEASE_IN_PRESERVE_MODE,    6, "Preserve&nbsp;Mode" , "No change allowed. Archived, but artifacts retained in dpkg_archive")%>

linkset[2]+=<%=genReleaseMode(ReleaseMode,enumDB_RELEASE_IN_ARCHIVE_MODE,     5, "Archive&nbsp;Mode" , "No change allowed. Packages may be purged from dpkg_archive.")%>

linkset[2]+='<hr>'

<%If canActionControlInProject("CreateNewRelease") Then%>

   linkset[2]+='<div class="menuitems"><a href="form_add_release.asp?source_rtag_id=<%=parRtag_id%>&proj_id=<%=DB_PROJ_ID%>&branch=Y&<%=objPMod.ComposeURL()%>">Clone&nbsp;Release</a></div>'

<%Else%>

   linkset[2]+='<div class="menuitemDisable">Clone Release</div>'

<%End If%>

<%If canActionControlInProject("DestroyRelease") AND releaseIsClosed(ReleaseMode) Then%>

   linkset[2]+='<div class="menuitems"><a href="javascript:;" onClick="destroyThisRelease();">Destroy&nbsp;Release</a></div>'

<%Else%>

   linkset[2]+='<div class="menuitemDisable">Destroy Release</div>'

<%End If%>

linkset[2]+='<hr>'

<%If (ReleaseMode = enumDB_RELEASE_IN_OPEN_MODE) AND canShowControlInProject ("CloneReleaseContents") Then%>

   linkset[2]+='<div class="menuitems"><a href="javascript:;" onClick="MM_openVixIFrame(\'_wform_import_release.asp?ToRtag_id=<%=parRtag_id%>&<%=objPMod.ComposeURL()%>\',\'Import Release Contents\')">Import&nbsp;Release&nbsp;Contents</a></div>'

<%Else%>

   linkset[2]+='<div class="menuitemDisable">Import&nbsp;Release&nbsp;Contents</div>'

<%End If%>

<%If (ReleaseMode = enumDB_RELEASE_IN_OPEN_MODE) AND canShowControlInProject ("ImportDependencies") Then%>

   linkset[2]+='<div class="menuitems"><a href="javascript:;" onClick="MM_openVixIFrame(\'_wform_import_dependency.asp?<%=objPMod.ComposeURL()%>\',\'Import Package Dependencies\')">Import&nbsp;Dependencies</a></div>'

<%Else%>

   linkset[2]+='<div class="menuitemDisable">Import&nbsp;Dependencies</div>'

<%End If%>

<%If (ReleaseMode = enumDB_RELEASE_IN_OPEN_MODE) AND canShowControlInProject ("ImportDependencies") Then%>

   linkset[2]+='<div class="menuitems"><a href="javascript:;" onClick="MM_openVixIFrame(\'_wform_import_daemonconfig.asp?<%=objPMod.ComposeURL()%>\',\'Import Daemon Configuration\')">Import&nbsp;Daemon&nbsp;Config</a></div>'

<%Else%>

   linkset[2]+='<div class="menuitemDisable">Import&nbsp;Daemon&nbsp;Config</div>'

<%End If%>

linkset[2]+='<hr>'

linkset[2]+='<div class="menuitems"><a href="form_edit_release.asp?rtag_id=<%=parRtag_id%>">Release&nbsp;Properties</a></div>'

linkset[2]+='<div class="menuitems"><a href="diff.asp?rtagA=<%=parRtag_id%>&rtagB=<%=parRtag_id%>" >Merge&nbsp;Manager</a></div>'

linkset[2]+='<div class="menuitems"><a href="form_view_release_licencing.asp?rtag_id=<%=parRtag_id%>">View Licencing</a></div>'

<%If (canActionControlInProject ("EditPackageLicence") OR canActionControl("MSMaintainer")) AND releaseIsWritable(ReleaseMode) Then%>

linkset[2]+='<div class="menuitems"><a href="form_edit_release_licencing.asp?rtag_id=<%=parRtag_id%>">Edit Licencing</a></div>'

<%Else%>

linkset[2]+='<div class="menuitemDisable">Edit Licencing</div>'

<%End If%>

linkset[2]+='<div class="menuitems"><a href="form_view_deployable_state.asp?rtag_id=<%=parRtag_id%>">View Deployable Flags</a></div>'

<%If releaseIsWritable(ReleaseMode) Then %>

linkset[2]+='<div class="menuitems"><a href="javascript:;" onClick="MM_openVixIFrame(\'wAddDaemonInstruction.asp?ToRtag_id=<%=parRtag_id%>&<%=objPMod.ComposeURL()%>\',\'Add Daemon Instruction\')">Add&nbsp;Daemon&nbsp;Instruction</a></div>'

<%Else%>

linkset[2]+='<div class="menuitemDisable">Add Daemon Instruction</div>'

<%End If %>

linkset[2]+='<hr>'

linkset[2]+='<div class="menuitems"><a href="build_order.asp?rtag_id=<%=parRtag_id%>">Build&nbsp;Order</a></div>'

linkset[2]+='<div class="menuitems"><a href="dependencies.asp?rtag_id=<%=parRtag_id%>&RebuildIcons=1">Rebuild&nbsp;Status&nbsp;Icons</a></div>'

linkset[2]+='<div class="menuitems"><a href="unused_packages.asp?rtag_id=<%=parRtag_id%>">Unused&nbsp;Packages</a></div>'

linkset[2]+='<div class="menuitems"><a href="release_stats.asp?rtag_id=<%=parRtag_id%>">Release&nbsp;Statistics</a></div>'

linkset[6]=''

linkset[6]+='<div class="menuitems"><a href="admin_build_test_page.asp">Release&nbsp;Manager&nbsp;Tests</a></div>'

<%If canActionControl("MSMaintainer") Then%>

   linkset[6]+='<div class="menuitems"><a href="admin_session_details.asp">Session&nbsp;Details</a></div>'

<%Else%>

   linkset[6]+='<div class="menuitemDisable">Session&nbsp;Details</div>'

<%End If%>

linkset[6]+='<hr>'

linkset[6]+='<div class="menuitems"><a href="admin_gbe_machtype.asp">GBE&nbsp;MachType</a></div>'

linkset[6]+='<div class="menuitems"><a href="admin_gbe_machclass.asp">GBE&nbsp;MachClass</a></div>'

linkset[6]+='<div class="menuitems"><a href="admin_build_machine.asp">Build&nbsp;Machine</a></div>'

linkset[6]+='<div class="menuitems"><a href="admin_gbe_buildstandard.asp">Build&nbsp;Standards</a></div>'

linkset[6]+='<div class="menuitems"><a href="admin_licences.asp">Licences</a></div>'

linkset[6]+='<div class="menuitems"><a href="admin_vcs_types.asp">Version&nbsp;Control&nbsp;Systems</a></div>'

linkset[6]+='<hr>'

<%If canActionControl("CreateNewProject") Then %>

    linkset[6]+='<div class="menuitems"><a href="javascript:;" onClick="MM_openVixIFrame(\'_wform_new_project.asp\',\'Create a New Project\')">New&nbsp;Project</a></div>'

<%Else%>

    linkset[6]+='<div class="menuitemDisable">New&nbsp;Project</div>'

<%End If%>

linkset[6]+='<div class="menuitems"><a href="admin_projects.asp">Project&nbsp;Info</a></div>'

linkset[6]+='<div class="menuitems"><a href="admin_project_suffix.asp">Project&nbsp;Suffix</a></div>'

linkset[6]+='<hr>'

linkset[6]+='<div class="menuitems"><a href="admin_package_properties.asp">Package&nbsp;Properties</a></div>'

linkset[6]+='<div class="menuitems"><a href="admin_baseviews.asp">Manage&nbsp;Base&nbsp;Views</a></div>'

linkset[6]+='<hr>'

linkset[6]+='<div class="menuitems"><a href="project_log.asp">Project&nbsp;Log</a></div>'

linkset[6]+='<div class="menuitems"><a href="DanglingVersions.asp">Dangling&nbsp;Packages</a></div>'

linkset[5]=''

<%If Not objAccessControl.UserLogedIn Then%>

   linkset[5]+='<div class="menuitems"><a href="Login.asp?rfile=<%=scriptName & QSTR_FullQuery%>">Login</a></div>'

   linkset[5]+='<div class="menuitemDisable">Logout</div>'

<%Else%>

   linkset[5]+='<div class="menuitems"><a href="Login.asp?rfile=<%=scriptName & QSTR_FullQuery%>">Login as ...</a></div>'

   <%If canActionControl("Masquerade") Then%>

        linkset[5]+='<div class="menuitems"><a href="Masquerade.asp?rfile=<%=scriptName & QSTR_FullQuery%>">Masquerade as ...</a></div>'

   <%End If%>

   linkset[5]+='<div class="menuitems"><a href="_Logout.asp">Logout</a></div>'

<%End If%>

linkset[5]+='<div class="menuitems"><a href="members_pkgs_followed.asp">Notifications</a></div>'

linkset[5]+='<div class="menuitems"><a href="members_personal_view.asp">Views</a></div>'

linkset[5]+='<div class="menuitems"><a href="members_my_details.asp">My&nbsp;Details</a></div>'

linkset[5]+='<div class="menuitems"><a href="members_my_roles.asp">My&nbsp;Roles</a></div>'

linkset[7]=''

linkset[7]+='<div class="menuitems"><a href="release_config.asp?rtag_id=<%=parRtag_id%>">Configuration</a></div>'

linkset[7]+='<div class="menuitems"><a href="build_status.asp?rtag_id=<%=parRtag_id%>">Status</a></div>'

linkset[7]+='<div class="menuitems"><a href="build_plan.asp?rtag_id=<%=parRtag_id%>">Plan</a></div>'

linkset[7]+='<div class="menuitems"><a href="build_release_log.asp?rtag_id=<%=parRtag_id%>">Build Log</a></div>'

linkset[8]=''

linkset[8]+='<div class="menuitems"><a href="admin_build_service.asp">Build&nbsp;Service</a></div>'

linkset[8]+='<div class="menuitems"><a href="admin_build_status.asp">Daemon&nbsp;Status</a></div>'

linkset[8]+='<div class="menuitems"><a href="build_release_log.asp">Daemon&nbsp;Build&nbsp;Log</a></div>'

linkset[8]+='<div class="menuitems"><a href="admin_daemon_instructions.asp">Daemon&nbsp;Instructions</a></div>'

linkset[9]=''

linkset[9]+='<div class="menuitems"><a href="Wikiasp/wiki.asp" target="_blank">Release&nbsp;Notes</a></div>'

<%If (IsEmpty(Application("LiveSystem"))) Then%>

linkset[9]+='<div class="menuitems"><a href="Wikiasp/wiki.asp?db=ImplementationNotes" target="_blank">Development&nbsp;Notes</a></div>'

<%End If%>

linkset[9]+='<div class="menuitems"><a href="help/index.asp" target="_blank">Internal&nbsp;Help(old)</a></div>'

linkset[9]+='<div class="menuitems"><a href="_about.asp" target="_blank">About</a></div>'

</script>

<%

Sub Print_TopRight_Menu_ROW1

   Response.write "<table bgcolor='#ffffff' border='0' cellpadding='0' cellspacing='0' height='26'>"

   Response.write "  <tr class='nowrap'> "

   If objAccessControl.UserLogedIn Then

      Response.write "    <td class='mmEntry'><a class=mmItem href='' onMouseover=""showmenu(event,linkset[5])"" onMouseout=""delayhidemenu()""><img src='images/i_user.gif' border='0' hspace='3'>"&  objAccessControl.FullName &"</a>&nbsp;&nbsp;</td>"

   Else

      Response.write "    <td class='mmEntry'><a class=mmItem href='Login.asp?rfile=" & scriptName & QSTR_FullQuery & "' onMouseover=""showmenu(event,linkset[5])"" onMouseout=""delayhidemenu()"">Login</a>&nbsp;&nbsp;</td>"

   End If

   Response.write "   <td align=middle>|</td>"

   Response.write "    <td class='mmEntry'><a class=mmItem href='' onMouseover=""showmenu(event,linkset[1])"" onMouseout=""delayhidemenu()"">Suite</a></td>"

   Response.write "   <td align=middle>|</td>"

   If InStr(1,ScriptName,"sdk_", 1) <> 0 Then

   Response.write "    <td class='mmEntry'><a class=mmItem href='index.asp'>Releases</a></td>"

   Response.write "   <td align=middle>|</td>"

   Else

   Response.write "    <td class='mmEntry'><a class=mmItem href='sdk_main_page.asp#url=sdk_names_body.asp'>SDK</a></td>"

   Response.write "   <td align=middle>|</td>"

   End If

   Response.write "   <td class='mmEntry'><a class=mmItem href='index.asp' onMouseover=""showmenu(event,linkset[0])"" onMouseout=""delayhidemenu()"">Projects</a></td>"

   Response.write "   <td align=middle>|</td>"

   Response.write "    <td class='mmEntry'><a class=mmItem href='reports.asp'>Reports</a></td>"

   Response.write "   <td align=middle>|</td>"

   Response.write "    <td class='mmEntry'><a class=mmItem href='' onMouseover=""showmenu(event,linkset[8])"" onMouseout=""delayhidemenu()"">Build</a></td>"

   Response.write "   <td align=middle>|</td>"

   Response.write "    <td class='mmEntry'><a class=mmItem href='' onMouseover=""showmenu(event,linkset[6])"" onMouseout=""delayhidemenu()"">Admin</a></td>"

   Response.write "   <td align=middle>|</td>"

   Response.write "    <td class='mmEntry'><a class=mmItem href='' onMouseover=""showmenu(event,linkset[9])"" onMouseout=""delayhidemenu()"">Help</a></td>"

   Response.write "  </tr>"

   Response.write "</table>"

End Sub

Sub Print_TopRight_Menu_ROW2

   Response.write "<table bgcolor='#ffffff' border='0' cellpadding='0' cellspacing='0' height='35'>"

   Response.write "  <tr> "

   If QStrPar("rtag_id") <> "" Then

       Dim lxrContent : lxrContent = RenderLxrStateString(releaseInfoHash("rtag_id"),releaseInfoHash("lxr"),releaseInfoHash("lxrserver"), releaseInfoHash("official")," LXR")

      If lxrContent <> "" Then

        Response.write "   <td class='mmEntry'>"& lxrContent &"</td>"

        Response.write "   <td align=middle>|</td>"

      End If

      Response.write "    <td class='mmEntry'><a class=mmItem href='#' onMouseover=""showmenu(event,linkset[2])"" onMouseout=""delayhidemenu()"">Release</a></td>"

      Response.write "    <td align=middle>|</td>"

      Response.write "    <td class='mmEntry'><a class=mmItem href='#' onMouseover=""showmenu(event,linkset[7])"" onMouseout=""delayhidemenu()"">Build</a></td>"

   Else

      Response.write "    <td class='mmEntry mmItemDisable'>Release</td>"

      Response.write "    <td align=middle>|</td>"

      Response.write "    <td class='mmEntry mmItemDisable'>Build</td>"

   End If

   Response.write "  </tr>"

   Response.write "</table>"

End Sub

Sub Print_TopLeft_Menu

   Dim HomeSTR, ProjSTR, RtagSTR,ModeSTR

   Dim ActionSTR

   HomeSTR = "<a class=mmItem href='index.asp'>HOME</a>"

   RtagSTR = ""

   ProjSTR = ""

   If DB_RTAG_ID > 0 Then RtagSTR = "&nbsp;&gt;&nbsp;<a class=mmItem href='dependencies.asp?rtag_id="& DB_RTAG_ID &"'>"& DB_RTAG_NAME &"</a>"

   If DB_PROJ_ID > 0 Then ProjSTR = "&nbsp;&gt;&nbsp;<a class=mmItem href='rtree.asp?proj_id="& DB_PROJ_ID &"'>"& DB_PROJ_NAME &"</a>"

   '-- Calculate authorisation state

   ActionSTR = ""

   If NOT canActionInProject Then

    ActionSTR = " [Not Authorised]"

    ActionSTR = "<img src='images/i_not_authorised.png' width='10' height='10' border='0' hspace='2' title='Not Authorised to make changes in this project'>" 

   End If

   '-- Append Mode indication

   ModeSTR = ""

   If ReleaseMode = enumDB_RELEASE_IN_RESTRICTIVE_MODE Then

      ModeSTR = " [Restrictive Mode]"

   ElseIf ReleaseMode = enumDB_RELEASE_IN_CCB_MODE Then

      ModeSTR = " [CCB Mode!]"

   ElseIf ReleaseMode = enumDB_RELEASE_IN_CLOSED_MODE Then

      ModeSTR = "<img src='images/i_locked.gif' width='7' height='10' border='0' hspace='2' >&nbsp;[Closed Mode]"

   ElseIf ReleaseMode = enumDB_RELEASE_IN_CLOSED_MODE Then

      ModeSTR = "<img src='images/i_locked.gif' width='7' height='10' border='0' hspace='2' >&nbsp;[Closed Mode]"

   ElseIf ReleaseMode = enumDB_RELEASE_IN_PRESERVE_MODE Then

      ModeSTR = "<img src='images/i_locked.gif' width='7' height='10' border='0' hspace='2' >&nbsp;[Preserve Mode]"

   ElseIf ReleaseMode = enumDB_RELEASE_IN_ARCHIVE_MODE Then

       ModeSTR = "<img src='images/i_archived.gif' width='7' height='10' border='0' hspace='2' >&nbsp;[Archived Mode]"

   End If

    Dim PkgNameSTR, PkgVersionSTR

    PkgNameSTR = ""

    PkgVersionSTR = ""

    If IsObject(pkgInfoHash) Then

        If pkgInfoHash.Item("pkg_name") <> "" Then

            PkgNameSTR = "&nbsp;&gt;&nbsp;<a class=mmItem href='view_by_version.asp?pkg_id="& pkgInfoHash.Item("pkg_id") &"&listby=1'>"& pkgInfoHash.Item("pkg_name")& "</a>"

            PkgVersionSTR = "&nbsp;&gt;&nbsp;<a class=mmItem href='#'>"& pkgInfoHash.Item("pkg_version") &"</a>"

        End If

    End IF

   '-- Render Menu --

   Response.write "<table width='100%' border='0' cellspacing='0' cellpadding='0'>"

   Response.write "  <tr>"

   Response.write "    <td width='1%'><img src='images/h_trsp_dot.gif' width='30' height='35'></td>"

   Response.write "    <td nowrap width='100%' class='mmItem'>"& HomeSTR & ProjSTR & ActionSTR &  RtagSTR & ModeSTR & PkgNameSTR & PkgVersionSTR

   Response.write "&nbsp;<a href='#' onClick='showmenu(event,copyReleaseMenu)' onmouseout='delayhidemenu()'>"

   Response.Write enum_imgClipBoard10

   Response.write "</a></td>"

   Response.write "  </tr>"

   Response.write "</table>"

End Sub

'-----------------------------------------------------------

' Display package breadcrumbs, when displaying package details 

' outside the context of a Release

'

Sub Print_Package_TopLeft_Menu

    Dim PkgNameSTR, PkgVersionSTR, PkgLock

    If IsObject(pkgInfoHash) Then

        PkgNameSTR = "<a class=mmItem href='view_by_version.asp?pkg_id="& pkgInfoHash.Item("pkg_id") &"&listby=1'>"& pkgInfoHash.Item("pkg_name")& "</a>"

        PkgVersionSTR = " &gt; <a class=mmItem href='#'>"& pkgInfoHash.Item("pkg_version") &"</a>"

        PkgLock = pkgInfoHash.Item("dlocked")

    else

        Dim SSpkgID, SSpkgName, SSpkgVersion, SSsrc_path, SSpkgDesc, BBdlocked

        Call Get_Pkg_Short_Info( Request("pv_id"), SSpkgID, SSpkgName, SSpkgVersion, SSsrc_path, SSpkgDesc, BBdlocked )

        PkgNameSTR = "<a class=mmItem href='view_by_version.asp?pkg_id="& SSpkgID &"&listby=1'>"& SSpkgName& "</a>"

        PkgVersionSTR = " &gt; <a class=mmItem href='#'>"& SSpkgVersion &"</a>"

        PkgLock = BBdlocked

    End If

    Response.write "<table width='100%' border='0' cellspacing='0' cellpadding='0'>"

    Response.write "  <tr>"

    Response.write "    <td width='1%'><img src='images/h_trsp_dot.gif' width='30' height='35'></td>"

    Response.write "    <td nowrap width='100%' class=mmItem>"& PkgNameSTR & PkgVersionSTR

    If (PkgLock= "Y") OR (PkgLock = "A") Then

        Response.write "<img src='images/i_locked.gif' width='7' height='10' border='0' hspace='2' title='Packages locked'>"

    End If

    Response.write "<a href='#' onClick='showmenu(event,copyReleaseMenu)' onmouseout='delayhidemenu()'>"

    Response.Write enum_imgClipBoard10

    Response.write "</a>"

    Response.write "    </td>"

    Response.write "  </tr>"

    Response.write "</table>"

End Sub

'-----------------------------------------------------------

'   Generate the list of projects in a menu item

Function Projects_Menu ( NNarrIndex )

   Dim rsTemp, Query_String, tempSTR

   tempSTR = ""

   Query_String = _

	"select unique p.* from release_tags rt, projects p where rt.PROJ_ID = p.PROJ_ID and rt.official in ('N','R','C','P') ORDER BY p.proj_name ASC"

   '" SELECT * FROM projects ORDER BY proj_name ASC"

   Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))

   While ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF))

      tempSTR = tempSTR & "linkset["& NNarrIndex &"]+='<div class=""menuitems""><a href=""rtree.asp?proj_id="& rsTemp.Fields("proj_id") &""">"& Replace(rsTemp.Fields("proj_name"), " ", "&nbsp;") &"</a></div>'"& VBNewLine

      rsTemp.MoveNext

   WEnd

   Projects_Menu = tempSTR

   rsTemp.Close

   Set rsTemp = nothing

End Function

'Function Get_Proj ( NNrtag_id, NNvtree_id )

'   Dim rsTemp, Query_String, tempRtag_id

'   If NNvtree_id = "" Then

'      If NNrtag_id = "" Then

'         tempRtag_id = -1

'      Else

'         tempRtag_id = NNrtag_id

'      End If

'      Query_String = _

'      " SELECT vt.vtree_id, vt.proj_id"&_

'        "   FROM release_tags rel, vtrees vt"&_

'       "   WHERE vt.vtree_id = rel.vtree_id AND rel.rtag_id = "& tempRtag_id

'   Else

'      Query_String = _

'      " SELECT vt.vtree_id, vt.proj_id"&_

'        "   FROM vtrees vt"&_

'       "   WHERE vt.vtree_id = "& NNvtree_id

'   End If

'

'   Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))

'

'   If ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF)) Then

'      Get_Proj = (rsTemp.Fields("proj_id"))

'      NNvtree_id = (rsTemp.Fields("vtree_id"))

'   Else

'      Get_Proj = -1

'      NNvtree_id = -1

'   End If

'

'   rsTemp.Close

'   Set rsTemp = nothing

'End Function

%>