Subversion Repositories DevTools

<%

'=====================================================

'|                                                   |

'|                 REPORTS DEFINITION                |

'|                                                   |

'=====================================================

' Good idea to set when using redirect

Response.Expires = 0   ' always load the page, dont store

'To enable the script timeout to 10 mins

Server.ScriptTimeout=600

%>

<%

'------------ ACCESS CONTROL ------------------

%>

<%

'------------ Variable Definition -------------

Dim rsQry

Dim rsTemp

Dim parPv_id, parExt

Dim objReleaseContent

Dim aReleaseContent

Dim objPackageDetails

Dim outobjDetails

Dim pvIdList

Dim dpv_id

Dim BldStd

'------------ Constants Declaration -----------

'------------ Variable Init -------------------

parExt = Request("ext")

Set objReleaseContent = CreateObject("Scripting.Dictionary")

Set objPackageDetails = CreateObject("Scripting.Dictionary")

Set outobjDetails = CreateObject("Scripting.Dictionary")

'----------------------------------------------------------------------------------------------------------------------------------------

Sub GetPackageInformation ( nPv_id, ByRef oPackageDetails )

   Dim rsQry, query

   query = _

   " SELECT pkg.pkg_name, pv.* "&_

   "  FROM PACKAGES pkg,"&_

   "       PACKAGE_VERSIONS pv"&_

   " WHERE pv.pv_id = "& nPv_id &_

   "   AND pv.pkg_id = pkg.pkg_id   "

   Set rsQry = OraDatabase.DbCreateDynaset( query, 0)

   oPackageDetails.RemoveAll

   If (NOT rsQry.BOF) AND (NOT rsQry.EOF) Then

      oPackageDetails("pkg_name") = rsQry("pkg_name")

      oPackageDetails("pkg_version") = rsQry("pkg_version")

      oPackageDetails("v_ext") = rsQry("v_ext")

      oPackageDetails("pv_description") = rsQry("pv_description")

      oPackageDetails("pv_overview") = rsQry("pv_overview")

      oPackageDetails("src_path") = rsQry("src_path")

      oPackageDetails("pkg_label") = rsQry("pkg_label")

      oPackageDetails("is_build_env_required") = rsQry("is_build_env_required")

   End If

   rsQry.Close()

   Set rsQry = Nothing

End Sub

'----------------------------------------------------------------------------------------------------------------------------------------

Function SQL_Build_Std ( nPv_id )

   SQL_Build_Std = _

   " SELECT bs.bs_name"&_

   "  FROM RELEASE_MANAGER.PACKAGE_VERSIONS pv,"&_

   "       RELEASE_MANAGER.BUILD_STANDARDS bs"&_

   " WHERE pv.PV_ID = "& nPv_id &_

   "   AND pv.BS_ID = bs.BS_ID "

End Function

'----------------------------------------------------------------------------------------------------------------------------------------

Function SQL_Build_Env ( nPv_id )

   SQL_Build_Env = _

   " SELECT bm.bm_name"&_

   "  FROM  RELEASE_MANAGER.PACKAGE_BUILD_INFO pbi,"&_

   "        RELEASE_MANAGER.BUILD_MACHINES bm"&_

   " WHERE pbi.PV_ID = "& nPv_id &_

   "   AND pbi.BM_ID = bm.BM_ID "&_

   " ORDER BY UPPER(bm.BM_NAME) "

End Function

'----------------------------------------------------------------------------------------------------------------------------------------

Function SQL_Modules (nPv_idList)

   SQL_Modules   = _

   "SELECT DISTINCT"&_

    "   qry.DPV_ID "&_

    " FROM ("&_

    "      SELECT dep.*,"&_

    "            LEVEL AS LEVEL_NUM"&_

    "        FROM PACKAGE_DEPENDENCIES dep"&_

    "      START WITH dep.PV_ID IN ( "& nPv_idList &" ) "&_

    "      CONNECT BY PRIOR dep.DPV_ID = dep.PV_ID"&_

    "   ) qry,"&_

    "   PACKAGES pkg,"&_

   "   PACKAGE_VERSIONS pv"&_

    " WHERE qry.PV_ID = pv.PV_ID AND pv.PKG_ID = pkg.PKG_ID"

End   Function

'----------------------------------------------------------------------------------------------------------------------------------------

Function SQL_Build_Dependencies ( nPv_id )

   SQL_Build_Dependencies = _

   " SELECT dpkg.pkg_name, dpv.pkg_version"&_

   "     FROM PACKAGE_DEPENDENCIES dep,"&_

   "           PACKAGES dpkg,"&_

   "         PACKAGE_VERSIONS dpv"&_

   "    WHERE dep.pv_id = "& nPv_id &_

   "      AND dep.DPV_ID = dpv.pv_id"&_

   "      AND dpv.pkg_id = dpkg.pkg_id   "&_

   "   ORDER BY UPPER(dpkg.pkg_name) "

End Function

'----------------------------------------------------------------------------------------------------------------------------------------

