Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>

<%

'=====================================================

'       JSON test and play

'=====================================================

%>

<%

Option explicit

' Essential to get UTF through all the hoops. ie: VÄSTTRAFIK (VTK)

Response.ContentType = "text/html"

Response.AddHeader "Content-Type", "text/html;charset=UTF-8"

Response.CodePage = 65001

Response.CharSet = "UTF-8"

%>

<!--#include file="common/conf.asp"-->

<!--#include file="common/globals.asp"-->

<!--#include file="common/qstr.asp"-->

<!--#include file="common/common_subs.asp"-->

<SCRIPT LANGUAGE="VBScript" RUNAT=SERVER SRC="class/classaspJSON.vbs"></SCRIPT> 

<%

'------------ Variable Definition -------------

Dim result : result = -1

Dim SqlQry

Dim rsQry

Dim parRtagId : parRtagId = Request("rtag_id")

' Init the output JSON class

'   Operations can add data

'   Default data will be added at the end

Dim oJSON :Set oJSON = New aspJSON

Dim newitem

'

' Determine the size of the record set

'   Gives bad results when searching

Dim MaxCount : MaxCount = 0

SqlQry = "select count(*) as count from BUILD_INSTANCES bi"

If parRtagId <> "" Then

    SqlQry = SqlQry + " WHERE rtag_id = " &  parRtagId

End If

On Error Resume Next

objEH.ErrorRedirect = FALSE

objEH.TryORA ( OraSession )

Set rsQry = OraDatabase.DbCreateDynaset( SqlQry, ORADYN_DEFAULT )

objEH.CatchORA ( OraSession )

    If ((NOT rsQry.BOF) AND (NOT rsQry.EOF)) Then

        MaxCount = rsQry("COUNT")

    End If

rsQry.Close

Set rsQry = Nothing

' Basic Header

oJSON.data("sEcho") = CInt(Request.QueryString("sEcho"))

oJSON.data("iTotalRecords") = MaxCount

oJSON.data("iTotalDisplayRecords") = MaxCount

' Assist in debug

oJSON.data("iReqDisplayStart") = CInt(Request.QueryString("iDisplayStart"))

oJSON.data("iReqDisplayLength") = CInt(Request.QueryString("iDisplayLength"))

Dim vName

for each vName in Request.QueryString

    oJSON.data("sReq_" & vName) = Request.QueryString(vName)

next

' Extract selected range

result = 0

dim firstRow,lastRow

firstRow = CInt(Request.QueryString("iDisplayStart"))

lastRow = firstRow + CInt(Request.QueryString("iDisplayLength"))

' Define the data items to extract from the database

' An array of items to extract

'

Dim dataCols: dataCols = Array ( _

        "bi.PV_ID", _

        "bi.RTAG_ID" ,_

        "pv.pkg_id", _

        "pj.PROJ_NAME", _

        "pj.PROJ_ID", _

        "RTAG_NAME", _

        "p.PKG_NAME", _

        "pv.PKG_VERSION", _

        "pv.PV_DESCRIPTION", _

        "pv.COMMENTS", _

        "NVL(pv.V_EXT, '') as V_EXT", _

        "TO_CHAR(bi.TIMESTAMP, 'Dy DD-Mon-YYYY HH24:MI:SS') as TIMESTAMPTXT", _

        "DECODE(bi.reason, 'N', 'New Version', 'R', 'Ripple', 'T', 'Test', 'P', 'Restored', 'Unknown') as REASON" ,_

        "DECODE(bi.state, 'B', 'Buiding', 'C', 'Complete', 'E', 'Error', 'S', 'SysErr', 'Unknown') as STATE" )

'   Define array of colums to sort by

'       Must match user sort column request

Dim sortCols: sortCols = Array ( _

        "UPPER(pj.PROJ_NAME)",_

        "UPPER(rt.RTAG_NAME)",_

        "UPPER(p.PKG_NAME)",_

        "UPPER(pv.PKG_VERSION)",_

        "bi.BUILD_ID",_

        "UPPER(bi.reason)",_

        "UPPER(bi.state)" )

' Dim determine sorting options

'On Error goto 0

'Response.Write "<pre>"

Dim sortString

