Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>

<%

'=====================================================

'|                                                   |

'|				    	Move Release			     |

'|                                                   |

'=====================================================

%>

<%

Option explicit

' Good idea to set when using redirect

Response.Expires = 0	' always load the page, dont store

%>

<!--#include file="common/conf.asp"-->

<!--#include file="common/globals.asp"-->

<!--#include file="common/formating.asp"-->

<!--#include file="common/qstr.asp"-->

<!--#include file="common/common_subs.asp"-->

<!--#include file="common/_form_window_common.asp"-->

<!--#include file="common/_rtree_common.asp"-->

<%

' Set rfile parameter. This is a return page after Login

Call objPMod.StoreParameter ( "rfile", "rtree.asp" )

objPMod.PersistInQryString("proj_id")

'------------ ACCESS CONTROL ------------------

%>

<!--#include file="_access_control_login.asp"-->

<!--#include file="_access_control_general.asp"-->

<!--#include file="_access_control_project.asp"-->

<%

'------------ Variable Definition -------------

Dim objSortHelper

Dim rsQry

Dim parProjId

'------------ Constants Declaration -----------

'------------ Variable Init -------------------

parProjId = Request("proj_id")

objPMod.PersistInQryString("proj_id")

'----------------------------------------------

%>

<%

'--------------------------------------------------------------------------------------------------------------------------

Sub GetFormDetails ( nRtagId, ByRef outobjDetails )

	Dim rsQry, query

	OraDatabase.Parameters.Add "RTAG_ID", 	nRtagId,		ORAPARM_INPUT, ORATYPE_NUMBER 

	query = _

	" SELECT rt.* "&_

	"  FROM RELEASE_TAGS rt"&_

	" WHERE rt.RTAG_ID = :RTAG_ID"

	Set rsQry = OraDatabase.DbCreateDynaset( query, ORADYN_DEFAULT )

	OraDatabase.Parameters.Remove "RTAG_ID"

	If rsQry.RecordCount > 0 Then

		outobjDetails.Item ("rtag_id") = rsQry("rtag_id")

		outobjDetails.Item ("rtag_name") = rsQry("rtag_name")

		outobjDetails.Item ("description") = rsQry("description")

		outobjDetails.Item ("parent_rtag_id") = rsQry("parent_rtag_id")

		outobjDetails.Item ("proj_id") = rsQry("proj_id")

	Else

		Err.Raise 8, "Sub GetFormDetails in "& ScriptName, "Empty record set returned. nRtagId="& nRtagId

	End If

	rsQry.Close

	Set rsQry = Nothing

End Sub

'--------------------------------------------------------------------------------------------------------------------------

Sub MoveRelease ()

	Dim sRtagIdOrderList

	'-- Check cookie for new soring list

	If Request.Cookies("sort-list") = "" Then Exit Sub

	'-- Replace pipe separated values with comma for database use

	sRtagIdOrderList = Replace( Request.Cookies("sort-list") , "|", "," )

	On Error Resume Next

	OraDatabase.Parameters.Add "RTAG_ID_ORDER", 	sRtagIdOrderList, 			ORAPARM_INPUT, ORATYPE_VARCHAR2 

	OraDatabase.Parameters.Add "PROJ_ID", 			Request("proj_id"), 		ORAPARM_INPUT, ORATYPE_NUMBER 

	OraDatabase.Parameters.Add "USER_ID", 			objAccessControl.UserId, 	ORAPARM_INPUT, ORATYPE_NUMBER 

	objEH.TryORA ( OraSession )

	OraDatabase.ExecuteSQL _

	"BEGIN   PK_RELEASE.MOVE_RELEASE ( :RTAG_ID_ORDER, :PROJ_ID, :USER_ID );   END;"

	objEH.CatchORA ( OraSession )

	OraDatabase.Parameters.Remove "RTAG_ID_ORDER"

	OraDatabase.Parameters.Remove "PROJ_ID"

	OraDatabase.Parameters.Remove "USER_ID"

End Sub

'--------------------------------------------------------------------------------------------------------------------------

%>

<%

'------------ RUN BEFORE PAGE RENDER ----------

' --- Get Form details from DB ---

Call GetFormDetails ( Request("rtag_id_list"), objFormCollector )

' --- Load Validation Rules ---

'Call objForm.LoadValidationRules ( Array("rtag_name","rtag_description"), OraDatabase )		' Load Validation Rules