Sub GetReleaseContent ( nBom_id, ByRef oReleaseContent )

   Dim rsQry, query

   query = _

   " SELECT qry.prod_id"&_

   "  FROM ("&_

   "         SELECT DISTINCT"&_

   "          osc.PROD_ID,"&_

   "            pkg.pkg_name,"&_

   "         pv.pkg_version,"&_

   "         1   as   seq_num"&_

   "         FROM DEPLOYMENT_MANAGER.bom_contents bc,"&_

   "         DEPLOYMENT_MANAGER.operating_systems os, "&_

   "         DEPLOYMENT_MANAGER.os_contents osc,"&_

   "         PACKAGES pkg,"&_

   "         PACKAGE_VERSIONS pv,"&_

   "         DEPLOYMENT_MANAGER.PRODUCT_DETAILS pd"&_

   "          WHERE osc.os_id = os.os_id "&_

   "         AND os.node_id = bc.node_id"&_

   "         AND bc.bom_id =   "&   nBom_id &_

   "         AND pd.PROD_ID (+) = osc.PROD_ID"&_

   "         AND pv.pkg_id = pkg.pkg_id"&_

   "         AND osc.prod_id = pv.pv_id "&_

   "         AND (pd.is_rejected IS NULL or pd.IS_REJECTED != 'Y')  "&_

   "      UNION   "&_

   "      SELECT DISTINCT bec.prod_id,  pkg.pkg_name, pkg_version, 2   as   seq_num"&_

   "       FROM DEPLOYMENT_MANAGER.boms bm,"&_

   "            DEPLOYMENT_MANAGER.bom_contents bc,"&_

   "            DEPLOYMENT_MANAGER.network_nodes nn,"&_

   "            DEPLOYMENT_MANAGER.operating_systems os,"&_

   "            DEPLOYMENT_MANAGER.os_base_env obe,"&_

   "            DEPLOYMENT_MANAGER.base_env_contents bec,"&_

   "            PACKAGES pkg,"&_

   "            package_versions pv,"&_

   "            DEPLOYMENT_MANAGER.base_env be,"&_

   "            DEPLOYMENT_MANAGER.bos_types bt,"&_

   "            DEPLOYMENT_MANAGER.PRODUCT_DETAILS pd"&_

   "      WHERE bm.bom_id =   "&   nBom_id   &_

   "        AND bm.bom_id = bc.bom_id"&_

   "        AND nn.node_id = bc.node_id"&_

   "        AND os.node_id = nn.node_id"&_

   "        AND obe.os_id = os.os_id"&_

   "      AND pd.PROD_ID (+) = bec.PROD_ID"&_

   "      AND (pd.is_rejected IS NULL or pd.IS_REJECTED != 'Y')  "&_

   "        AND bec.base_env_id = obe.base_env_id"&_

   "        AND bec.prod_id = pv.pv_id"&_

   "        AND pkg.pkg_id = pv.pkg_id"&_

   "        AND be.base_env_id = obe.base_env_id"&_

   "       AND bt.bos_id = be.bos_id"&_

   "      ) qry  "&_

   " ORDER BY  qry.seq_num, UPPER(qry.pkg_name), UPPER(qry.pkg_version)"

   Set rsQry = OraDatabase.DbCreateDynaset( query, 0)

   While (NOT rsQry.BOF) AND (NOT rsQry.EOF)

      oReleaseContent( CStr( rsQry("prod_id")) ) = ""

      rsQry.MoveNext()

   WEnd

   rsQry.Close()

   Set rsQry = Nothing

End Sub

'----------------------------------------------------------------------------------------------------------------------------------------

Function PatchIcon ( cIsPatch, cIsPatchObsolete )

   If IsNull(cIsPatch) Then

      PatchIcon = "<img src='images/rex_images/ext_blank.gif' width='16' height='16' border='0' align='absmiddle'>"

   Else

      If IsNull(cIsPatchObsolete) Then

         PatchIcon = "<img src='images/i_patch_small.gif' width='16' height='16' border='0' align='absmiddle' >"

      Else

         PatchIcon = "<img src='images/i_patch_small_obsolete.gif' width='16' height='16' border='0' align='absmiddle' title='Patch is obsolete'>"

      End If

   End If

End Function

%>

<%

Sub Reports_List ( SSgroup )

   Dim repNum

%>  <!-- REPORTS LIST -------------------------------------------------------->

   <%Select Case SSgroup%>

   <%Case "Advanced_Search"%>

      <%repNum = 1%>

      <strong>Find ClearQuest Bugs / Issues Location</strong><br>

      Use this advance search to locate bugs / issues imported to Release Manager from ClearQuest.<br>

      <a href="rep_where_are_bugs_located.asp?repnum=<%=repNum%>&group=<%=SSgroup%>" class="txt_linked">more...</a><br><br><hr size="1" noshade color="#DAD7C8">

      <%repNum = 2%>

      <strong>Find Packages Using "Ignore Warnings" feature</strong><br>

      Lists packages which use "Ignore Warning" feature on their dependencies.<br>

      <a href="rep_packages_using_ignore_feature.asp?repnum=<%=repNum%>&group=<%=SSgroup%>" class="txt_linked">more...</a><br><br><hr size="1" noshade color="#DAD7C8">

      <%repNum = 4%>

      <strong>Find A Package</strong><br>

      Use this advanced search to find a package in Release Manager<br>

      <a href="rep_find_package.asp?repnum=<%=repNum%>&group=<%=SSgroup%>" class="txt_linked">more...</a><br><br><hr size="1" noshade color="#DAD7C8">

      <%repNum = 5%>

      <strong>Find Package Version History</strong><br>

      Find all package versions and their current locations.<br>

      <a href="rep_package_version_history.asp?repnum=<%=repNum%>&group=<%=SSgroup%>" class="txt_linked">more...</a><br><br><hr size="1" noshade color="#DAD7C8">

   <%Case "Release_Status"%>

      <%repNum = 3%>

      <strong>Current Status of Release</strong><br>

      Shows all packages in a selected release with their current state, owner and last modifier.<br>

      <a href="rep_current_state_of_release.asp?repnum=<%=repNum%>&group=<%=SSgroup%>" class="txt_linked">more...</a><br><br><hr size="1" noshade color="#DAD7C8">

      <%repNum = 8%>

      <strong>Deployable Software Modules</strong><br>

      This report shows new and current deployable software modules. Use this report to find which modules will be deployed to the customer.<br>

      Also, use this report to find if there are new modules flaged as 'deployable'.<br>

      <a href="rep_depoyable_software_modules.asp?repnum=<%=repNum%>&group=<%=SSgroup%>" class="txt_linked">more...</a><br><br><hr size="1" noshade color="#DAD7C8">

      <%repNum = 7%>

      <strong>Unit Tests per Package</strong><br>

      Use this report to check the unit tests performed on packages in a project.<br>

      <a href="rep_unit_tests_per_package.asp?repnum=<%=repNum%>&group=<%=SSgroup%>" class="txt_linked">more...</a><br><br><hr size="1" noshade color="#DAD7C8">

      <%repNum = 12%>

      <strong>Release AutoBuildable Status</strong><br>

      Use this report to check the package versions that are autobuildable/not autobuildable in a given release.<br>

      <a href="rep_autobuildable_package.asp?repnum=<%=repNum%>&group=<%=SSgroup%>" class="txt_linked">more...</a><br><br><hr size="1" noshade color="#DAD7C8">

      <%repNum = 13%>

      <strong>Release DEVI Status</strong><br>

      Use this report to obtain a list of DEVIs for all packages in a given release.<br>

      <a href="rep_devi_status_for_release.asp?repnum=<%=repNum%>&group=<%=SSgroup%>" class="txt_linked">more...</a><br><br><hr size="1" noshade color="#DAD7C8">

