Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>

<%

Option explicit

Response.Expires = 0   ' always load the page, dont store

%>

<%

'=====================================================

'               Import Issues

'=====================================================

%>

<!--#include file="common/conf.asp"-->

<!--#include file="common/globals.asp"-->

<!--#include file="common/qstr.asp"-->

<!--#include file="common/common_subs.asp"-->

<!--#include file="common/common_dbedit.asp"-->

<!--#include file="common/formating.asp"-->

<!--#include file="common/_popup_window_common.asp"-->

<%

' Set rfile parameter. This is a return page after Login

Call objPMod.StoreParameter ( "rfile", "fixed_issues.asp" )

'------------ ACCESS CONTROL ------------------

%>

<!--#include file="_access_control_login.asp"-->

<!--#include file="_access_control_general.asp"-->

<!--#include file="_access_control_project.asp"-->

<%

'------------ Variable Definition -------------

Dim parPv_id

Dim parFRiss_db

Dim parFRiss_id

Dim parFRiss_num

Dim rsCQ

Dim rspPage         ' current page number for multiple page results

Dim rspTotal        ' total number of records

Dim rspCount        ' Record counter

Dim rspTotalPages   ' Total number of pages required to display results

Dim imported

Dim retVal

Dim rsCQTemp

Dim SQLstr

Dim parPackage

Dim parProject

Dim parProduct

Dim parSkipOpen

Dim disabled

Dim IsOptionUsed

Dim parCategMain

Dim parCategMinor

Dim parIStates

Dim parTitle

Dim parDoQuery

Dim oIStates

Dim checked

Dim summaryText

'------------ Constants Declaration -----------

Const rspMax = 100   ' maximum number of records displayed

Const LENUM_ALL = "ALL"

Const LCONST_STAR = "*"

'------------ Variable Init -------------------

parPv_id = Request("pv_id")

parRtag_id = Request("rtag_id")

rspPage = Request("rpg")

parFRiss_db = Request("FRiss_db")

parFRiss_id = Request("FRiss_id")

parFRiss_num = Request("FRiss_num")

parPackage = Request("package")

parProject = Request("project")

parProduct = Request("product")

parCategMain = Request("categmain")

parCategMinor = Request("categminor")

parSkipOpen = Request("skip_open")

parIStates = Request("istates")

parTitle = Request("title")

parDoQuery = Request("doQuery")

imported = FALSE

IsOptionUsed = FALSE

'-- CONDITIONS --------------------------------

If rspPage = "" Then rspPage = 1

If ( Request("btn") = "Filter" )  OR ( Request("btn") = "Find" ) Then rspPage = 1

If (parFRiss_num = "") Then parFRiss_num = LENUM_ALL

If (parTitle = "") Then parTitle = LCONST_STAR  ' Default

If parFRiss_db = "" Then parFRiss_db = enumCLEARQUEST_DEVI_ID      ' Default

If CInt(parFRiss_db) = enumCLEARQUEST_DEVI_ID Then

   If (parPackage <> "") OR  (parProject <> "")  OR  (parProduct <> "") OR (parTitle <> LCONST_STAR) Then IsOptionUsed = TRUE

Else

   If (parCategMain <> "") OR  (parCategMinor <> "") Then IsOptionUsed = TRUE

End If

If (parDoQuery = "") Then parDoQuery = "0"

' Get DEVI issue states checked

Set oIStates = GetIStates()

'----------------------------------------------

'Response.write "parPackage="& parPackage &", parProject="& parProject &", parProduct="& parProduct &", parSkipOpen="& parSkipOpen &"<br>"

'Response.write "parPv_id="& parPv_id &", parRtag_id="& parRtag_id &", rspPage="& rspPage &", parFRiss_db="& parFRiss_db &", parFRiss_id="& parFRiss_id &", parFRiss_num="& parFRiss_num

'Response.write "parIStates="& parIStates &", parSkipOpen="& parSkipOpen

%>

<%

'------------------------------------------------------------------------------------------------------------------------------------