' --- Enter Form Validation Rule Changes here... ----

'----------------------------------------------------

' --- RUN onPostBack ---

If Request("action") <> "" Then

	If objForm.IsValidOnPostBack Then

		' --- Form is Valid ---

		Call MoveRelease()

		If objEH.Finally Then

			Call OpenInWindow ( "rtree.asp?DONE=OK&"& objPMod.ComposeURL() )

		End If

	End If

End If

'----------------------------------------------

%>

<html>

<head>

<title>Release Manager</title>

<link rel="shortcut icon" href="<%=FavIcon%>"/>

<meta HTTP-EQUIV="Pragma" CONTENT="no-cache">

<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">

<link rel="stylesheet" href="images/release_manager_style.css" type="text/css">

<link rel="stylesheet" href="images/navigation.css" type="text/css">

<script language="JavaScript" src="images/common.js"></script>

<!-- DROPDOWN MENUS -->

<!--#include file="_menu_def.asp"-->

<script language="JavaScript1.2" src="images/popup_menu.js"></script>

<!-- Drag and Drop modules +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->

<script language="JavaScript" type="text/javascript" src="scripts/dragdrop/tool-man/core.js"></script>

<script language="JavaScript" type="text/javascript" src="scripts/dragdrop/tool-man/events.js"></script>

<script language="JavaScript" type="text/javascript" src="scripts/dragdrop/tool-man/css.js"></script>

<script language="JavaScript" type="text/javascript" src="scripts/dragdrop/tool-man/coordinates.js"></script>

<script language="JavaScript" type="text/javascript" src="scripts/dragdrop/tool-man/drag.js"></script>

<script language="JavaScript" type="text/javascript" src="scripts/dragdrop/tool-man/dragsort.js"></script>

<script language="JavaScript" type="text/javascript" src="scripts/dragdrop/tool-man/cookies.js"></script>

<!-- +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->

<script language="JavaScript" type="text/javascript"><!--

	var dragsort = ToolMan.dragsort()

	var junkdrawer = ToolMan.junkdrawer()

	window.onload = function() {

		self.focus();

		dragsort.makeListSortable(document.getElementById("list"),

				verticalOnly, saveOrder);

	}

	function verticalOnly(item) {

		item.toolManDragGroup.verticalOnly()

	}

	function saveOrder(item) {

		var group = item.toolManDragGroup

		var list = group.element.parentNode

		var id = list.getAttribute("id")

		if (id == null) return

		group.register('dragend', function() {

			ToolMan.cookies().set("sort-" + id, 

					junkdrawer.serializeList(list), 365)

		})

	}

	//-->

</script>

</head>

<body bgcolor="#FFFFFF" text="#000000" leftmargin="0" topmargin="0">

<!-- MENU LAYERS -------------------------------------->

<div id="popmenu" class="menuskin" onMouseover="clearhidemenu();highlightmenu(event,'on')" onMouseout="highlightmenu(event,'off');dynamichide(event)"> 

</div>

<!-- TIPS LAYERS -------------------------------------->

<div id="formTipsLayer" style="position: absolute; z-index: 1000; visibility: hidden; left:0; top: 0; width: 10">&nbsp;</div>

<!----------------------------------------------------->

<!-- HEADER -->

<!--#include file="_header.asp"-->

<!-- BODY ---->

<table width="100%" border="0" cellspacing="0" cellpadding="0">

<%

'-- FROM START ---------------------------------------------------------------------------------------------------------

objFormComponent.FormName = "FormName"

objFormComponent.Action = ScriptName

Call objFormComponent.FormStart()