<!--    <strong>All Packages With out-of-sync Dependencies</strong><br>

   List of all packages with dependencies out-of-sync with the release environment.<br>

   In escence, these are the packages which has versions in "latest" column of their dependencies.<br>

   Not available yet.<br><br><hr size="1" noshade color="#DAD7C8">

 -->

   <%Case "Release_History"%>

      <%repNum = 10%>

      <strong>Build History</strong><br>

      Use this report to find which packages have been officially released within specified date range.<br>

      <a href="rep_build_history.asp?repnum=<%=repNum%>&group=<%=SSgroup%>" class="txt_linked">more...</a><br><br><hr size="1" noshade color="#DAD7C8">

   <%Case "Admin_Reports"%>

      <strong>All Packages by Project by Version Tree by Release</strong><br>

      CSV output of all packages used in Release Manager per Project.<br>

      <a href="rep_all_packages_by_project_by_vtree_by_release.asp" target="_blank" class="txt_linked">more...</a><br><br><hr size="1" noshade color="#DAD7C8">

      <strong>All Runtime Dependencies by Project by Version Tree by Release</strong><br>

      CSV output of all runtime dependencies used in Release Manager per Project.<br>

      <a href="rep_all_runtime_dependencies_by_project_by_vtree_by_release.asp" target="_blank" class="txt_linked">more...</a><br><br><hr size="1" noshade color="#DAD7C8">

      <%repNum = 6%>

      <strong>Unused Packages</strong><br>

      All packages (Not Products) with no entries in "Used By" tab.<br>

      Use this report to help you clean up a release and remove all potentially unused packages.<br>

      <a href="rep_obsolete_packages.asp?repnum=<%=repNum%>&group=<%=SSgroup%>" class="txt_linked">more...</a><br><br><hr size="1" noshade color="#DAD7C8">

   <%Case "Escrow"%>

      <%repNum = 9%>

      <strong>Bill of Materials (BOM)</strong><br>

      List of all ERG Products per network node for a particular

      project. Use this report to integrate a particular project.<br>

      <a href="rep_bill_of_materials.asp?repnum=<%=repNum%>&group=<%=SSgroup%>" class="txt_linked">more...</a><br><br><hr size="1" noshade color="#DAD7C8">

      <%repNum = 11%>

      <strong>Escrow Report</strong><br>

      List of all Products/Patches for the BOM including modules. Use this report to provide a build roadmap.<br>

      <a href="escrow_report.asp?repnum=<%=repNum%>&group=<%=SSgroup%>" class="txt_linked">more...</a><br><br><hr size="1" noshade color="#DAD7C8">

      <strong>Build Dependencies per Package</strong><br>

      Use this report to build package from source code. The report

      include package repository location, label and build dependencies.<br>

      Not available yet.<br><br><hr size="1" noshade color="#DAD7C8">

      <strong>Build Order</strong><br>

      Use this reports to find the order in which packages should be built.<br>

      Not available yet.<br><br><hr size="1" noshade color="#DAD7C8">

   <%Case Else%>

      <b>&laquo; Select reporting category.</b>

   <%End Select%>

   <!-- REPORTS LIST END-------------------------------------------------------->

<%End Sub%>

<%

'-------------------------------------------------------------------------------------------------------------------------------------------------------------------

Sub Get_Projects ( NNproj_id, BBallow_all )

   Dim rsTemp, Query_String

   Query_String = _

   "SELECT * FROM projects ORDER BY proj_name ASC"

   Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))

   Response.write "<select name='FRproj_id' onChange=""Cascaded_Menu('parent','"& scriptName &"?FRvtree_id=&FRrtag_id=&group="& Request("group") &"&repnum="& Request("repnum") &"&FRproj_id=',this,0)"" class='form_item'>"

      If BBallow_all Then

         Response.write "<option value='-1'>ALL</option>"

      Else

         Response.write "<option></option>"

      End If

      While ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF))

         If CDbl(NNproj_id) = CDbl(rsTemp.Fields("proj_id")) Then

              Response.write "<option value='"& rsTemp.Fields("proj_id") &"' selected>"& UCase(rsTemp.Fields("proj_name")) &"</option>"

           Else

            Response.write "<option value='"& rsTemp.Fields("proj_id") &"'>"& UCase(rsTemp.Fields("proj_name")) &"</option>"

         End If

         rsTemp.MoveNext

      WEnd

   Response.write "</select>"

   rsTemp.Close

   Set rsTemp = nothing

End Sub

'-------------------------------------------------------------------------------------------------------------------------------------------------------------------

Sub Get_Version_Trees ( NNproj_id, NNvtree_id, BBallow_all )

   Dim rsTemp, Query_String

   Query_String = _

   "SELECT vtree_id, vtree_name FROM vtrees WHERE hide = 'N' AND proj_id = "& NNproj_id &" ORDER BY vtree_id ASC"

   Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))

   Response.write "<select name='FRvtree_id' onChange=""Cascaded_Menu('parent','"& scriptName &"?FRproj_id="& NNproj_id &"&FRrtag_id=&group="& Request("group") &"&repnum="& Request("repnum") &"&FRvtree_id=',this,0)"" class='form_item'>"

      If BBallow_all Then

         Response.write "<option value='-1'>ALL</option>"

      Else

         Response.write "<option></option>"

      End If

      If NNproj_id <> -1 Then

         While ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF))

            If CDbl(NNvtree_id) = CDbl(rsTemp.Fields("vtree_id")) Then

                 Response.write "<option value='"& rsTemp.Fields("vtree_id") &"' selected>"& (rsTemp.Fields("vtree_name")) &"</option>"

              Else

               Response.write "<option value='"& rsTemp.Fields("vtree_id") &"'>"& (rsTemp.Fields("vtree_name")) &"</option>"

            End If

            rsTemp.MoveNext

         WEnd

      End If

   Response.write "</select>"

   rsTemp.Close

   Set rsTemp = nothing