Function GetIStates()

   Dim IStates, aStates, stateId

   Set IStates = CreateObject("Scripting.Dictionary")

   If parIStates = "" Then

      IStates.Item ("ALL") = "checked"

   Else

      aStates = Split( Replace( parIStates, " ", "" ), ",")

      For Each stateId In aStates

         IStates.Item (CStr(stateId)) = "checked"

      Next

   End If

   Set GetIStates = IStates

End Function

'------------------------------------------------------------------------------------------------------------------------------------

Function Get_Issues ( NNiss_db, NNiss_num, NNrecordCount, OOrsCQ )

   Dim SQLstr, issARR, iss_num, col_name, Title

   If CInt(NNiss_db) = enumCLEARQUEST_DEVI_ID Then

      SQLstr = _

      " SELECT si.dbid AS iss_id, si.new_num AS iss_num, si.headline AS summary, sd.NAME AS state"&_

      "   FROM release_manager.CQ_software_issue si,"&_

      "        release_manager.CQ_STATEDEF sd"&_

      "  WHERE si.STATE = sd.ID "

   End If

   '-- User filter --

   If (CInt(NNiss_db) = enumCLEARQUEST_DEVI_ID) Then

      ' Add package Filter

      If (parPackage <> "") Then

         SQLstr = SQLstr &" AND  si.package_ref = '"& Replace( parPackage, "'","''" ) &"'"

      End If

      ' Add project Filter

      If (parProject <> "") Then

         SQLstr = SQLstr &" AND  si.project = '"& Replace( parProject, "'","''" ) &"'"

      End If

      ' Add product Filter

      If (parProduct <> "") Then

         SQLstr = SQLstr &" AND  si.product = '"& Replace( parProduct, "'","''" ) &"'"

      End If

      ' Add Issue State Filter

      If (parIStates <> "") Then

         SQLstr = SQLstr &" AND  sd.id IN ("& parIStates &")"

      End If

      ' Add Title keyword search

      If ( parTitle <> LCONST_STAR ) Then

         Title = Replace( parTitle, "'", "''" )

         Title = Replace( Title, "*", "%" )

         SQLstr = SQLstr &" AND  si.headline LIKE ( '"& Title &"' )"

      End If

   End If

   '-- Keyword search --

   If ( NNiss_num <> LENUM_ALL ) Then

      issARR = Split( Replace( NNiss_num, " ", ""), "," )

      col_name = "new_num"

      SQLstr = SQLstr & " AND ( "

      For Each iss_num IN issARR

         SQLstr = SQLstr &" ("& col_name &" LIKE '%"& iss_num &"%') OR"

      Next

      SQLstr = Left( SQLstr, Len(SQLstr) - 2 )   ' Remove last 'OR'

      SQLstr = SQLstr & "     ) "

   End If

   '-- Get record count ---

   NNrecordCount = Get_Record_Count( SQLstr )

   '-- Order by --

   If CInt(NNiss_db) = enumCLEARQUEST_DEVI_ID Then

      SQLstr = SQLstr &" ORDER BY si.submit_date DESC"

   End If

   'Response.write SQLstr

   On Error Resume Next

   Set OOrsCQ = OraDatabase.DbCreateDynaset( SQLstr, cint(0))

   Get_Issues = Err.Number

   'Response.write  "Result Code" & Get_Issues

End Function

'------------------------------------------------------------------------------------------------------------------------------------

Function Get_Record_Count ( SSsql )

   Dim rsTemp, sqlTemp

   sqlTemp = _

   " SELECT COUNT(*) as record_count "&_

   "   FROM ("& SSsql &") ct"

   Set rsTemp = OraDatabase.DbCreateDynaset( sqlTemp, cint(0))

   If (NOT rsTemp.BOF) AND (NOT rsTemp.EOF) Then

      Get_Record_Count = rsTemp("record_count")

   Else

      Get_Record_Count = 0

   End If

   rsTemp.Close

   Set rsTemp = nothing

End Function

