Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>

<%

'=====================================================

'|                                                   |

'|                        RTREE                      |

'|                                                   |

'=====================================================

%>

<%

Option explicit

' Good idea to set when using redirect

Response.Expires = 0   ' always load the page, dont store

%>

<!--#include file="common/conf.asp"-->

<!--#include file="common/globals.asp"-->

<!--#include file="common/formating.asp"-->

<!--#include file="common/qstr.asp"-->

<!--#include file="common/common_subs.asp"-->

<!--#include file="common/_rtree_common.asp"-->

<!--#include file="common/daemon_status.asp"-->

<%

'------------ ACCESS CONTROL ------------------

%>

<!--#include file="_access_control_general.asp"-->

<%

'------------ Variable Definition -------------

Dim ViewType

Dim bIsaTreeView

Dim rsQryStr

Dim rsQry

Dim parProjId

Dim parShowFilter

Dim objBtnControl

Dim currLevel, lastLevel

Dim dListFilter

Dim objDmSts

Dim hoverTitle, createdBy, comment

Dim bCanMove

Dim bCanDestroy

Dim bCanClone

Dim bCanUnarchive

Dim bCanCloseArchive

'------------ Constants Declaration -----------

Const LIMG_TREE_I_HALF = "<img src='images/spacer.gif' width='20' height='1'>"

Const LIMG_TREE_I_NONE = "<img src='images/spacer.gif' width='30' height='15'>"

Const LIMG_TREE_I_FULL = "<img src='images/dot1h.gif' width='30' height='15'>"

Const LIMG_TREE_T      = "<img src='images/dot1.gif' width='30' height='15'>"

Const LIMG_LIST_VIEW   = "<img src='images/abtn_list_view.gif' border='0' align=absmiddle' name='imgviewtype' usemap='#mapviewtype' id='imgviewtype'>"

Const LIMG_TREE_VIEW   = "<img src='images/abtn_tree_view.gif' border='0' align=absmiddle' name='imgviewtype' usemap='#mapviewtype' id='imgviewtype'>"

Const LCONST_LIST_VIEW = 1

Const LCONST_TREE_VIEW = 2

Const DEFAULT_SHOW_FILTER = "'N','R','C','O'"

'------------ Variable Init -------------------

'   Need either proj_id or rtag_id, for which we will calculate a project id

parProjId = Request("proj_id")

If parProjId = "" Then parProjId = DB_PROJ_ID

If parProjId = ""  OR parProjId < 0 Then

   Response.Redirect("index.asp")

End If

Call objPMod.StoreParameter("proj_id", parProjId)

' Get show_filter from query string or failing that, from the cookie.

' Make sure that if neither supplies it, use the default

parShowFilter = Request("show_filter")

If NOT IsNull(parShowFilter) AND parShowFilter <> "" Then

   Response.Cookies (COOKIE_RELEASE_MANAGER_MEMORY)("show_filter") = parShowFilter

Else

   parShowFilter = Request.Cookies (COOKIE_RELEASE_MANAGER_MEMORY)("show_filter")

   If IsNull(parShowFilter) OR parShowFilter = "" Then

      parShowFilter = DEFAULT_SHOW_FILTER

      Response.Cookies (COOKIE_RELEASE_MANAGER_MEMORY)("show_filter") = parShowFilter

   End If

End If

Set dListFilter = CreateObject("Scripting.Dictionary")

Set objBtnControl = New ActionButtonControl

' Init access control

bCanMove =  canActionControlInProject("ConfigureRelease") 

bCanDestroy = canActionControlInProject("DestroyRelease")

bCanClone =  canActionControlInProject("CreateNewRelease")

bCanUnarchive = canActionControl("MSMaintainer")

bCanCloseArchive = canActionInProject()

'----------------------------------------------

%>

<%

'--------------------------------------------------------------------------------------------------------------------------

' Determines if the specified filter is on/off and returns a string to use to check the associated checkbox accordingly

Function GetIsListFilterChecked( nFilterId )

   GetIsListFilterChecked = ""

  If bIsaTreeView Then

       ' Disable the control in Tree View

       GetIsListFilterChecked = GetIsListFilterChecked & " checked disabled"

  Else

       If dListFilter.Exists ( "'" & CStr(nFilterId) & "'"  ) Then

          GetIsListFilterChecked = "checked"

       End If

  End If

End Function

'--------------------------------------------------------------------------------------------------------------------------

' Reads the cookie for the filter and creats a dictionary element for each item therein. the dictionary

' is used by the GetIsListFilterChecked function to determine checkbox state in the filter options