End Sub

'-------------------------------------------------------------------------------------------------------------------------------------------------------------------

Sub Get_Open_Release_Labels ( NNproj_id, NNrtag_id, BBallow_all )

   Dim rsTemp, Query_String

   Query_String = _

   "SELECT rtag_id, rtag_name FROM release_tags WHERE proj_id = "& NNproj_id &"AND official in ('N','C','R')  ORDER BY rtag_name ASC"

   Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))

   Response.write "<select name='FRrtag_id' onChange=""Cascaded_Menu('parent','"& scriptName &"?FRproj_id="& NNproj_id &"&group="& Request("group") &"&repnum="& Request("repnum") &"&FRrtag_id=',this,0)"" class='form_item'>"

   If BBallow_all Then

      Response.write "<option value='-1'>ALL</option>"

   Else

      Response.write "<option></option>"

   End If

      If NNproj_id <> -1 Then

         While ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF))

            If CDbl(NNrtag_id) = CDbl(rsTemp.Fields("rtag_id")) Then

                 Response.write "<option value='"& rsTemp.Fields("rtag_id") &"' selected>"& (rsTemp.Fields("rtag_name")) &"</option>"

              Else

               Response.write "<option value='"& rsTemp.Fields("rtag_id") &"'>"& (rsTemp.Fields("rtag_name")) &"</option>"

            End If

            rsTemp.MoveNext

         WEnd

      End If

   Response.write "</select>"

   rsTemp.Close

   Set rsTemp = nothing

End Sub

Sub Get_Release_Labels ( NNproj_id, NNrtag_id, BBallow_all )

   Dim rsTemp, Query_String

   Query_String = _

   "SELECT rtag_id, rtag_name FROM release_tags WHERE proj_id = "& NNproj_id &" ORDER BY rtag_id ASC"

   Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))

   Response.write "<select name='FRrtag_id' onChange=""Cascaded_Menu('parent','"& scriptName &"?FRproj_id="& NNproj_id &"&group="& Request("group") &"&repnum="& Request("repnum") &"&FRrtag_id=',this,0)"" class='form_item'>"

   If BBallow_all Then

      Response.write "<option value='-1'>ALL</option>"

   Else

      Response.write "<option></option>"

   End If

      If NNproj_id <> -1 Then

         While ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF))

            If CDbl(NNrtag_id) = CDbl(rsTemp.Fields("rtag_id")) Then

                 Response.write "<option value='"& rsTemp.Fields("rtag_id") &"' selected>"& (rsTemp.Fields("rtag_name")) &"</option>"

              Else

               Response.write "<option value='"& rsTemp.Fields("rtag_id") &"'>"& (rsTemp.Fields("rtag_name")) &"</option>"

            End If

            rsTemp.MoveNext

         WEnd

      End If

   Response.write "</select>"

   rsTemp.Close

   Set rsTemp = nothing

End Sub

'-------------------------------------------------------------------------------------------------------------------------------------------------------------------

Sub Get_SBOM_Version ( NNproj_id, NNrtag_id, BBallow_all, NNversion )

   Dim rsTemp, Query_String

   Query_String = _

   "SELECT BOM_ID, BRANCH_ID, BOM_VERSION ||'.'||BOM_LIFECYCLE AS VERSION FROM DEPLOYMENT_MANAGER.BOMS WHERE BRANCH_ID ="&NNrtag_id&" ORDER BY VERSION"

   Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))

   Response.write "<select name='FRversion' class='form_item'>"

   If BBallow_all Then

      Response.write "<option value='-1'>ALL</option>"

   Else

      Response.write "<option></option>"

   End If

      If NNrtag_id <> -1 Then

         While ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF))

            If CStr(NNversion) = CStr(rsTemp.Fields("version")) Then

                 Response.write "<option value='"& rsTemp.Fields("version") &"' selected>"& (rsTemp.Fields("version")) &"</option>"

              Else

               Response.write "<option value='"& rsTemp.Fields("version") &"'>"& (rsTemp.Fields("version")) &"</option>"

            End If

            rsTemp.MoveNext

         WEnd

      End If

   Response.write "</select>"

   rsTemp.Close

   Set rsTemp = nothing

End Sub

'-------------------------------------------------------------------------------------------------------------------------------------------------------------------

Sub Get_Branches ( NNproj_id, NNrtag_id, BBallow_all )

   Dim rsTemp, Query_String

   Query_String = _

   "SELECT * FROM deployment_manager.branches WHERE proj_id = "& NNproj_id &" ORDER BY branch_id ASC"

   Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))

   Response.write "<select name='FRbranch_id' onChange=""Cascaded_Menu('parent','"& scriptName &"?FRproj_id="& NNproj_id &"&group="& Request("group") &"&repnum="& Request("repnum") &"&FRrtag_id=',this,0)"" class='form_item'>"

   If BBallow_all Then

      Response.write "<option value='-1'>ALL</option>"

   Else

      Response.write "<option></option>"

   End If

      If NNproj_id <> -1 Then

         While ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF))

            If CDbl(NNrtag_id) = CDbl(rsTemp.Fields("branch_id")) Then

                 Response.write "<option value='"& rsTemp.Fields("branch_id") &"' selected>"& (rsTemp.Fields("branch_name")) &"</option>"

              Else

               Response.write "<option value='"& rsTemp.Fields("branch_id") &"'>"& (rsTemp.Fields("branch_name")) &"</option>"

            End If

            rsTemp.MoveNext

         WEnd

      End If

   Response.write "</select>"

   rsTemp.Close

   Set rsTemp = nothing

End Sub

'-------------------------------------------------------------------------------------------------------------------------------------------------------------------