'------------------------------------------------------------------------------------------------------------------------------------

Sub Get_CQ_Issues_States ( sIssIdList, nIssDB, outObjCQissState )

   Dim rsTemp, SQLstr

   If CInt(nIssDB) = enumCLEARQUEST_DEVI_ID Then

      SQLstr = _

      " SELECT si.dbid, sd.name AS state_name, si.state AS state_id"&_

      "  FROM release_manager.CQ_software_issue si,"&_

      "       release_manager.CQ_statedef sd"&_

      " WHERE si.STATE = sd.ID"&_

      "   AND si.dbid IN ("& sIssIdList &")"

   End If

   Set rsTemp = OraDatabase.DbCreateDynaset( SQLstr, cint(0))

   While (NOT rsTemp.BOF) AND (NOT rsTemp.EOF)

      outObjCQissState.Add CStr(rsTemp("dbid")), CStr(rsTemp("state_name"))

      rsTemp.MoveNext

   WEnd

   rsTemp.Close

   Set rsTemp = nothing

End Sub

'------------------------------------------------------------------------------------------------------------------------------------

Function Is_Pkg_Official ( nPv_id )

   Dim rsTemp, Query_String

   Query_String = _

   " SELECT dlocked"&_

   "  FROM package_versions "&_

   " WHERE pv_id = "& nPv_id

   Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))

   If rsTemp("dlocked") = "Y" Then

      Is_Pkg_Official = TRUE

   Else

      Is_Pkg_Official = FALSE

   End If

   rsTemp.Close

   Set rsTemp = nothing

End Function

'------------------------------------------------------------------------------------------------------------------------------------

Function Set_Issue_State ( sCQState )

   If parSkipOpen <> "" Then

      Set_Issue_State = enumISSUES_STATE_FIXED

   Else

      Set_Issue_State = enumISSUES_STATE_IMPORTED

   End If

End Function

'------------------------------------------------------------------------------------------------------------------------------------

Sub Import_Issues ( NNpv_id, NNiss_db, NNiss_id_list )

   Dim issArr, iss_id, oCQissState, iss_num, iss_state, iss_state_human_readable

   If NNiss_id_list = "" Then Exit Sub

   Set oCQissState = CreateObject("Scripting.Dictionary")

   issArr = Split ( NNiss_id_list, ",")

   Call Get_CQ_Issues_States ( NNiss_id_list, NNiss_db, oCQissState )

   objEH.TryORA ( OraSession )

   On Error Resume Next

   For Each iss_id In issArr

      iss_num = GetIssueNumber ( NNiss_db, iss_id )

      iss_state = Set_Issue_State ( oCQissState.Item (Trim(iss_id)) )

      If Err.Number = 0 Then

         OraDatabase.ExecuteSQL _

            " INSERT INTO cq_issues ( pv_id, iss_db, iss_id, iss_state, mod_date )"&_

            " VALUES ( "& NNpv_id &", "& NNiss_db &", "& iss_id &", "& iss_state &", "& ORA_SYSDATE &")"

         If iss_state = 0 Then

            iss_state_human_readable = "No"

         Else

            iss_state_human_readable = "Yes"

         End If

         If Err.Number = 0 Then

            OraDatabase.ExecuteSQL _

               "BEGIN  Log_Action ( "& NNpv_id &", 'issue_add', "& objAccessControl.UserId &", 'Issue number: "& iss_num &", Fixed: "& iss_state_human_readable &"' );  END;"

         End If

      End If

   Next

   objEH.CatchORA ( OraSession )

End Sub

'------------------------------------------------------------------------------------------------------------------------------------

%>

<%

'Process submition

If CBool(Request("action")) AND (Request("btn") = "Import")  AND objAccessControl.UserLogedIn Then

   Call Import_Issues ( parPv_id, parFRiss_db, parFRiss_id )

   imported = TRUE

   Call OpenInParentWindow ("fixed_issues.asp?pv_id="& parPv_id &"&rtag_id="& parRtag_id)

End If

%>

<%

