Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>

<%

'=====================================================

'       sdk_names_json.asp

'       Ajax support for table of SDK names

'       Designed to be driven by the jquery tablescroller

'=====================================================

%>

<%

Option explicit

' Essential to get UTF through all the hoops. ie: VÄSTTRAFIK (VTK)

Response.ContentType = "text/html"

Response.AddHeader "Content-Type", "text/html;charset=UTF-8"

Response.CodePage = 65001

Response.CharSet = "UTF-8"

%>

<!--#include file="common/conf.asp"-->

<!--#include file="common/globals.asp"-->

<!--#include file="common/qstr.asp"-->

<!--#include file="common/common_subs.asp"-->

<SCRIPT LANGUAGE="VBScript" RUNAT=SERVER SRC="class/classaspJSON.vbs"></SCRIPT> 

<%

'------------ Variable Definition -------------

Dim result : result = -1

Dim SqlQry

Dim rsQry

' Init the output JSON class

'   Operations can add data

'   Default data will be added at the end

Dim oJSON :Set oJSON = New aspJSON

Dim newitem

'

' Determine the size of the record set

'   Gives bad results when searching

Dim MaxCount : MaxCount = 0

SqlQry = "select count(*) as count from SDK_NAMES skn"

On Error Resume Next

objEH.ErrorRedirect = FALSE

objEH.TryORA ( OraSession )

Set rsQry = OraDatabase.DbCreateDynaset( SqlQry, ORADYN_DEFAULT )

objEH.CatchORA ( OraSession )

    If ((NOT rsQry.BOF) AND (NOT rsQry.EOF)) Then

        MaxCount = rsQry("COUNT")

    End If

rsQry.Close

Set rsQry = Nothing

' Basic Header

'   iTotalRecords = total records without any filtering/limits

'   iTotalDisplayRecords = filtered result count

oJSON.data("sEcho") = CInt(Request.QueryString("sEcho"))

oJSON.data("iTotalRecords") = MaxCount

oJSON.data("iTotalDisplayRecords") = MaxCount

' Assist in debug

oJSON.data("iReqDisplayStart") = CInt(Request.QueryString("iDisplayStart"))

oJSON.data("iReqDisplayLength") = CInt(Request.QueryString("iDisplayLength"))

Dim vName

for each vName in Request.QueryString

    oJSON.data("sReq_" & vName) = Request.QueryString(vName)

next

' Extract selected range

result = 0

dim firstRow,lastRow

firstRow = CInt(Request.QueryString("iDisplayStart"))

lastRow = firstRow + CInt(Request.QueryString("iDisplayLength"))

' Define the data items to extract from the database

' An array of items to extract

'

Dim dataCols: dataCols = Array ( _

        "sdk_id", _

        "sdk_name", _

        "sdk_comment" )

'   Define array of colums to sort by

'       Must match user sort column request

Dim sortCols: sortCols = Array ( _

        "sdk_id",_

        "UPPER(sdk_name)",_

        "UPPER(sdk_comment)" )

' Dim determine sorting options

'On Error goto 0

'Response.Write "<pre>"

Dim sortString

If Request.QueryString("iSortCol_0") <> "" Then

    sortString = " ORDER BY " & sortCols(CInt(Request.QueryString("iSortCol_0")))

    sortString = sortString & " " & Request.QueryString("sSortDir_0")

Else

    sortString = " ORDER BY " & sortCols(CInt(1)) & "asc"

End If

' Filter (search )

Dim searchString

If Request.QueryString("sSearch") <> "" Then

    searchString = " AND upper(sdk_name) LIKE upper('%" & Request.QueryString("sSearch") & "%')" 

End If

' Create a list of cols that we need. Avoids ambiguity in selections

Dim x,colList,colListJoin

For x = Lbound(dataCols) to Ubound(dataCols)

    colList = colList & colListJoin & dataCols(x)

    colListJoin = ","

Next

Dim whereString

Dim BasicSql

BasicSql = "select " & colList &_

            " from SDK_NAMES skn " &_

            whereString &_

            searchString &_

            sortString

SqlQry = "select * from ( "&_

            "select a.*, ROWNUM rnum from (" & BasicSql &_

                ") a where ROWNUM <= " & lastRow &_

            ") where rnum >= " & firstRow

' Assist in debug

oJSON.data("BasicSql") = BasicSql

'oJSON.data("SqlQry") = SqlQry

' Perform the database query

Set oJSON.data("aaData") = oJSON.Collection()

On Error Resume Next

objEH.ErrorRedirect = FALSE

objEH.TryORA ( OraSession )

Set rsQry = OraDatabase.DbCreateDynaset( SqlQry, ORADYN_DEFAULT )

objEH.CatchORA ( OraSession )

' Process each row and return required fields to the user

If objEH.Finally Then

On Error goto 0

   While (NOT rsQry.BOF) AND (NOT rsQry.EOF)

       Set newitem = oJSON.AddToCollection(oJSON.data("aaData"))

       ' Attempt to speed up access tot he data

       '    Extract all fields for the row

       '    Access fields by index

       Dim fields

       Set fields = rsQry.Fields

       Dim sdk_id       : sdk_id = fields(0)

       Dim sdk_name     : sdk_name = fields(1)

       Dim sdk_comment  : sdk_comment = fields(2)

       Set fields = nothing

        newitem(0) = sdk_id

        newitem(1) = sdk_name

        newitem(2) = sdk_comment

        newitem(3) = "<button class=rmbutton onclick='editSdkEntry("& sdk_id &");'>Edit</button>"

       rsQry.MoveNext

   Wend

End IF

rsQry.Close

Set rsQry = Nothing

'

' SQL error detection and reporting

If objEH.LastOraFailed Then

    oJSON.data("error") = 1

    oJSON.data("emsgSummary") = objEH.MessageSummary

    oJSON.data("emsgDetails") = objEH.MessageDetails

    oJSON.data("SqlQry") = SqlQry

End If

'Return the object

Response.Write oJSON.JSONoutput()

'OraSession.Dispose()

%>