Sub GetListFilterValues ( outDepFilter )

   Dim FilterVal, aFilterValues

   If parShowFilter <> "" Then

      aFilterValues = Split( Replace( parShowFilter, " ", ""), ",")

      For Each FilterVal In aFilterValues

         outDepFilter.Item (CStr( FilterVal )) = ""

      Next

   End If

End Sub

'----------------------------------------------------------------------------------------------------------------------------------------------

Sub RenderIndent ( nLastLevel, nCurrLevel )

   Dim i

   If nCurrLevel <= 1 Then Exit Sub

   '-- Render half lines

   If nCurrLevel > 2 Then

      For i = 1 To nCurrLevel - 2

         Response.write LIMG_TREE_I_NONE

      Next

   End If

   '-- Render branch or line

   If nLastLevel < nCurrLevel Then

      Response.write LIMG_TREE_T

   Else

      Response.write LIMG_TREE_I_FULL

   End If

End Sub

'----------------------------------------------------------------------------------------------------------------------------------------------

Sub NewRelease ()

    Call OpenInWindow ( "new_release.asp?" & objPMod.ComposeURL() )

End Sub

'----------------------------------------------------------------------------------------------------------------------------------------------

Sub MergeManager ()

    ' Open Merge Manager without parameters

    Call OpenInWindow ( "diff.asp" )

End Sub

'----------------------------------------------------------------------------------------------------------------------------------------------

Sub AdminView()

     Dim Query_String

     Query_String = _

     "   SELECT DISTINCT vi.view_id, vi.view_name"&_

     "   FROM VIEWS vi"&_

     "   WHERE vi.view_name = 'PROJECT WIDE'"

     Set rsQry = OraDatabase.DbCreateDynaset( Query_String , cint(0) )

     Dim viewRecordCount

     Dim id

     viewRecordCount=0

     viewRecordCount = rsQry.RecordCount

     While (NOT rsQry.BOF) AND (NOT rsQry.EOF)

        id=rsQry.Fields("view_id")

        rsQry.MoveNext

     WEnd

      rsQry.Close()

     Set rsQry = nothing

     If viewRecordCount = 0 Then

        OraDatabase.Parameters.Add "PROJ_ID", parProjId,    ORAPARM_INPUT, ORATYPE_NUMBER

        Query_String = _

        " SELECT DISTINCT vi.view_id, vi.view_name"&_

        " FROM VIEWS vi, RELEASE_CONTENT rc, RELEASE_TAGS rt"&_

        " WHERE rc.BASE_VIEW_ID = vi.VIEW_ID AND rt.proj_id = "& parProjId &"AND rc.rtag_id = rt.rtag_id"&_

        " ORDER BY ( vi.view_name )"

        Set rsQry = OraDatabase.DbCreateDynaset( Query_String , cint(0) )

        OraDatabase.Parameters.Remove "PROJ_ID"

        viewRecordCount = rsQry.RecordCount

        While (NOT rsQry.BOF) AND (NOT rsQry.EOF)

           id=rsQry.Fields("view_id")

           rsQry.MoveNext

        WEnd

        rsQry.Close()

        Set rsQry = nothing

     End If

     If viewRecordCount = 0 Then

        Call OpenInWindow ( "form_edit_project_view.asp?proj_id="&parProjId)

     Else

        Call OpenInWindow ( "form_edit_project_view.asp?proj_id="&parProjId&"&FRview_id="&id)

     End If

End Sub

'----------------------------------------------------------------------------------------------------------------------------------------------

Function GetViewType ()

   Dim CookieViewType

   CookieViewType = Request.Cookies (COOKIE_RELEASE_MANAGER_MEMORY)("RELEASE_VIEW")

   If CookieViewType <> "" Then

      ' Get current view type from cookie

      GetViewType = CInt(CookieViewType)

   Else

      ' Set current view to list view

      Response.Cookies (COOKIE_RELEASE_MANAGER_MEMORY)("RELEASE_VIEW") = LCONST_LIST_VIEW

      GetViewType = LCONST_LIST_VIEW

   End If

End Function

'----------------------------------------------------------------------------------------------------------------------------------------------

Sub SetViewType ()

   If Request("viewtype") = "" Then Exit Sub    ' Nothing to do

   Response.Cookies (COOKIE_RELEASE_MANAGER_MEMORY)("RELEASE_VIEW") = Request("viewtype")

End Sub

'----------------------------------------------------------------------------------------------------------------------------------------------