Sub Get_Base_Views ( nRtag_id, nBase_view_id, BBallow_all )

   Dim rsTemp, Query_String

   Query_String = _

   "SELECT DISTINCT vi.view_id, vi.view_name"&_

   "  FROM VIEWS vi,"&_

   "         RELEASE_CONTENT rc"&_

   " WHERE rc.BASE_VIEW_ID = vi.VIEW_ID"&_

   "   AND rc.rtag_id = "& nRtag_id &_

   "ORDER BY UPPER( vi.view_name )"

   Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))

   Response.write "<select name='FRbase_view_id' class='form_item'>"

   If BBallow_all Then

      Response.write "<option value='-1'>ALL</option>"

   Else

      Response.write "<option></option>"

   End If

      If nRtag_id <> -1 Then

         While ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF))

            If CDbl(nBase_view_id) = CDbl(rsTemp.Fields("view_id")) Then

                 Response.write "<option value='"& rsTemp.Fields("view_id") &"' selected>"& (rsTemp.Fields("view_name")) &"</option>"

              Else

               Response.write "<option value='"& rsTemp.Fields("view_id") &"'>"& (rsTemp.Fields("view_name")) &"</option>"

            End If

            rsTemp.MoveNext

         WEnd

      End If

   Response.write "</select>"

   rsTemp.Close

   Set rsTemp = nothing

End Sub

%>

<%

'-------------------------------------------------------------------------------------------------------------------------------------------------------------------

'==================================================================================

' Report Name      :    Packages Using Ignore Feature

' Description      :   Lists packages which use "Ignore Warning"

'                  feature on their dependencies.

' INPUT            :   Project, Vesion Tree, Release Label

'==================================================================================

Sub Packages_Using_Ignore_Feature ( SSsection, NNproj_id, NNrtag_id )

   Dim Query_String, rsRep

   Const Allow_All = TRUE

   If NNproj_id = "" Then NNproj_id = -1

   If NNrtag_id = "" Then NNrtag_id = -1

   If SSsection = "TITLE" Then

      Response.write "Packages Using 'Ignore Warnings' Feature"

      Exit Sub

   End If

   If SSsection = "FORM" Then

      %>

      <table width="100%" border="0" cellpadding="2" cellspacing="1">

         <form action="<%=scriptName%>" method="post" name="repform">

            <tr>

               <td width="1%" nowrap class="form_field"><img src="images/spacer.gif" width="30" height="8"></td>

               <td width="1%" align="right" nowrap class="form_field">Project</td>

               <td width="100%"><%Call Get_Projects( NNproj_id, Allow_All )%></td>

            </tr>

            <tr>

               <td nowrap class="form_field">&nbsp;</td>

               <td align="right" nowrap class="form_field">Release</td>

               <td><%Call Get_Release_Labels ( NNproj_id,  NNrtag_id, Allow_All )%></td>

            </tr>

            <tr>

               <td nowrap class="form_field">&nbsp;</td>

               <td align="right" nowrap class="form_field">&nbsp;</td>

               <td><br>

                  <input type="hidden" name="group" value="<%=parGroup%>">

                  <input type="hidden" name="repnum" value="<%=parRepNum%>">

                  <input type="hidden" name="action" value="true">

                  <input name="Submit" type="submit" class="form_btn" value="Submit">

               </td>

            </tr>

         </form>

      </table>

      <%   Exit Sub

   End If

   If SSsection = "BODY" Then

      If NOT CBool(Request("action")) Then Exit Sub

      Query_String = ReadFile( rootPath & "queries\rep_packages_using_ignore_feature.sql" )

      OraDatabase.Parameters.Add "PROJ_ID", NNproj_id, ORAPARM_INPUT, ORATYPE_NUMBER

      OraDatabase.Parameters.Add "RTAG_ID", NNrtag_id, ORAPARM_INPUT, ORATYPE_NUMBER

      %>

      <table width="100%" border="0" cellspacing="0" cellpadding="2">

         <tr>

            <td width="1%" nowrap class="body_colb">&nbsp;</td>

            <td width="1%" nowrap class="body_colb">Package Name&nbsp;&nbsp;&nbsp;</td>

            <td width="1%" nowrap class="body_colb">Version&nbsp;&nbsp;&nbsp;</td>

            <td width="100%" nowrap class="body_colb">&nbsp;</td>

         </tr>

         <tr>

         <td colspan="4" background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

         </tr>

         <%

         Dim currRtag_id

         currRtag_id = -1

         Set rsRep = OraDatabase.DbCreateDynaset( Query_String, 0 )

         If rsRep.RecordCount = 0 Then

            With Response

               .write "<tr>"

               .write "<td colspan='4' class='body_row'>Found 0 records</td>"

               .write "</tr>"

            End With

         End If

         While ((NOT rsRep.BOF) AND (NOT rsRep.EOF))

            ' -------- GROUP BY RTAG_ID -----------------

            If CDbl(currRtag_id) <> CDbl(rsRep("rtag_id")) Then

               %>

               <tr>

                  <td colspan="3" background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

               <td></td>

               </tr>

               <tr>

                  <td colspan="4" nowrap class="body_scol"><%=rsRep("proj_name")  &" &gt; "& rsRep("rtag_name")%></td>

               </tr>

               <%

               currRtag_id = CDbl(rsRep("rtag_id"))

            End If

            ' -------- END GROUP ------------------------

            %>

            <tr>

               <td class="body_row"></td>

               <td nowrap><a href="dependencies.asp?rtag_id=<%=rsRep("rtag_id")%>&pv_id=<%=rsRep("pv_id")%>" class="txt_linked"><%=rsRep("pkg_name")%></a></td>

               <td nowrap><a href="dependencies.asp?rtag_id=<%=rsRep("rtag_id")%>&pv_id=<%=rsRep("pv_id")%>" class="txt_linked"><%=rsRep("pkg_version")%></a></td>

               <td class="body_row"></td>

            </tr>

            <%  rsRep.MoveNext

         WEnd

         %>

         <tr>

            <td colspan="3" background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

            <td></td>

         </tr>

         <tr>

            <td colspan="4" background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

         </tr>

      </table>

      <!-- PRINT, SAVE, ETC. ------------>

      <%If parPrint = "" Then%>

         <br>

         <br>

         <a href="javascript:;" onClick="window.print();" class="txt_linked"><img src="images/btn_print.gif" width="23" height="24" hspace="4" border="0" align="absmiddle">Print this report</a><br>

         <br>

      <%End If%>

      <!-- PRINT, SAVE, ETC. END -------->

      <%

      rsRep.Close

      Set rsRep = nothing

   End If