%>

  <tr> 

    <td width="1" background="images/bg_home_orange.gif" valign="top">

	</td>

	<td width="100%" rowspan="2" align="center" valign="top" bgcolor="#EEEFEF"><table width="10" border="0" cellspacing="0" cellpadding="0">

      <tr>

        <td width="1%"></td>

        <td width="100%">

          <table width="100%" border="0" cellspacing="0" cellpadding="0">

            <tr>

              <td nowrap class="form_ttl">MOVE RELEASES </td>

              <td align="right" valign="bottom"></td>

            </tr>

        </table></td>

        <td width="1%"></td>

      </tr>

      <tr>

        <td align="left" valign="top" background="images/lbox_bg_blue.gif"><img src="images/lbox_tl_cnr_b.gif" width="13" height="13"></td>

        <td background="images/lbox_bg_blue.gif" class="lbox_ttl_w"><img src="images/h_trsp_dot.gif" width="600" height="15"></td>

        <td align="right" valign="top"  background="images/lbox_bg_blue.gif"><img src="images/lbox_tr_cnr_b.gif" width="13" height="13"></td>

      </tr>

      <tr>

        <td bgcolor="#FFFFFF"><img src="images/h_trsp_dot.gif" width="10" height="100"></td>

        <td bgcolor="#FFFFFF" valign="top">

		<%

		Call Messenger ( "Click and Drag releases up/down.", 3, "100%" )

		%>

		<!-- MESSAGE +++++++++++++++++++++++++++++++++++++++++++++++++++ -->	

		<!--#include file="messages/_msg_inline.asp"-->

		<!-- +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->

		<br>

		<!-- SORT PRODUCT +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->		

		<ul id="list" class="boxy">

		<%

		OraDatabase.Parameters.Add "PARENT_RTAG_ID", 	objFormCollector.Item("parent_rtag_id"),	ORAPARM_INPUT, ORATYPE_NUMBER 

		OraDatabase.Parameters.Add "PROJ_ID", 			objFormCollector.Item("proj_id"),			ORAPARM_INPUT, ORATYPE_NUMBER 

		If (objFormCollector.Item("rtag_id") = objFormCollector.Item("parent_rtag_id")) Then

			Set rsQry = OraDatabase.DbCreateDynaset( GetQuery ("ReleaseRootElements.sql"), ORADYN_DEFAULT )

		Else

			Set rsQry = OraDatabase.DbCreateDynaset( GetQuery ("ReleaseChildrenElements.sql"), ORADYN_DEFAULT )

		End If

		OraDatabase.Parameters.Remove "PARENT_RTAG_ID"

		OraDatabase.Parameters.Remove "PROJ_ID"

		While (NOT rsQry.BOF) AND (NOT rsQry.EOF)

		%>

			<li id="<%=rsQry("rtag_id")%>"><%=ReleaseIcon( rsQry("official") )%>&nbsp;<%=rsQry("rtag_name")%></li>

		<%rsQry.MoveNext%>

		<%

		WEnd

		rsQry.Close()

		Set rsQry = Nothing

		%>

		</ul>

		<br>

		<!-- ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->

		</td>

        <td background="images/lbox_bgside_white.gif">&nbsp;</td>

      </tr>

	  <tr>

        <td background="images/bg_action_norm.gif" ></td>

        <td align="right" background="images/bg_action_norm.gif" >

		<%=objFormComponent.SubmitButton ( "Submit", "class='form_btn'" )%>&nbsp;

		<%=objFormComponent.CancelButton ( "Cancel", "class='form_btn'", "rtree.asp?CANCEL=OK&"& objPMod.ComposeURL() )%>

		<%=objPMod.ComposeHiddenTags()%>

		<input type="hidden" name="rtag_id_list" value="<%=Request("rtag_id_list")%>">

		<input type="hidden" name="action" value="true">

		</td>

        <td background="images/bg_action_norm.gif" ><img src="images/h_trsp_dot.gif" width="5" height="30"></td>

      </tr>

      <tr>

        <td background="images/lbox_bg_blue.gif" valign="bottom"><img src="images/lbox_bl_cnr_b.gif" width="13" height="13"></td>

        <td background="images/lbox_bg_blue.gif"></td>

        <td background="images/lbox_bg_blue.gif" valign="bottom" align="right"><img src="images/lbox_br_cnr_b.gif" width="13" height="13"></td>

      </tr>

    </table>

	<!-- ACTION BUTTONS ---------------------------------------------->

	<!-- ACTION BUTTONS END  ------------------------------------------></td>

	<td width="1" valign="top"><img src="images/h_trsp_dot.gif" width="1" height="1"></td>

  </tr>

  <tr> 

    <td valign="bottom" align="center" background="images/bg_home_orange.gif"><img src="images/img_vtree.gif" width="86" height="99" vspace="20" hspace="30"></td>

    <td background="images/bg_lght_gray.gif" valign="top"><img src="images/h_trsp_dot.gif" width="1" height="500"></td>

  </tr>

<%

Call objFormComponent.FormEnd()

'-- FROM END ----------------------------------------------------------------------------------------------------------------

%>   

</table>

<!-- FOOTER -->

<!--#include file="_footer.asp"-->

</body>

</html>

<%

Call Destroy_All_Objects

%>