Sub RenderDaemonStatusConfig(nRtagId) 

   %>

   <table class="embedded_table">

    <tr>

     <td>

     <%

      Response.Write("<img src=""icons/i_edit.gif"" border=0 vspace=0 hspace=0 title='Configure Daemons' onclick='location.href=""release_config.asp?rtag_id="&nRtagId&"""'>")

      Response.Write("<img src=""icons/ext_log.gif"" border=0 vspace=0 hspace=0 title='View Build Log'onclick='location.href=""build_release_log.asp?rtag_id="&nRtagId&"""'>")

     %>

     </td>

     <td>

   <%

    Call objDmSts.RenderDaemonStatus(nRtagId,16)

    %>

        </td>

        </tr>

        </table>

    <%

End Sub

'----------------------------------------------------------------------------------------------------------------------------------------------

Function RenderActions(nRtagId, sOfficial)

    Response.Write "<span title='Select operation from dropdown menu' class='select-operation ui-icon ui-icon-triangle-1-s' data-rtag-id='"&nRtagId&"' data-official='"&sOfficial&"'></span>"

End Function

'----------------------------------------------------------------------------------------------------------------------------------------------

Function GetMassRefComments (nRtagId)

   Dim UsedBy

   Dim rsQryUse

   Dim linkB

   Dim joiner : joiner = ""

   Dim comment : comment = ""

'   If parProjId <> 2 Then

'     assocMASSREF = rsQry("assoc_mass_ref")

'     If assocMASSREF <> "" Then

'        Set rsQryAssoc = OraDatabase.DbCreateDynaset("SELECT RTAG_NAME, RTAG_ID FROM RELEASE_TAGS WHERE RTAG_ID="&assocMASSREF , ORADYN_DEFAULT)

'        assocMASSREFName = rsQryAssoc("RTAG_NAME")

'        link = rsQryAssoc("rtag_id")

'        rsQryAssoc.Close

'        Set rsQryAssoc = Nothing

'     Else

'        assocMASSREFName = "None."

'     End If

'   Else

      UsedBy = nRtagId

      If UsedBy <> "" Then

         Set rsQryUse = OraDatabase.DbCreateDynaset("SELECT * FROM RELEASE_TAGS RT, PROJECTS P WHERE RT.ASSOC_MASS_REF=" & nRtagId & " AND RT.PROJ_ID=P.PROJ_ID", ORADYN_DEFAULT)

         While ((NOT rsQryUse.BOF) AND (NOT rsQryUse.EOF))

            If rsQryUse("assoc_mass_ref") = UsedBy Then

               linkB = "dependencies.asp?rtag_id="&rsQryUse("rtag_id")

               comment = joiner & rsQryUse("proj_name") & " -> <a href="&linkB&">"& rsQryUse("rtag_name") &"</a>"

               joiner = " <br> "

               rsQryUse.MoveNext

            End If

         WEnd

         rsQryUse.Close

         Set rsQryUse = Nothing

      End If

      GetMassRefComments = comment

End Function

'----------------------------------------------------------------------------------------------------------------------------------------------

%>

<%

'------------ RUN BEFORE PAGE RENDER ----------

If (Request("action") <> "") Then

   If Request("btn") = "Update" Then

      ' Store filter in cookie

      Response.Cookies (COOKIE_RELEASE_MANAGER_MEMORY)("show_filter") = Request("listFilter")

      parShowFilter = Request("listFilter")

      If IsNull(parShowFilter) OR parShowFilter = "" Then parShowFilter = DEFAULT_SHOW_FILTER

   Else

      '-- Select Action

      Select Case Request("action")

          Case "btnNewRelease"

             Call NewRelease()

          Case "btnMergeManager"

             Call MergeManager()

          Case "btnAdminView"

             Call AdminView()

      End Select

   End If

End If

' Set view type  if required

Call SetViewType ()

' Get current view type

ViewType = GetViewType()

bIsaTreeView = (ViewType = LCONST_TREE_VIEW)

'----------------------------------------------

%>

<html>

<head>

<%

   Set rsQry = OraDatabase.DbCreateDynaset( "SELECT PROJ_NAME FROM PROJECTS WHERE PROJ_ID="& parProjId, ORADYN_DEFAULT )

%>

<title><%=rsQry("proj_name")%></title>

<%

   rsQry.Close

   Set rsQry = Nothing

%>

<meta HTTP-EQUIV="Pragma" CONTENT="no-cache">

<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">

<link rel="stylesheet" href="images/release_manager_style.css" type="text/css">

<link rel="stylesheet" href="images/navigation.css" type="text/css">

<script language="JavaScript" src="images/common.js"></script>

<!-- DROPDOWN MENUS -->

<!--#include file="_menu_def.asp"-->

<script language="JavaScript1.2" src="images/popup_menu.js"></script>

<!-- Dropdown action menu scripts -->

<style>

    .ui-menu { position: absolute; }

</style>

<!--#include file="_jquery_includes.asp"-->

<script>

    $(function() {

        // Global menu data structure

        //  Persist between invocations of the menu

        //      Used to mergeLeft rtagid

        //      Used to store current menu info

        $.miniMenu = {

            //  Data

            bCanUnarchive : <%=iif(bCanUnarchive, "true", "false")%> ,

            bCanCloseArchive : <%=iif(bCanCloseArchive, "true", "false")%> ,

            //  Menu operations

            open : function (data, event) {

                console.log("Opening:", data.rtagid);

                this.gotoUrl("dependencies.asp", {rtag_id : data.rtagid});

             },

             edit : function (data) {

                 console.log("Editing:", data.rtagid);

                 this.gotoUrl("form_edit_release.asp", {rtag_id : data.rtagid, rfile : "<%=ScriptName%>"});

             },

             mergeSelect : function (data) {

                 console.log("Merge from:", data.rtagid );

                 data.mergeLeft = data.rtagid;

             },

             merge : function (data) {

                 console.log ("Merge:", data.mergeLeft, data.rtagid);

                 this.gotoUrl("diff.asp", { rtagA : data.mergeLeft, rtagB : data.rtagid});

             },

             close : function (data) {

                 console.log("Closing:", data.rtagid);

                 this.gotoUrl("_change_release_mode.asp", {rtag_id : data.rtagid, mode_code : 3 , rfile : "<%=ScriptName%>"});

             },

             preserve : function (data) {

                 console.log("Preserving:", data.rtagid);

                 this.gotoUrl("_change_release_mode.asp", {rtag_id : data.rtagid, mode_code : 6 , rfile : "<%=ScriptName%>"});

             },

             archive : function (data) {

                 console.log("Archiving:", data.rtagid);

                 this.gotoUrl("_change_release_mode.asp", {rtag_id : data.rtagid, mode_code : 5 , rfile : "<%=ScriptName%>"});

             },

<%If bCanDestroy Then%>

             delete : function (data) {

                 console.log("Delete:", data.rtagid);

                 var that = this;

                 this.confirmDelete(function(){

                     that.gotoUrl("_destroy_release.asp", {rtag_id_list : data.rtagid, proj_id : <%=parProjId%>, rfile : "<%=ScriptName%>"});

                 });

             },

<%End If%>

<%If bCanMove Then%>

             move : function (data) {

                 console.log("Move:", data.rtagid);

                 this.gotoUrl("form_move_release.asp", { rtag_id_list : data.rtagid, proj_id : <%=parProjId%> });

             },

<%End If%>

<%If bCanClone Then%>

             clone : function(data) {

                 console.log("Clone:", data.rtagid);

                 this.gotoUrl("new_release.asp", { rtag_id_list : data.rtagid, proj_id : <%=parProjId%> });

             },

<%End If%>

             //

             // Internal functions

             // Goto url, or open in new tab

             gotoUrl: function (url, params)

             {

                 // Open in new tab - not as simple as it sounds

                 // Need to create a form and submit it

                 if(event.shiftKey){

                     var form = $('<form>',{

                         action : url,

                         target : '_blank',

                         //method : 'GET'

                         });

                     $.each(params,function(n,v){

                         var item = $('<input>',{

                             name : n,

                             value : v

                         });

                         form.append(item);

                        });

                     form.appendTo(document.body);

                     form.submit();

                     form.remove();

                 }

                 else {

                     if (params)

                         url += '?' + jQuery.param(params)

                     window.location.href = url;

                 }

             },

             // Confirm action

             //     okcb - callback function

             confirmDelete : function(okcb){

                 $( "<div>Are you sure</div>" ).dialog({

                    resizable: true,

                    height:170,

                    width : 300,

                    modal: true,

                    position: { my: "top", at: "top+100", of: window },

                    title:'Destroy Release',

                    open: function() {

                        $(this).siblings('.ui-dialog-buttonpane').find('button:eq(1)').focus(); 

                        var markup = '<p><img src="images/i_critical.gif" style="float:left; margin:0 7px 20px 0;">This Release will be permanently destroyed.<p>Are you sure?';

                        $(this).html(markup);

                    },

                    close : function() {

                        $(this).remove();

                    },

                    buttons: {

                        "Destroy Release": function() {

                            okcb();

                            $(this).dialog("close");

                        },

                        Cancel: function() {

                            $(this).dialog("close");

                        }

                    }

                 });

             },

    };

    // Hide the Menu

    $( "#select-menu" ).hide().menu();

    // Register menuselect event handler

    $( "#select-menu" ).on( "menuselect", function( event, ui ) {

       var opr = ui.item.data('opr');

        // Invoke operation within the menu data structure

        if (typeof $.miniMenu[opr] == 'function' ) {

            $.miniMenu[event] = event;

            $.miniMenu[opr]($.miniMenu);

            return;

        }

        console.log ("Menu Operation:", opr, "Not found");

    });

    // Add menu to all require instances

   $( ".select-operation" ).click(function() {

        // When clicked - create and show the menu

        // Insert rtag-id

        //  Create the menu

        var menu = $("#select-menu").show().position({

         my: "left top",

         at: "center bottom",

         of: this 

    });

        // Allow click outside of the menu to close it

      $( document ).one( "click", function() {

        menu.hide();

        });

        // Setup global data

        $.miniMenu.rtagid = $(this).data('rtag-id');

        // Set initial menu state - merge target

        $('#select-menu-merge').toggleClass('ui-state-disabled',!('mergeLeft' in $.miniMenu ));

        // Set initial state close/archive

        //

        var official = $(this).data('official');

        $('#select-menu-close').toggleClass('ui-state-disabled',!($.miniMenu.bCanCloseArchive && ((official == 'A' && $.miniMenu.bCanUnarchive)|| (official != 'A' && official != 'Y' && official != 'O' && official != 'P'))));

        $('#select-menu-preserve').toggleClass('ui-state-disabled',!($.miniMenu.bCanCloseArchive && official != 'P'));

        $('#select-menu-archive').toggleClass('ui-state-disabled',!($.miniMenu.bCanCloseArchive && official != 'A'));

        // Prevent propagation of event

        return false;

    });

});

</script>

</head>

<body bgcolor="#FFFFFF" text="#000000" leftmargin="0" topmargin="0" >

<!-- MENU LAYERS -------------------------------------->

<div id="popmenu" class="menuskin" onMouseover="clearhidemenu();highlightmenu(event,'on')" onMouseout="highlightmenu(event,'off');dynamichide(event)">

</div>

<!-- TIPS LAYERS -------------------------------------->

<div id="formTipsLayer" style="position: absolute; z-index: 1000; visibility: hidden; left:0; top: 0; width: 10">&nbsp;</div>

<!----------------------------------------------------->

<!-- HEADER -->

<!--#include file="_header.asp"-->

<!-- BODY ---->

<%Call GetListFilterValues ( dListFilter )%>

<form name="FormName" method="post" action="<%=ScriptName%>">

<table width="100%" border="0" cellspacing="0" cellpadding="0">

   <tr>

      <td width="1" background="images/bg_home_orange.gif" valign="top">

         <!-- ICON STATUS and FILTER -------------------------------------->

         <table width="118" border="0" align="left" style="margin-top: 38px;">

            <tr>

               <td bgcolor="#E4E9EC" width="26"><span class="body_txt">Icon</span></td>

               <td bgcolor="#E4E9EC" width="82"><span class="body_txt">Release State </span></td>

            </tr>

            <tr>

               <td bgcolor="#F5F5F5"><img src="images/i_rtag_open_mode.gif" width="15" height="13"></td>

               <td bgcolor="#F5F5F5"><span class="body_txt"><input name="listFilter" type="checkbox" value="'<%=enumDB_RELEASE_IN_OPEN_MODE%>'" <%=GetIsListFilterChecked(enumDB_RELEASE_IN_OPEN_MODE)%>>Open Mode</span></td>

            </tr>

            <tr>

               <td bgcolor="#F5F5F5"><img src="images/i_rtag_restrictive_mode.gif" width="15" height="15"></td>

               <td nowrap bgcolor="#F5F5F5"><span class="body_txt"><input name="listFilter" type="checkbox" value="'<%=enumDB_RELEASE_IN_RESTRICTIVE_MODE%>'" <%=GetIsListFilterChecked(enumDB_RELEASE_IN_RESTRICTIVE_MODE)%>>Restrictive Mode</span></td>

            </tr>

            <tr>

               <td bgcolor="#F5F5F5"><img src="images/i_rtag_ccb_mode.gif" width="15" height="15"></td>

               <td bgcolor="#F5F5F5"><span class="body_txt"><input name="listFilter" type="checkbox" value="'<%=enumDB_RELEASE_IN_CCB_MODE%>'" <%=GetIsListFilterChecked(enumDB_RELEASE_IN_CCB_MODE)%>>CCB Mode</span></td>

            </tr>

            <tr>

               <td bgcolor="#F5F5F5"><img src="images/i_rtag_closed_mode.gif" width="15" height="14"></td>

               <td bgcolor="#F5F5F5"><span class="body_txt"><input name="listFilter" type="checkbox" value="'<%=enumDB_RELEASE_IN_CLOSED_MODE%>'" <%=GetIsListFilterChecked(enumDB_RELEASE_IN_CLOSED_MODE)%>>Closed Mode</span></td>

            </tr>

            <tr>

               <td bgcolor="#F5F5F5"><img src="images/i_rtag_closed_mode_warn.gif" width="15" height="14"></td>

               <td bgcolor="#F5F5F5"><span class="body_txt"><input name="listFilter" type="checkbox" value="'<%=enumDB_RELEASE_IN_CLOSED_WARN%>'" <%=GetIsListFilterChecked(enumDB_RELEASE_IN_CLOSED_WARN)%>>Closed Aged</span></td>

            </tr>

            <tr>

               <td bgcolor="#F5F5F5"><img src="images/i_rtag_preserve_mode.gif" width="15" height="14"></td>

               <td bgcolor="#F5F5F5"><span class="body_txt"><input name="listFilter" type="checkbox" value="'<%=enumDB_RELEASE_IN_PRESERVE_MODE%>'" <%=GetIsListFilterChecked(enumDB_RELEASE_IN_PRESERVE_MODE)%>>Preserve Mode</span></td>

            </tr>

            <tr>

               <td bgcolor="#F5F5F5"><img src="images/i_rtag_archive_mode.gif" width="15" height="14"></td>

               <td bgcolor="#F5F5F5"><span class="body_txt"><input name="listFilter" type="checkbox" value="'<%=enumDB_RELEASE_IN_ARCHIVE_MODE%>'" <%=GetIsListFilterChecked(enumDB_RELEASE_IN_ARCHIVE_MODE)%>>Archive Mode</span></td>

            </tr>

            <%If NOT bIsaTreeView Then%>

             <tr>

                <td>&nbsp;</td>

                <td><input name="btn" type="submit" class="form_btn" value="Update"></td>

             </tr>

             <%End If%>

         </table>

      </td>

      <td rowspan="2" valign="top" width="100%">

         <!-- ACTION BUTTONS ---------------------------------------------->

         <table width="100%"  border="0" cellspacing="0" cellpadding="7" style="background-color:#DAD7C8">

            <tr>

               <td width="1">

                  <%

                  If bIsaTreeView Then

                     Response.write LIMG_TREE_VIEW

                  Else

                     Response.write LIMG_LIST_VIEW

                  End If

                  %>

               </td>

               <td width="100%">

                  <%

                  Dim aBtnsDef

                  ' Define action buttons

                  aBtnsDef = Array("btnNewRelease", "width=5", "btnMergeManager", "width=5", "btnAdminView")

                  ' Load action buttons from database

                  Call objBtnControl.LoadActionButtons ( aBtnsDef, OraDatabase )

                  ' Set spacing to minimum between buttons

                  objBtnControl.ButtonSpacer = 0

                  objBtnControl.ImageHspace = 2

                  ' Access Control

                  If NOT canActionControlInProject("CreateNewRelease") Then Call objBtnControl.Active ( "btnNewRelease", "N" )

                  If NOT canActionControlInProject("DestroyRelease") Then Call objBtnControl.Active ( "btnDestroyRelease", "N" )

                  If NOT canActionControlInProject("ConfigureRelease") Then Call objBtnControl.Active ( "btnMoveRelease", "N" )

                  ' -- Render Buttons

                  Call objBtnControl.Render  ( aBtnsDef, objAccessControl )

                  %>

               </td>

            </tr>

         </table>

         <!-- ACTION BUTTONS END  ------------------------------------------>

         <!-- RELEASE INFORMATION  ----------------------------------------->

         <table width="100%"  border="0" cellspacing="10" cellpadding="0">

               <tr>

                  <td>

                     <!-- TREE VIEW ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->

                     <%If bIsaTreeView Then%>

                        <table width="100%"  border="0" cellspacing="1" cellpadding="1">

                           <tr>

                              <td width="25%" bgcolor="#E4E9EC" class="body_txt">Release Name </td>

                              <%If parProjId <> 2 Then %>

                                 <td width="15%" bgcolor="#E4E9EC" class="body_txt">Created</td>

                                 <td width="47%" bgcolor="#E4E9EC" class="body_txt">Comments</td>

                                 <td width="3%"  bgcolor="#E4E9EC" class="body_txt">Daemon Status</td>

                              <%Else%>

                                 <td width="15%" bgcolor="#E4E9EC" class="body_txt">Created</td>

                                 <td width="25%" bgcolor="#E4E9EC" class="body_txt">Used By </td>

                                 <td width="22%" bgcolor="#E4E9EC" class="body_txt">Comments</td>

                                 <td width="3%"  bgcolor="#E4E9EC" class="body_txt">Daemon Status</td>

                              <%End If%>

                           </tr>

                           <%

                           OraDatabase.Parameters.Add "PROJ_ID",  parProjId,  ORAPARM_INPUT, ORATYPE_NUMBER

                           Set rsQry = OraDatabase.DbCreateDynaset( GetQuery ("ReleaseVersionTree.sql") , ORADYN_DEFAULT )

                           lastLevel = 0

                           OraDatabase.Parameters.Remove "PROJ_ID"

                           Dim lastRtagId, parentRtag_id

                           If rsQry.RecordCount > 0 Then

                              Set objDmSts = New DaemonStatus

                              Call objDmSts.GetDaemonStatus(parProjId)

                              While (NOT rsQry.BOF) AND (NOT rsQry.EOF)

                                 currLevel = CInt(rsQry("hierarchy"))

                                 hoverTitle = "Last change: "& rsQry("OFFICIAL_STAMP") & " by " & rsQry("modifier")

                                 createdBy = rsQry("created_stamp") & " by " & rsQry("creator") 

                                 %>

                                 <tr>

                                    <td nowrap bgcolor="#F5F5F5" class="body_rowg">

                                       <%Call RenderIndent( lastLevel, currLevel )%>

                                       <%Call RenderActions(rsQry("rtag_id"),rsQry("official"))%>

                                       <a href="dependencies.asp?rtag_id=<%=rsQry("rtag_id")%>" class="body_link" title="<%=hoverTitle%>" >

                                       <%=ReleaseIcon( rsQry("official") )%>&nbsp;<%=rsQry("rtag_name")%></a>

                                    </td>

                                    <td nowrap bgcolor="#F5F5F5" class="body_rowg valign=top"><%=createdBy%></td>

                                    <%

                                    If parProjId = 2 Then

                                       comment = GetMassRefComments(rsQry("rtag_id"))

                                       If comment = "" Then comment = "None."

                                       %>

                                       <td bgcolor="#F5F5F5" class="body_rowg"><%=comment%></td>

                                    <%End If%>

                                    <td bgcolor="#F5F5F5" class="body_rowg"><%=NewLine_To_BR(rsQry("description"))%></td>

                                    <td bgcolor="#F5F5F5" class="body_rowg" valign=top>

                                       <%Call RenderDaemonStatusConfig(rsQry("rtag_id"))%>

                                    </td>

                                 </tr>

                                 <%

                                 lastLevel = currLevel

                                 rsQry.MoveNext

                              WEnd

                              Set objDmSts = Nothing

                           End If

                           rsQry.Close

                           Set rsQry = Nothing

                           %>

                        </table>

                     <!-- LIST VIEW ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->

                     <%Else%>

                        <table width="100%"  border="0" cellspacing="1" cellpadding="1">

                           <tr>

                              <td width="1%" bgcolor="#E4E9EC">&nbsp;</td>

                              <td width="20%" bgcolor="#E4E9EC" class="body_txt">Release Name </td>

                              <td width="10%" bgcolor="#E4E9EC" class="body_txt">"Created"</td>

                              <%If parProjId <> 2 Then %>

                                 <td width="47%" bgcolor="#E4E9EC" class="body_txt">Comments</td>

                              <%Else%>

                                 <td width="24%" bgcolor="#E4E9EC" class="body_txt">Used By </td>

                                 <td width="22%" bgcolor="#E4E9EC" class="body_txt">Comments</td>

                              <%End If%>

                              <td width="3%" bgcolor="#E4E9EC" class="body_txt">Daemon Status</td>

                           </tr>

                           <%

                              OraDatabase.Parameters.Add "PROJ_ID",  parProjId,  ORAPARM_INPUT, ORATYPE_NUMBER

                              rsQryStr = GetQuery ("ReleaseVersionList.sql")

                              rsQryStr = Replace(rsQryStr, "/*SHOW_FILTER*/", parShowFilter)

                              Set rsQry = OraDatabase.DbCreateDynaset( rsQryStr, ORADYN_DEFAULT )

                              OraDatabase.Parameters.Remove "PROJ_ID"

                              If rsQry.RecordCount > 0 Then

                                 Set objDmSts = New DaemonStatus

                                 Call objDmSts.GetDaemonStatus(parProjId)

                                 While (NOT rsQry.BOF) AND (NOT rsQry.EOF)

                                    hoverTitle = "Last change: "& rsQry("OFFICIAL_STAMP") & " by " & rsQry("modifier") & ". " & rsQry("OFFICIAL_STAMP_DAYS")& " Days ago"

                                    createdBy = rsQry("created_stamp") & " by " & rsQry("creator")

                                    %>

                                    <tr>

                                       <td bgcolor="#F5F5F5" class="body_txt" valign="top">

                                          <%Call RenderActions(rsQry("rtag_id"),rsQry("official"))%>

                                       </td>

                                       <td nowrap bgcolor="#F5F5F5" valign="top">

                                          <a href="dependencies.asp?rtag_id=<%=rsQry("rtag_id")%>" class="body_link" title="<%=hoverTitle%>">

                                          <%=ReleaseIcon( rsQry("official"))%>&nbsp;<%=rsQry("rtag_name")%></a>

                                       </td>

                                       <td nowrap bgcolor="#F5F5F5" class="body_rowg" valign=top><%=createdBy%></td>

                                       <%

                                       If parProjId = 2 Then

                                          comment = GetMassRefComments(rsQry("rtag_id"))

                                          If comment = "" Then comment = "None."

                                          %>

                                            <td bgcolor="#F5F5F5" class="body_rowg"><%=comment%></td>

                                       <%End If%>

                                       <td bgcolor="#F5F5F5" class="body_rowg"><%=NewLine_To_BR(  rsQry("description")   )%></td>

                                       <td bgcolor="#F5F5F5" class="body_rowg" valign=top>

                                          <%Call RenderDaemonStatusConfig(rsQry("rtag_id"))%>

                                       </td>

                                    </tr>

                                    <%

                                    rsQry.MoveNext

                                 WEnd

                                 Set objDmSts = Nothing

                              End If

                              rsQry.Close

                              Set rsQry = Nothing

                              %>

                        </table>

                        <%=objPMod.ComposeHiddenTags()%>

                        <input type="hidden" name="action" value="true">

                        </form>

                        <!-- MESSAGE +++++++++++++++++++++++++++++++++++++++++++++++++++ -->

                        <!--#include file="messages/_msg_inline.asp"-->

                        <!-- +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->

                     <%End If%>

                     <!-- LIST VIEW END ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->

                  </td>

               </tr>

         </table>

      </td>

      <td width="1" valign="top"><img src="images/h_trsp_dot.gif" width="1" height="1"></td>

   </tr>

   <tr>

      <td valign="bottom" align="center" background="images/bg_home_orange.gif">

      </td>

   </tr>

</table>

<!-- Dropdown Menu -->

<div >

  <ul id="select-menu" style="display:none;">

   <li data-opr="open" title="Goto this Release">Open ...</li>

    <li data-opr="edit" title="Edit the properties of the Release">Edit Properties</li>

    <li <%=iif(bCanMove,"data-opr=move","class=ui-state-disabled")%> title="Change the order in which releases are displayed">Change display order</li>

    <li>-</li>

    <li data-opr="mergeSelect" title="Select as the source (left side) of a merge or comparison">Select for Merge</li>

    <li id="select-menu-merge" data-opr="merge" title="Merge from selected release to this release">Merge from selected</li>

    <li>-</li>

    <li id="select-menu-close" data-opr="close">Close Release</li>

    <li id="select-menu-preserve" data-opr="preserve" >Preserve Release</li>

    <li id="select-menu-archive" data-opr="archive" >Archive Release</li>

    <li>-</li>

    <li <%=iif(bCanClone,"data-opr=clone","class=ui-state-disabled")%> title="Create a new Release based on selected Release">Clone Release</li>

    <li>-</li>

    <li <%=iif(bCanDestroy,"data-opr=delete","class=ui-state-disabled")%>  title="Delete the selected Release">Destroy Release</li>

    <li>-</li>

    <li>Close Menu</li>

  </ul>

</div>

<!-- FOOTER -->

<!--#include file="_footer.asp"-->

<map name="mapviewtype">

  <area shape="rect" coords="2,2,69,23" href="<%=ScriptName%>?viewtype=1&<%=objPMod.ComposeURL()%>" title="Switch to List View">

  <area shape="rect" coords="73,2,143,23" href="<%=ScriptName%>?viewtype=2&<%=objPMod.ComposeURL()%>" title="Switch to Tree View">

</map>

</body>

</html>

<%

Call Destroy_All_Objects

%>