'-------------- Main Line ---------------

If parDoQuery <> "0" Then

   retVal = Get_Issues ( parFRiss_db, parFRiss_num, rspTotal, rsCQ )

End If

' total number of pages required

rspTotalPages = rspTotal \ rspMax

If (rspTotal Mod rspMax) > 0 Then rspTotalPages = rspTotalPages + 1

%>

<html>

<head>

<title>Release Manager</title>

<meta HTTP-EQUIV="Pragma" CONTENT="no-cache">

<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">

<link rel="stylesheet" href="images/release_manager_style.css" type="text/css">

<link rel="stylesheet" href="images/navigation.css" type="text/css">

<script language="JavaScript" src="images/common.js"></script>

<script language="javascript">

<!--

   function toggleOptions()

   {

      var dbOpt = MM_findObj("FRiss_db");

      var dbName = dbOpt.options[dbOpt.selectedIndex].text;

      if (dbName == "DEVI")

      {

         MM_findObj("DIVOPTIONSTDSE").style.display = "none";

         MM_findObj("DIVOPTIONSDEVI").style.display = "block";

      }

      else

      {

         MM_findObj("DIVOPTIONSDEVI").style.display = "none";

         MM_findObj("DIVOPTIONSTDSE").style.display = "block";

      }

   }

//-->

</script>

</head>

<body bgcolor="#FFFFFF" text="#000000" leftmargin="0" topmargin="0" onload="self.focus();">

<%If retVal = 0 Then%>