If Request.QueryString("iSortCol_0") <> "" Then

    sortString = " ORDER BY " & sortCols(CInt(Request.QueryString("iSortCol_0")))

    sortString = sortString & " " & Request.QueryString("sSortDir_0")

End If

' Filter (search )

Dim searchString

If Request.QueryString("sSearch") <> "" Then

    searchString = " AND upper(p.PKG_NAME) LIKE upper('%" & Request.QueryString("sSearch") & "%')" 

End If

' Create a list of cols that we need. Avoids ambiguity in selections

Dim x,colList,colListJoin

For x = Lbound(dataCols) to Ubound(dataCols)

    colList = colList & colListJoin & dataCols(x)

    colListJoin = ","

Next

Dim whereString

If parRtagId <> "" Then

    whereString = " AND bi.rtag_id = " &  parRtagId

End If

Dim BasicSql

BasicSql = "select " & colList &_

            " from BUILD_INSTANCES bi, " &_

            "     projects pj, " &_

            "     RELEASE_TAGS rt, " &_

            "     packages p, " &_

            "     PACKAGE_VERSIONS pv" &_

            " where bi.PV_ID = pv.pv_id " &_

            "  and pv.PKG_ID = p.PKG_ID" &_

            "  and bi.RTAG_ID = rt.RTAG_ID" &_

            "  and rt.proj_id = pj.proj_id" &_

            whereString &_

            searchString &_

            sortString

SqlQry = "select * from ( "&_

            "select a.*, ROWNUM rnum from (" & BasicSql &_

                ") a where ROWNUM <= " & lastRow &_

            ") where rnum >= " & firstRow

' Assist in debug

oJSON.data("BasicSql") = BasicSql

'oJSON.data("SqlQry") = SqlQry

' Perform the database query

Set oJSON.data("aaData") = oJSON.Collection()

On Error Resume Next

objEH.ErrorRedirect = FALSE

objEH.TryORA ( OraSession )

Set rsQry = OraDatabase.DbCreateDynaset( SqlQry, ORADYN_DEFAULT )

objEH.CatchORA ( OraSession )

' Process each row and return required fields to the user

If objEH.Finally Then

   While (NOT rsQry.BOF) AND (NOT rsQry.EOF)

       Set newitem = oJSON.AddToCollection(oJSON.data("aaData"))

       ' Attempt to speed up access tot he data

       '    Extract all fields for the row

       '    Access fields by index

       Dim fields

       Set fields = rsQry.Fields

       Dim proj_name    : proj_name = fields(3)

       Dim proj_id      : proj_id = fields(4)

       Dim rtag_name    : rtag_name = fields(5)

       Dim pkg_name     : pkg_name = fields(6)

       Dim pkg_id       : pkg_id = fields(2)

       Dim v_ext        : v_ext = fields(10)

       Dim description  : description = Server.HTMLEncode(fields(8))

       Dim pv_id        : pv_id = fields(0)

       Dim rtag_id      : rtag_id = fields(1)

       Dim comments     : comments = Server.HTMLEncode(fields(9))

       Dim pkg_version  : pkg_version = fields(7)

       Dim timestamp    : timestamp = fields(11)

       Dim reason       : reason = fields(12)

       Dim state        : state = fields(13)

       Set fields = nothing

        newitem(0) = "<a href='rtree.asp?proj_id=" & proj_id & "'>" & proj_name & "</a>"

        newitem(1) = rtag_name

        newitem(2) = "<a href=view_by_version.asp?pkg_id=" & pkg_id & "&fpkgversion=*" & v_ext & " title=""" & description & """>" & pkg_name & "</a>"

        newitem(3) =  "<a href='dependencies.asp?pv_id=" & pv_id & "&rtag_id=" & rtag_id &"' title=""" & comments & """>" & pkg_version & "</a>"

        newitem(4) = timestamp

        newitem(5) = reason

        newitem(6) = state

       rsQry.MoveNext

   Wend

End IF

rsQry.Close

Set rsQry = Nothing

'

' SQL error detection and reporting

If objEH.LastOraFailed Then

    oJSON.data("error") = 1

    oJSON.data("emsgSummary") = objEH.MessageSummary

    oJSON.data("emsgDetails") = objEH.MessageDetails

    oJSON.data("SqlQry") = SqlQry

End If

'Return the object

Response.Write oJSON.JSONoutput()

'OraSession.Dispose()

%>