End Sub

%>

<%

'-------------------------------------------------------------------------------------------------------------------------------------------------------------------

'==================================================================================

' Report Name      :    Current State of Release

' Description      :   Show all packages in a release with their state, owner and modifier

' Form Input      :   Project, Vesion Tree, Release Label

' SQL INPUT         :   rtag_id

'==================================================================================

Sub Current_State_of_Release ( SSsection, NNproj_id, NNrtag_id, NNpkg_states )

   Dim Query_String, rsRep

   Const Disallow_All = FALSE

   If NNproj_id = "" Then NNproj_id = -1

   If NNrtag_id = "" Then NNrtag_id = -1

   If NNpkg_states = "" Then NNpkg_states = -1

   If SSsection = "TITLE" Then

      Response.write "Current State of Release"

      Exit Sub

   End If

   If SSsection = "FORM" Then

      %>

      <table width="100%" border="0" cellpadding="2" cellspacing="1">

         <form action="<%=scriptName%>" method="post" name="repform" onSubmit="MM_validateForm('FRproj_id','Project','R','FRvtree_id','Version Tree','R','FRrtag_id','Release','R');return document.MM_returnValue">

            <tr>

               <td width="1%" nowrap class="form_field"><img src="images/spacer.gif" width="30" height="8"></td>

               <td width="1%" align="right" nowrap class="form_field">Project</td>

               <td width="100%"><%Call Get_Projects( NNproj_id, Disallow_All )%></td>

            </tr>

            <tr>

               <td nowrap class="form_field">&nbsp;</td>

               <td align="right" nowrap class="form_field">Release</td>

               <td><%Call Get_Release_Labels ( NNproj_id, NNrtag_id, Disallow_All )%></td>

            </tr>

            <tr>

               <td nowrap class="form_field">&nbsp;</td>

               <td align="right" nowrap class="form_field">Package States</td>

               <td class="form_field" nowrap>

                  <span style="border: 1px solid #808080;">&nbsp;OK&nbsp;<input type="checkbox" name="FRpkg_state" value="<%=enumPKG_STATE_OK%>" <%If InStr( Request("FRpkg_state"), Cstr(enumPKG_STATE_OK) ) > 0 Then%>checked<%End If%>></span>&nbsp;&nbsp;

                  <span style="border: 1px solid #808080;"><%=enum_imgCritical%><input type="checkbox" name="FRpkg_state" value="<%=enumPKG_STATE_MAJOR%>" <%If InStr( Request("FRpkg_state"), Cstr(enumPKG_STATE_MAJOR) ) > 0 Then%>checked<%End If%>></span>&nbsp;&nbsp;

                  <span style="border: 1px solid #808080;"><%=enum_imgWarning%><input type="checkbox" name="FRpkg_state" value="<%=enumPKG_STATE_MINOR%>" <%If InStr( Request("FRpkg_state"), Cstr(enumPKG_STATE_MINOR) ) > 0 Then%>checked<%End If%>></span>&nbsp;&nbsp;

                  <span style="border: 1px solid #808080;"><%=enum_imgCReady%><input type="checkbox" name="FRpkg_state" value="<%=enumPKG_STATE_MAJOR_READY%>" <%If InStr( Request("FRpkg_state"), Cstr(enumPKG_STATE_MAJOR_READY) ) > 0 Then%>checked<%End If%>></span>&nbsp;&nbsp;

                  <span style="border: 1px solid #808080;"><%=enum_imgWReady%><input type="checkbox" name="FRpkg_state" value="<%=enumPKG_STATE_MINOR_READY%>" <%If InStr( Request("FRpkg_state"), Cstr(enumPKG_STATE_MINOR_READY) ) > 0 Then%>checked<%End If%>></span>&nbsp;&nbsp;

               </td>

            </tr>

            <tr>

               <td nowrap class="form_field">&nbsp;</td>

               <td align="right" nowrap class="form_field">&nbsp;</td>

               <td><br>

                  <input type="hidden" name="group" value="<%=parGroup%>">

                  <input type="hidden" name="repnum" value="<%=parRepNum%>">

                  <input type="hidden" name="action" value="true">

                  <input name="Submit" type="submit" class="form_btn" value="Submit">

               </td>

            </tr>

         </form>

      </table>

      <%   Exit Sub

   End If

   If SSsection = "BODY" Then

      If NOT CBool(Request("action")) Then Exit Sub

      Query_String = ReadFile( rootPath & "queries\rep_details_current_status_of_release.sql" )

      Query_String = Replace ( Query_String, "/*PKG_STATES*/", NNpkg_states )

      OraDatabase.Parameters.Add "RTAG_ID", NNrtag_id, ORAPARM_INPUT, ORATYPE_NUMBER

      %>

      <table width="100%" border="0" cellspacing="0" cellpadding="2">

         <tr>

            <td width="1%" nowrap class="body_colb">&nbsp;</td>

            <td width="1%" nowrap class="body_colb">&nbsp;</td>

            <td width="1%" nowrap class="body_colb">&nbsp;</td>

            <td width="1%" nowrap class="body_colb">Package Name and Version&nbsp;&nbsp;&nbsp;</td>

            <td width="1%" nowrap class="body_colb">Owner&nbsp;&nbsp;&nbsp;</td>

            <td width="1%" nowrap class="body_colb">Last Modifier&nbsp;&nbsp;&nbsp;</td>

            <td width="1%" nowrap class="body_colb">Added to Release&nbsp;&nbsp;&nbsp;</td>

            <td width="100%" nowrap class="body_colb">&nbsp;</td>

         </tr>

         <tr>

         <td colspan="8" background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

         </tr>

         <%

         Dim currView_id

         currView_id = -1

         Set rsRep = OraDatabase.DbCreateDynaset( Query_String, 0 )

         If rsRep.RecordCount = 0 Then

            With Response

               .write "<tr>"

               .write "<td colspan='8' class='body_row'>Found 0 records</td>"

               .write "</tr>"

            End With

         End If

         While ((NOT rsRep.BOF) AND (NOT rsRep.EOF))

            ' -------- GROUP BY RTAG_ID -----------------

            If CDbl(currView_id) <> CDbl(rsRep("view_id")) Then

               %>

               <tr>

                  <td colspan="7" background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

                  <td></td>

               </tr>

               <tr>

                  <td colspan="8" nowrap class="body_scol"><%=rsRep("view_name")%></td>

               </tr>

               <%

               currView_id = CDbl(rsRep("view_id"))

            End If

            ' -------- END GROUP ------------------------

            %>

            <tr>

               <td class="body_row"></td>

               <td><%=DefineStateIcon ( rsRep("pkg_state"), rsRep("dlocked"), NULL, NULL, NULL, NULL )%></td>

               <%If rsRep("dlocked") = "Y" Then%>

                  <td align="center" class="form_item"><img src='images/i_locked.gif' width='7' height='10' hspace='6'></td>

               <%Else%>

                  <td align="center" class="form_item"><img src='images/spacer.gif' width='7' height='10' hspace='6'></td>

               <%End If%>

               <td nowrap class="body_row"><%=rsRep("pkg_name") &" "& rsRep("pkg_version")%></td>

               <td nowrap><a href="mailto:<%=rsRep("owner_email")%>" class="txt_linked"><%=rsRep("owner")%></a>&nbsp;&nbsp;&nbsp;</td>

               <td nowrap><a href="mailto:<%=rsRep("modifier_email")%>" class="txt_linked"><%=rsRep("modifier")%></a>&nbsp;&nbsp;&nbsp;</td>

               <td class="body_row"><%=EuroDate( rsRep("insert_stamp") )%></td>

               <td class="body_row"></td>

            </tr>

            <%  rsRep.MoveNext

         WEnd

         %>

         <tr>

            <td colspan="8" background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

         </tr>

      </table>

      <!-- PRINT, SAVE, ETC. ------------>

      <%If parPrint = "" Then%>

         <br>

         <br>

         <a href="javascript:;" onClick="window.print();" class="txt_linked"><img src="images/btn_print.gif" width="23" height="24" hspace="4" border="0" align="absmiddle">Print this report</a><br>

         <br>

      <%End If%>

      <!-- PRINT, SAVE, ETC. END -------->

      <%

      rsRep.Close

      Set rsRep = nothing

   End If