<form name="importform" method="post" action="<%=scriptName%>">

   <table width="100%" border="0" cellspacing="0" cellpadding="2" height="100%">

      <tr>

         <td height="1%" background="images/bg_admin_dark.gif"><img src="images/spacer.gif" width="10" height="40"></td>

         <td nowrap colspan="3" class="wform_ttl" background="images/bg_admin_dark.gif">

            <table width="100" border="0" cellspacing="5" cellpadding="0">

               <tr>

                  <td align="left" class="wform_ttl">Issue&nbsp;Number</td>

                  <td nowrap>

                     <input name="FRiss_num" type="text" class="form_item" id="FRiss_num" value="<%=parFRiss_num%>" size="30" >

                     <span class="form_wtxt_link">Example: ALL, 123, DEVI-123 </span>

                  </td>

               </tr>

               <tr>

                  <td align="left" class="wform_ttl">Database</td>

                  <td>

                     <select name="FRiss_db" class="form_item" id="FRiss_db" onChange="toggleOptions();">

                        <option value="<%=enumCLEARQUEST_DEVI_ID%>" <%If CInt(parFRiss_db) = enumCLEARQUEST_DEVI_ID Then%>selected<%End If%>>DEVI</option>

                     </select>

                  </td>

               </tr>

               <tr>

                  <td align="right" class="wform_ttl"><img src="images/spacer.gif" width="80" height="1"></td>

                  <td><a href="javascript:;" onClick="ToggleDisplay('DIVOPTIONS');" class="form_wtxt_link">Options...</a></td>

               </tr>

            </table>

            <DIV id="DIVOPTIONS" <%If IsOptionUsed Then%>style="display:block;"<%Else%>style="display:none;"<%End If%>>

               <DIV id="DIVOPTIONSDEVI" <%If CInt(parFRiss_db) = enumCLEARQUEST_DEVI_ID Then%>style="display:block;"<%Else%>style="display:none;"<%End If%>>

                  <table width="100" border="0" cellspacing="5" cellpadding="0">

                     <tr>

                        <td align="left" class="wform_ttl" valign="top">Title</td>

                        <td class="form_wtxt_link"><input name="title" type="text" class="form_item" id="title" value="<%=parTitle%>" style="width:100%;"> * Wildcard available</td>

                     </tr>

                     <tr>

                        <td align="left" class="wform_ttl">Package</td>

                        <td>

                           <select name="package" class="form_item" id="package" style="width:100%;">

                              <option value="">ALL</option>

                              <%

                              '---- PACKAGES ----

                              '-- Get projects

                              SQLstr = _

                              "SELECT si.PACKAGE_REF"&_

                              " FROM release_manager.CQ_SOFTWARE_ISSUE si"&_

                              " WHERE NOT si.PACKAGE_REF IS NULL"&_

                              " GROUP BY si.PACKAGE_REF"&_

                              " ORDER BY si.PACKAGE_REF"

                              Set rsCQTemp = OraDatabase.DbCreateDynaset( SQLstr, cint(0))

                              While (NOT rsCQTemp.BOF) AND (NOT rsCQTemp.EOF)

                                 %>

                                 <option value="<%=rsCQTemp("package_ref")%>" <%If parPackage = Cstr(rsCQTemp("package_ref")) Then%>selected<%End If%>><%=rsCQTemp("package_ref")%></option>

                                 <%

                                 rsCQTemp.MoveNext

                              WEnd

                              rsCQTemp.Close()

                              %>

                           </select>

                        </td>

                     </tr>

                     <tr>

                        <td align="left" class="wform_ttl">Project</td>

                        <td>

                           <select name="project" class="form_item" id="project" style="width:100%;">

                              <option value="">ALL</option>

                              <%

                              '---- PROJECT ----

                              '-- Get projects

                              SQLstr = _

                              "SELECT si.PROJECT"&_

                              "  FROM release_manager.CQ_SOFTWARE_ISSUE si"&_

                              " WHERE NOT si.PROJECT IS NULL"&_

                              " GROUP BY si.PROJECT"&_

                              " ORDER BY si.PROJECT"

                              Set rsCQTemp = OraDatabase.DbCreateDynaset( SQLstr, cint(0))

                              While (NOT rsCQTemp.BOF) AND (NOT rsCQTemp.EOF)

                                 %>

                                 <option value="<%=rsCQTemp("project")%>" <%If parProject = Cstr(rsCQTemp("project")) Then%>selected<%End If%>><%=rsCQTemp("project")%></option>

                                 <%

                                 rsCQTemp.MoveNext

                              WEnd

                              rsCQTemp.Close()

                              %>

                           </select>

                        </td>

                     </tr>

                     <tr>

                        <td align="left" class="wform_ttl">Product</td>

                        <td>

                           <select name="product" class="form_item" id="product" style="width:100%;">

                              <option value="">ALL</option>

                              <%

                              '---- PRODUCT ----

                              '-- Get projects

                              SQLstr = _

                              "SELECT si.PRODUCT"&_

                              "  FROM release_manager.CQ_SOFTWARE_ISSUE si"&_

                              " WHERE NOT si.PRODUCT IS NULL"&_

                              " GROUP BY si.PRODUCT"&_

                              " ORDER BY si.PRODUCT"

                              Set rsCQTemp = OraDatabase.DbCreateDynaset( SQLstr, cint(0))

                              While (NOT rsCQTemp.BOF) AND (NOT rsCQTemp.EOF)

                                 %>

                                 <option value="<%=rsCQTemp("product")%>" <%If parProduct = Cstr(rsCQTemp("product")) Then%>selected<%End If%>><%=rsCQTemp("product")%></option>

                                 <%

                                 rsCQTemp.MoveNext

                              WEnd

                              rsCQTemp.Close()

                              %>

                           </select>

                        </td>

                     </tr>

                     <tr>

                        <td align="left" class="wform_ttl">&nbsp;</td>

                        <td>

                           <fieldset>

                              <legend class="form_wtxt_link">Issue Status </legend>

                              <table width="100%"  border="0" cellspacing="0" cellpadding="0">

                                 <%

                                 '---- ISSUE STATES ----

                                 '-- Get Issuestates

                                 SQLstr = _

                                 " SELECT sd.ID,"&_

                                 "       sd.NAME"&_

                                 "  FROM release_manager.CQ_STATEDEF sd" &_

                                 " ORDER BY sd.ORDINAL"

                                Set rsCQTemp = OraDatabase.DbCreateDynaset( SQLstr, cint(0))

                                 While (NOT rsCQTemp.BOF) AND (NOT rsCQTemp.EOF)

                                    checked = ""

                                    If oIStates.Exists("ALL")  OR  oIStates.Exists(Cstr(rsCQTemp("id"))) Then checked = "checked"

                                    %>

                                    <tr>

                                       <td width="1"><input type="checkbox" name="istates" value="<%=rsCQTemp("id")%>" <%=checked%>></td>

                                       <td width="100%" class="form_wtxt_link"><%=rsCQTemp("name")%></td>

                                    </tr>

                                    <%

                                    rsCQTemp.MoveNext

                                 WEnd

                                 rsCQTemp.Close()

                                 %>

                              </table>

                           </fieldset>

                        </td>

                     </tr>

                     <tr>

                        <td align="right" class="wform_ttl"><img src="images/spacer.gif" width="80" height="1"></td>

                        <td><img src="images/spacer.gif" width="100" height="1"></td>

                     </tr>

                  </table>

               </DIV>

            </DIV>

            <table width="400" border="0" cellspacing="5" cellpadding="0">

               <tr background="images/lbox_bg_blue.gif">

                  <td colspan="2"><img src="images/spacer.gif" width="1" height="1"></td>

               </tr>

               <tr>

                  <td width="1">&nbsp;</td>

                  <td width="100%">

                     <input type="submit" name="btn" value="Find &raquo;" class="form_btn_comp">

                     <span class="form_wtxt_link">Click Find to initiate clearquest query based on your options</span>

                  </td>

               </tr>

            </table>

         </td>

      </tr>

      <tr>

         <td background="images/lbox_bg_blue.gif" width="1%" height="1%">&nbsp;</td>

         <td background="images/lbox_bg_blue.gif" nowrap width="50%" class="wform_ttl">&nbsp;</td>

         <td background="images/lbox_bg_blue.gif" align="right" width="50%">

            <input type="submit" name="btn" value="Import" class="form_btn_comp">

            <input type="reset" name="btn" value="Close" class="form_btn_comp" onclick="self.close()">

         </td>

         <td background="images/lbox_bg_blue.gif" align="right" width="1%" nowrap>

            <img src="images/h_trsp_dot.gif" width="5" height="22">

         </td>

      </tr>

      <tr>

         <td height="100%" width="1%">&nbsp;</td>

         <td valign="top" nowrap colspan="3" class="wform_ttl" background="images/bg_form_lightgray.gif">

            <%

            If imported Then

               Call DisplayInfo ( "ISSUES_IMPORTED", "300" )

            End If

            %>

            <table width="100%" border="0" cellspacing="1" cellpadding="2">

               <tr>

                  <td width="1%" background="images/bg_form_lightbluedark.gif">&nbsp;</td>

                  <td width="1%" nowrap background="images/bg_form_lightbluedark.gif" class="form_field">Issue Number</td>

                  <td width="1%" nowrap background="images/bg_form_lightbluedark.gif" class="form_field">State</td>

                  <td width="100%" nowrap background="images/bg_form_lightbluedark.gif" class="form_field">Summary</td>

               </tr>

               <%

               rspCount = 0

               If (parDoQuery <> "0") Then

                  If (NOT rsCQ.BOF) AND (NOT rsCQ.EOF) Then

                     rsCQ.MoveTo( 1+(rspMax * (rspPage - 1)))

                     While ((NOT rsCQ.BOF) AND (NOT rsCQ.EOF) AND (rspCount < rspMax))

                        If (objAccessControl.IsActive("ImportOpenIssues")) Then

                           Select Case UCase( rsCQ("state") )

                           Case "OPEN"

                              disabled = ""

                           Case "SUSPENDED"

                              disabled = ""

                           Case Else

                              disabled = ""

                           End Select

                        End If

                        If NOT (objAccessControl.IsActive("ImportOpenIssues")) Then

                           If (parSkipOpen <> "") Then

                              Select Case UCase( rsCQ("state") )

                              Case "OPEN"

                                 disabled = "disabled"

                              Case Else

                                 disabled = ""

                              End Select

                           Else

                              Select Case UCase( rsCQ("state") )

                              Case "CLOSED"

                                 disabled = "disabled"

                              Case Else

                                 disabled = ""

                              End Select

                           End If

                        End If

                        %>

                        <tr>

                           <td>

                              <input type="checkbox" name="FRiss_id" value="<%=rsCQ("iss_id")%>" <%=disabled%>>

                           </td>

                           <td nowrap class="form_item">

                              <a href="javascript:;" onClick="MM_openBrWindow('_wform_issues_details.asp?iss_db=<%=parFRiss_db%>&iss_id=<%=rsCQ("iss_id")%>','IssueDetails','resizable=yes,width=580,height=500')" class="txt_linked">

                                 <%If parFRiss_num <> LENUM_ALL Then%>

                                    <%=Highlight_Substring( rsCQ("iss_num"), parFRiss_num )%>

                                 <%Else%>

                                    <%=rsCQ("iss_num")%>

                                 <%End If%>

                              </a>

                           </td>

                           <td class="form_item"><%=rsCQ("state")%></td>

                           <td class="form_item"><%=Server.HTMLEncode(rsCQ("summary"))%></td>

                        </tr>

                        <%

                        rspCount = rspCount + 1

                        rsCQ.MoveNext

                     WEnd

                     rsCQ.Close

                     Set rsCQ = nothing

                  End If

               End If

               %>

               <tr>

                  <td background="images/bg_form_lightbluedark.gif">&nbsp;</td>

                  <td colspan="3" nowrap background="images/bg_form_lightbluedark.gif" class="form_step">

                     <%

                     If rspTotal > rspMax Then

                        If CInt(rspPage) = CInt(rspTotalPages) Then

                           Response.write "Found "& rspTotal &" records, showing "& (rspMax * rspPage) - rspMax + 1 &" - "& rspTotal

                        Else

                           Response.write "Found "& rspTotal &" records, showing "& (rspMax * rspPage) - rspMax + 1 &" - "& (rspCount * rspPage)

                        End If

                     Else

                        Response.write "Found "& rspTotal &" records"

                     End If

                     %>

                  </td>

               </tr>

            </table>

            <table width="100%" border="0" cellspacing="1" cellpadding="2">

               <tr>

                  <td align="center">

                     <%If CInt(rspPage) > 1 Then%><a href="javascript:void(document.importform.submit())" onClick="importform.rpg.value = parseInt(importform.rpg.value) - 1;  importform.submit();" class="txt_linked">&lt;previous</a><%End If%>&nbsp;

                     <%If CInt(rspPage) < CInt(rspTotalPages) Then%><a href="javascript:void(document.importform.submit())" onClick="importform.rpg.value = parseInt(importform.rpg.value) + 1;  importform.btn.value='next';" class="txt_linked">next &gt;</a><%End If%>

                  </td>

               </tr>

            </table>

            <br>

         </td>

      </tr>

      <tr>

         <td width="1%" height="1%" background="images/lbox_bg_blue.gif"><img src="images/h_trsp_dot.gif" width="5" height="5"></td>

         <td valign="top" nowrap colspan="3" class="wform_ttl" background="images/lbox_bg_blue.gif"></td>

      </tr>

   </table>

   <input name="rpg" type="hidden" value="<%=rspPage%>">

   <input name="skip_open" type="hidden" value="<%=parSkipOpen%>">

   <input name="pv_id" type="hidden" value="<%=parPv_id%>">

   <input name="rtag_id" type="hidden" value="<%=parRtag_id%>">

   <input name="doQuery" id="doQuery" type="hidden" value="1">

   <input name="action" type="hidden" value="true">

</form>

<%Else%>

<%=enumMSSQL_ERROR%>

<%End If%>

</body>

</html>

<!-- DESTRUCTOR ------->

<!--#include file="common/destructor.asp"-->