Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>

<%

'=====================================================

'   RequestPackageVersionHistoryMetrics.asp 

'=====================================================

%>

<%

Option explicit

' Good idea to set when using redirect

Response.Expires = 0   ' always load the page, dont store

%>

<!--#include file="common/conf.asp"-->

<!--#include file="common/globals.asp"-->

<!--#include file="common/formating.asp"-->

<!--#include file="common/qstr.asp"-->

<!--#include file="common/common_subs.asp"-->

<%

'------------ Variable Definition -------------

Dim rsMetrics

Dim parPvId

Dim parRtagId

Dim parMode

Dim parInterval

Dim qFile

Dim iRippleBasePVID, iLastSignificantPVID

'------------ Constants Declaration -----------

'------------ Variable Init -------------------

parPvId = Request("pv_id")

parRtagId = RequestDefault("rtag_id", 0)

parMode = RequestDefault("mode", 0)

parInterval = RequestDefault("interval", 0)

qFile = Iif ( parMode = 1, "PackageVersionMetricsAll.sql", "PackageVersionMetrics.sql")

If parMode <> 0 Then

    Call getLastSignificantVersions (parPvId, iRippleBasePVID, iLastSignificantPVID) 

End If

'----------------------------------------------

%>

<%

'------------------------ MAIN LINE ---------------------------------

'--------------------------------------------------------------------

' Get the list of ancestor versions

OraDatabase.Parameters.Add "RTAG_ID", parRtagId,    ORAPARM_INPUT, ORATYPE_NUMBER

OraDatabase.Parameters.Add "PV_ID", parPvId,        ORAPARM_INPUT, ORATYPE_NUMBER

Set rsMetrics = OraDatabase.DbCreateDynaset( GetQuery(qFile), cint(0))

OraDatabase.Parameters.Remove "PV_ID"

OraDatabase.Parameters.Remove "RTAG_ID"

%>

<!-- RequestPackageVersionHistoryMetrics.asp -->

<table width="100%" border="0" cellspacing="1" cellpadding="1">

<tr>

  <td>

     <table width="100%" border="0" cellspacing="1" cellpadding="1">

        <tr class="form_field_bg">

           <td nowrap class="body_row" valign="top" >Package Version [<%=rsMetrics.RecordCount%>]</td>

           <td nowrap class="body_row" valign="top" >Autobuilt</td>

           <td nowrap class="body_row" valign="top" >Build Reason</td>

           <td nowrap class="body_row" valign="top" >Lines Of Code</td>

           <td nowrap class="body_row" valign="top" >Unit Tested</td>

           <td nowrap class="body_row" valign="top" >Autotested</td>

           <td nowrap class="body_row" valign="top" >Last Modified</td>

           <td nowrap class="" valign="top" ></td>

        </tr>

        <%

        If rsMetrics.RecordCount < 1 Then

        %>

           <tr class="form_field_grey_bg">

              <td colspan="7" class="body_row" nowrap>None Found</td>

           </tr>

        <%

        Else

           While ((NOT rsMetrics.BOF) AND (NOT rsMetrics.EOF))

               Dim trClass : trClass = "form_field_grey_bg"

               Dim showBaseRippleHelp : showBaseRippleHelp = FALSE

               Dim showInterval : showInterval = FALSE

               If parMode > 0 Then

                If rsMetrics("inRelease") <> 0 OR CLng(rsMetrics("ageDays")) <= CLng(parInterval) Then

                    trClass = "form_field_hilight_bg"

                    showInterval = TRUE

                End If

                If CLng(iRippleBasePVID) = CLng(rsMetrics("pv_id")) Then

                    trClass = "form_field_hilight_bg"

                    showBaseRippleHelp = TRUE

                End If

               End If

              %>

                 <tr class="<%=trClass%>">

                    <td nowrap class="body_row">

                       <a class="txt_linked" href="dependencies.asp?pv_id=<%=rsMetrics("pv_id")%>"><%=rsMetrics("pkg_name")%>&nbsp;<%=rsMetrics("pkg_version")%></a>

                    </td>

                    <td nowrap class="body_row"><%=IIf(rsMetrics("is_autobuildable") = "Y", "Yes", "No")%></td>

                    <td nowrap class="body_row"><%=rsMetrics("reason")%></td>

                    <td nowrap class="body_row tright"><%=rsMetrics("code_lines")%></td>

                    <td nowrap class="body_row"><%=IIf(rsMetrics("unit_tested") = "Y", "Yes", "No")%></td>

                    <td nowrap class="body_row tright"><%If IsNull(rsMetrics("autotested")) OR rsMetrics("autotested") <> "Y" Then %>No<%ElseIf rsMetrics("test_count") = "0" Then%>?<%Else%><%=rsMetrics("test_count")%><%End If%></td>

                    <td nowrap class="body_row"><%=rsMetrics("modified_stamp")%></td>

                    <%If showBaseRippleHelp OR showInterval Then%>

                    <td nowrap>

                        <%If showInterval Then%>

                            <%=Quick_Help("h_showInterval")%>

                        <%End If%>

                        <%If showBaseRippleHelp Then%>

                            <%=Quick_HelpImg("h_baseRipple", "images/btn_left.gif")%>

                        <%End If%>

                    </td>

                    <%End If%>

                 </tr>

              <%

           rsMetrics.MoveNext

           WEnd

        End If

        rsMetrics.Close

        Set rsMetrics = nothing

        %>

     </table>

  </td>

</tr>

</table>

<br>

<%

Call Destroy_All_Objects

%>