End Sub

%>

<%

'-------------------------------------------------------------------------------------------------------------------------------------------------------------------

'==================================================================================

' Report Name      :    Find ClearQuest Bugs / Issues Location

' Description      :   Locates bugs / issues imported from ClearQuest

' Form Input      :   CQ issue Database, CQ issue number list space separated

'==================================================================================

Sub Where_Are_Bugs_Located ( SSsection, NNiss_db, SSiss_num_list )

   Dim Query_String, rsRep

   If SSsection = "TITLE" Then

      Response.write "Find ClearQuest Bugs / Issues Location"

      Exit Sub

   End If

   If SSsection = "FORM" Then

      %>

      <table width="100%" border="0" cellpadding="2" cellspacing="1">

         <form action="<%=scriptName%>" method="post" name="repform" onSubmit="MM_validateForm('FRiss_num_list','Issue Number','R');return document.MM_returnValue">

            <tr>

               <td width="1%" nowrap class="form_field"><img src="images/spacer.gif" width="30" height="8"></td>

               <td width="1%" align="right" nowrap class="form_field" valign="top">ClearQuest Database</td>

               <td width="100%">

                  <select name="FRiss_db" class="form_item">

                     <option value="<%=enumCLEARQUEST_DEVI_ID%>" <%If CDbl(NNiss_db) = enumCLEARQUEST_DEVI_ID Then%>selected<%End If%>>DEVI</option>

                  </select>

               </td>

            </tr>

            <tr>

               <td nowrap class="form_field">&nbsp;</td>

               <td align="right" nowrap class="form_field" valign="top">Issue Numbers</td>

               <td class="form_txt"><input type="text" name="FRiss_num_list" size="50" class="form_item" value="<%=SSiss_num_list%>"><br>

               HINTS:<br>

               - You can use * wildcard. e.g. *0123 or 0123* or *0123*<br>

               - Use space separated issue numbers for multiple search.</td>

            </tr>

            <tr>

               <td nowrap class="form_field">&nbsp;</td>

               <td align="right" nowrap class="form_field">&nbsp;</td>

               <td><br>

                  <input type="hidden" name="group" value="<%=parGroup%>">

                  <input type="hidden" name="repnum" value="<%=parRepNum%>">

                  <input type="hidden" name="action" value="true">

                  <input name="Submit" type="submit" class="form_btn" value="Submit">

               </td>

            </tr>

         </form>

      </table>

      <%   Exit Sub

   End If

   If SSsection = "BODY" Then

      If NOT CBool(Request("action")) Then Exit Sub

      Dim SSsql, issARR, num_item, iss_num_col, issNumDict, rsCQ, recCount, maxRecCount

      Set rsCQ = Server.CreateObject("ADODB.Recordset")

      Set issNumDict = CreateObject("Scripting.Dictionary")

      '---- Find Issue numbers in ClearQuest ----

      If CDbl(NNiss_db) = enumCLEARQUEST_DEVI_ID Then

         iss_num_col = "new_num"

         SSsql = _

         " SELECT si.dbid AS iss_id, si."& iss_num_col &" AS iss_num"&_

         " FROM CQ_DEVI.admin.software_issue si"&_

         " WHERE "

      End If

      '---- Split multiple search ----

      SSiss_num_list = Trim(SSiss_num_list)

      If InStr( SSiss_num_list, " " ) > 0 Then

         ' space separator found

         issARR = Split ( SSiss_num_list, " ")

         For Each num_item In issARR

            If num_item <> "" Then

               SSsql = SSsql & " (si."& iss_num_col &" LIKE '%"& Replace( SQLstring(num_item), "*", "%" ) &"%') OR"

            End If

         Next

         SSsql = Left ( SSsql, Len(SSsql) - 2 )      ' Removes last OR

      Else

         SSsql = SSsql & " (si."& iss_num_col &" LIKE '%"& Replace( SQLstring(SSiss_num_list), "*", "%") &"%')"

      End If

      rsCQ.ActiveConnection = CQ_conn

      rsCQ.Source = SSsql

      rsCQ.CursorType = 0

      rsCQ.CursorLocation = 2

      rsCQ.LockType = 3

      rsCQ.Open()

      ' Get find results from CQ

      recCount = 1

      maxRecCount = 1000

      issNumDict.ADD "-1", "-1"      ' take care of no results

      While ((NOT rsCQ.BOF) AND (NOT rsCQ.EOF) AND (recCount < maxRecCount))

         issNumDict.ADD Cstr(rsCQ("iss_id")), Cstr(rsCQ("iss_num"))

         recCount = recCount + 1

         rsCQ.MoveNext

      WEnd

      rsCQ.Close

      Set rsCQ = nothing

      Query_String = ReadFile( rootPath & "queries\rep_where_are_bugs_located.sql" )

      Query_String = Replace ( Query_String, "/*ISS_DB*/", NNiss_db )

      Query_String = Replace ( Query_String, "/*ISS_ID_LIST*/", Join( issNumDict.Keys, ",") )

      %>

      <table width="100%" border="0" cellspacing="0" cellpadding="2">

         <tr>

            <td width="1%" nowrap class="body_colb">Issue Number&nbsp;&nbsp;&nbsp;</td>

            <td width="1%" nowrap class="body_colb">Fixed</td>

            <td width="1%" nowrap class="body_colb">Package Name and Version&nbsp;&nbsp;&nbsp;</td>

            <td width="1%" nowrap class="body_colb">Notes&nbsp;&nbsp;&nbsp;</td>

            <td width="100%" nowrap class="body_colb">&nbsp;</td>

         </tr>

         <tr>

         <td colspan="5" background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

         </tr>

         <%

         Dim currIss_id

         currIss_id = -1

         Set rsRep = OraDatabase.DbCreateDynaset( Query_String, 0 )

         If rsRep.RecordCount = 0 Then

            With Response

               .write "<tr>"

               .write "<td colspan='5' class='body_row'>Found 0 records</td>"

               .write "</tr>"

            End With

         End If

         While ((NOT rsRep.BOF) AND (NOT rsRep.EOF))

            ' -------- GROUP BY ISS_ID -----------------

            If Cstr(currIss_id) <> Cstr(rsRep("iss_id")) Then

               %>

               <tr>

                  <td colspan="5" background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

                  <td></td>

               </tr>

               <tr>

                  <td nowrap><a href="javascript:;" onClick="MM_openBrWindow('_wform_issues_details.asp?iss_db=<%=NNiss_db%>&iss_id=<%= rsRep("iss_id")%>','IssueDetails','resizable=yes,width=580,height=500')" class="body_scol"><img src="images/i_drill_down.gif" width="12" height="14" hspace="3" border="0" align="absmiddle" alt="See issue details."><%=issNumDict.Item ( Cstr ( rsRep("iss_id") ) )%></a></td>

                  <td colspan='5' class="body_scol"></td>

               </tr>

               <%

               currIss_id = Cstr(rsRep("iss_id"))

            End If

            ' -------- END GROUP ------------------------

            %>

            <tr>

               <td nowrap class="body_row" valign="top"></td>

               <%If CDbl(rsRep("iss_state")) = enumISSUES_STATE_FIXED Then%>

                  <td align="left"><img src="images/i_tick.gif" width="7" height="7" hspace="6"></td>

               <%Else%>

                  <td align="left"><img src='images/spacer.gif' width='7' height='7' hspace='6'></td>

               <%End If%>

               <td nowrap align="left" class="body_row" valign="top"><%=rsRep("pkg_name") &" "& rsRep("pkg_version")%><img src="images/i_drill_down.gif" width="12" height="14" hspace="3" border="0" align="absmiddle" alt="Find this package."></td>

               <%

               Set rsQry = OraDatabase.DbCreateDynaset( "select * from release_content rc, release_tags rt where rc.rtag_id = rt.rtag_id and "&_

                                          " pv_id ="&rsRep("pv_id"), 0 )

               While ((NOT rsQry.BOF) AND (NOT rsQry.EOF))

                  %>

                  <tr>

                     <td nowrap align="left" class="body_row" valign="top"></td>

                     <td nowrap align="left" class="body_row" valign="top"></td>

                     <td nowrap align="left" class="body_row" valign="top"><a href="fixed_issues.asp?rtag_id=<%=rsQry("rtag_id")%>&pv_id=<%=rsQry("pv_id")%>" class="txt_linked" target="_blank"><%=rsQry("rtag_name")%></a></td>

                  </tr>

                  <%

                  rsQry.MoveNext()

               WEnd

               rsQry.Close()

               Set rsQry = Nothing

               %>

               <td nowrap align="left" class="body_row" valign="top"><%=rsRep("notes")%></td>

               <td nowrap align="left" class="body_row" valign="top"></td>

            </tr>

            <%  rsRep.MoveNext

         WEnd

         %>

         <tr>

            <td colspan="5" background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

         </tr>

      </table>

      <!-- PRINT, SAVE, ETC. ------------>

      <%If parPrint = "" Then%>

         <br>

         <br>

         <a href="javascript:;" onClick="window.print();" class="txt_linked"><img src="images/btn_print.gif" width="23" height="24" hspace="4" border="0" align="absmiddle">Print this report</a><br>

         <br>

      <%End If%>

      <!-- PRINT, SAVE, ETC. END -------->

      <%

      rsRep.Close

      Set rsRep = nothing

   End If

End Sub

%>

<%

'-------------------------------------------------------------------------------------------------------------------------------------------------------------------

'==================================================================================

' Report Name      :    Find a Package

' Description      :   Locate a package in Release Manager