Subversion Repositories DevTools

<%

'=====================================================

'                MENU DEFINITION

'=====================================================

%>

<%

'------------ CONSTANTS -----------------------

Const MenuHeaderDefined = 1

Const LMENU_TICK = "<img src=""images/i_boxtick_on.gif"" width=""13"" height=""13"" border=""0"" vspace=""2"" align=""absmiddle"">"

Const LMENU_BLANK = "<img src=""images/spacer.gif"" width=""13"" height=""13"" border=""0"" vspace=""2"" align=""absmiddle"">"

'------------ Variable Definition -------------

Dim TABarray1, TABarray2, TABarray3, TABarray4, TABarray5, TABarray5D, TABarray6, TABarray6D

Dim ppClick

Dim imgDependenciesIcon, imgReleaseNotesIcon, imgPatchesIcon

Dim ReleaseMode

'-- GLOBAL VARIABLES --------------------------

imgDependenciesIcon = "<img src='images/i_dependency.gif' border='0' align='absmiddle' hspace='3'>"

imgReleaseNotesIcon = "<img src='images/i_release_note.gif' border='0' align='absmiddle' hspace='3'>"

imgPatchesIcon = "<img src='images/i_patch_small.gif' border='0' align='absmiddle' hspace='3'>"

' Used for cancel button history

If Request("click") <> "" Then

   ppClick = Request("click")

Else

   ppClick = 1

End If

ReleaseMode = GetReleaseMode( Request("rtag_id") )

'----------------------------------------------

If IsObject(pkgInfoHash) Then

   If IsNull(pkgInfoHash.Item ("is_patch")) Then

      If CInt(pkgInfoHash.Item ("base_view_id")) = enumBASE_VIEW_PRODUCTS  OR CInt(pkgInfoHash.Item ("base_view_id")) = enumAUTOPRODUCTS_BASE_VIEW_ID Then

         ' Tab for PRODUCTS

         TABarray1 = Array ( imgDependenciesIcon &"Dependencies@dependencies.asp?"& Persists_Query_String( Empty ), _

                             "Runtime@runtime_dependencies.asp?"& Persists_Query_String( Empty ), _

                             "Used by@used_by.asp?"& Persists_Query_String( Empty ), _

                             "Processes@process_dependencies.asp?"& Persists_Query_String( Empty ), _

                             imgPatchesIcon &"Patches@patches.asp?"& Persists_Query_String( Empty ), _

                             imgReleaseNotesIcon &"Release Notes@fixed_issues.asp?"& Persists_Query_String( Empty ), _

                             "Documentation@documentation.asp?" & Persists_Query_String( Empty ), _

                             "Files and Folders@files_and_folders.asp?" & Persists_Query_String( Empty ), _

                             "Action Log@action_log.asp?"& Persists_Query_String( Empty ), _

                             "Unit Test@unit_test_log.asp?"& Persists_Query_String( Empty ) )

      Else

         ' Tabs for other packages

         TABarray1 = Array ( imgDependenciesIcon &"Dependencies@dependencies.asp?"& Persists_Query_String( Empty ), _

                             "Runtime@runtime_dependencies.asp?"& Persists_Query_String( Empty ), _

                             "Used by@used_by.asp?"& Persists_Query_String( Empty ), _

                             "Processes@process_dependencies.asp?"& Persists_Query_String( Empty ), _

                             imgPatchesIcon &"Patches@patches.asp?"& Persists_Query_String( Empty ), _

                             imgReleaseNotesIcon &"Release Notes@fixed_issues.asp?"& Persists_Query_String( Empty ), _

                             "Documentation@documentation.asp?" & Persists_Query_String( Empty ), _

                             "Files and Folders@files_and_folders.asp?" & Persists_Query_String( Empty ), _

                             "Action Log@action_log.asp?"& Persists_Query_String( Empty ), _

                             "Unit Test@unit_test_log.asp?"& Persists_Query_String( Empty ) )

        ' Add a debug tab to show internal data

        If (IsEmpty(Application("LiveSystem"))) Then

            ReDim Preserve yourArray(UBound(TABarray1) + 1)

            TABarray1(UBound(TABarray1)) = "Debug@pvdata.asp?"& Persists_Query_String( Empty )

        End If

      End If

   Else

      ' Tabs for Patches

      TABarray1 = Array ( imgDependenciesIcon &"Dependencies@dependencies.asp?pv_id="& Request("pv_id") &"&rtag_id="& Request("rtag_id"), _

                          "Used by@used_by.asp?pv_id="& Request("pv_id") &"&rtag_id="& Request("rtag_id"), _

                          imgReleaseNotesIcon &"Release Notes@fixed_issues.asp?pv_id="& Request("pv_id") &"&rtag_id="& Request("rtag_id"), _

                          "Files and Folders@files_and_folders.asp?" & Persists_Query_String( Empty ), _

                          "Action Log@action_log.asp?pv_id="& Request("pv_id") &"&rtag_id="& Request("rtag_id"))

   End If

End If

' Tabs for Import / Export Dependencies

TABarray2 = Array ( "JATS style@form_update_jats_dependencies.asp?click="& CInt(ppClick) + 1 &"&pv_id="& Request("pv_id") &"&rtag_id="& Request("rtag_id"), _

                    "JANT style@form_update_jant_dependencies.asp?click="& CInt(ppClick) + 1 &"&pv_id="& Request("pv_id") &"&rtag_id="& Request("rtag_id"), _

                    "ANT-using style@form_update_ant_dependencies.asp?click="& CInt(ppClick) + 1 &"&pv_id="& Request("pv_id") &"&rtag_id="& Request("rtag_id"))

TABarray3 = Array ( "JATS style@form_export_jats_dependencies.asp?pv_id="& Request("pv_id") &"&rtag_id="& Request("rtag_id"), _

                    "JANT style@form_export_jant_dependencies.asp?pv_id="& Request("pv_id") &"&rtag_id="& Request("rtag_id"), _

                    "ClearCase style@form_export_clearcase_dependencies.asp?pv_id="& Request("pv_id") &"&rtag_id="& Request("rtag_id"), _

                    "ANT-using style@form_export_ant_dependencies.asp?pv_id="& Request("pv_id") &"&rtag_id="& Request("rtag_id"))

TABarray4 = Array ( "Details@_wform_issues_details.asp?iss_db="& Request("iss_db") &"&iss_id="& Request("iss_id") &"&iss_db_name="& Request("iss_db_name") &"&iss_id_num="& Request("iss_id_num") , _

                    "Notes@_wform_issues_notes.asp?iss_db="& Request("iss_db") &"&iss_id="& Request("iss_id") &"&iss_db_name="& Request("iss_db_name") &"&iss_id_num="& Request("iss_id_num"), _

                    "History@_wform_issues_history.asp?iss_db="& Request("iss_db") &"&iss_id="& Request("iss_id") &"&iss_db_name="& Request("iss_db_name") &"&iss_id_num="& Request("iss_id_num") )

' Tabs for History window

TABarray5 = Array ( imgDependenciesIcon &"Dependencies@_wform_versions_history_dependencies.asp?"& Persists_Query_String( Empty ), _

                    "Runtime@_wform_versions_history_runtime.asp?"& Persists_Query_String( Empty ), _

                    "Used by@_wform_versions_history_used_by.asp?"& Persists_Query_String( Empty ), _

                    "Patches@_wform_versions_history_patches.asp?" & Persists_Query_String( Empty ), _

                    imgReleaseNotesIcon &"Release Notes@_wform_versions_history_release_notes.asp?" & Persists_Query_String( Empty ), _

                    "Documentation@_wform_versions_history_documentation.asp?"& Persists_Query_String( Empty ), _

                    "Files and Folders@_wform_versions_history_files_and_folders.asp?" & Persists_Query_String( Empty ), _

                    "Action Log@_wform_versions_history_action_log.asp?"& Persists_Query_String( Empty ) ,_

                    "Unit Tests@_wform_versions_history_unit_test_log.asp?"& Persists_Query_String( Empty ) )

TABarray5D = Array ( imgDependenciesIcon &"Dependencies@#", _

                     "Runtime@#", _

                     "Patches@#", _

                     imgReleaseNotesIcon &"Release Notes@#", _

                     "Documentation@#", _

                     "Action Log@#",_

                     "Unit Tests@#" )

' Tabs for Unit Test window

TABarray6 = Array ( "Unit Test Details@_wform_update_unit_test.asp?rtag_id="& Request("rtag_id") &"&pv_id="& Request("pv_id") &"&test_id="& Request("test_id"), _

                    "Acceptance@_wform_update_unit_test_acceptance.asp?rtag_id="& Request("rtag_id") &"&pv_id="& Request("pv_id") &"&test_id="& Request("test_id"))

TABarray6D = Array ( "Unit Test Details@#", _

                     "Acceptance@#")

'----------------------------------------------

%>

<script language="JavaScript1.2">

var linkset=new Array()

// ---- Popup menu definition ----

linkset[0]=''

<%=Projects_Menu ( 0 )%>

linkset[1] = ''

linkset[1]+='<div class="menuitems"><a target="_blank" href="../Access_Manager">Access&nbsp;Manager</a></div>'

linkset[1]+='<div class="menuitems"><a target="_blank" href="../Deployment_Manager">Deployment&nbsp;Manager</a></div>'

//linkset[1]+='<div class="menuitems"><a target="_blank" href="../Production_Manager">Production&nbsp;Manager</a></div>'

linkset[1]+='<div class="menuitems"><a target="_blank" href="../Release_Manager">Release&nbsp;Manager</a></div>'

<%

'-------------------------------------------------

' Function:     genReleaseMode    

' Description:  Generate one line of the Release State dropdown menu

Function genReleaseMode(mode, emode, code, name, title)

    genReleaseMode = ""

    Dim href: href = ""

    Dim mclass : mclass = "menuitems"

        If mode = emode Then

            genReleaseMode = genReleaseMode & LMENU_TICK

            mclass="menuitemDisable"

        Else

            If canActionInProject() Then

                If canChangeMode Then

                    href = "<a href=""_change_release_mode.asp?mode_code=" & code & "&"& objPMod.ComposeURL() &""">"

                    genReleaseMode = genReleaseMode & href

                Else

                    mclass="menuitemDisable"

                End If

                genReleaseMode = genReleaseMode & LMENU_BLANK

            End If

        End If

        If genReleaseMode <> "" Then

            genReleaseMode = genReleaseMode & "<span title=""" & title & """>&nbsp;" & name &"</span>"

            If href <> "" Then genReleaseMode = genReleaseMode & "</a>"

            genReleaseMode = "<div class="""&mclass&""">" & genReleaseMode & "</div>"

        End If

    genReleaseMode = "'" & genReleaseMode & "'"

End Function

Dim canChangeMode : canChangeMode = FALSE

If ReleaseMode = enumDB_RELEASE_IN_OPEN_MODE Then

    canChangeMode = canActionInProject()

ElseIf ReleaseMode = enumDB_RELEASE_IN_RESTRICTIVE_MODE Then

    canChangeMode = canActionControlInProject("ChangeModeFromRestrictive") OR canActionControlInProject("ChangeModeFromClosed") 

ElseIf ReleaseMode = enumDB_RELEASE_IN_CCB_MODE Then

    canChangeMode = canActionControlInProject("ChangeModeFromRestrictive") OR canActionControlInProject("ChangeModeFromClosed") 

ElseIf ReleaseMode = enumDB_RELEASE_IN_CLOSED_MODE Then

    canChangeMode = canActionControlInProject("ChangeModeFromClosed") 

ElseIf ReleaseMode = enumDB_RELEASE_IN_ARCHIVE_MODE Then

    canChangeMode = canActionControl("MSMaintainer") 

End If

%>

linkset[2]=''

linkset[2]+=<%=genReleaseMode(ReleaseMode,enumDB_RELEASE_IN_OPEN_MODE, 1, "Open&nbsp;Mode" , "Packages can be released freely.")%>

linkset[2]+=<%=genReleaseMode(ReleaseMode,enumDB_RELEASE_IN_RESTRICTIVE_MODE, 2, "Restrictive&nbsp;Mode" , "Packages can only be released on approval.")%>

linkset[2]+=<%=genReleaseMode(ReleaseMode,enumDB_RELEASE_IN_CCB_MODE, 4, "CCB&nbsp;Mode" , "Packages can only be released on CCB approval.")%>

linkset[2]+=<%=genReleaseMode(ReleaseMode,enumDB_RELEASE_IN_CLOSED_MODE, 3, "Closed&nbsp;Mode" , "No changes allowed.")%>

linkset[2]+=<%=genReleaseMode(ReleaseMode,enumDB_RELEASE_IN_ARCHIVE_MODE, 5, "Archive&nbsp;Mode" , "This would put the release into archive state.")%>

linkset[2]+='<hr>'

<%If (ReleaseMode = enumDB_RELEASE_IN_OPEN_MODE) AND canShowControlInProject ("CloneReleaseContents") Then%>

   linkset[2]+='<div class="menuitems"><a href="javascript:;" onClick="MM_openBrWindow(\'_wform_import_release.asp?ToRtag_id=<%=parRtag_id%>&<%=objPMod.ComposeURL()%>\',\'ReleaseManager\',\'scrollbars=yes,resizable=yes,width=400,height=200\')">Import&nbsp;Release&nbsp;Contents</a></div>'

<%Else%>

   linkset[2]+='<div class="menuitemDisable">Import&nbsp;Release&nbsp;Contents</div>'

<%End If%>

<%If (ReleaseMode = enumDB_RELEASE_IN_OPEN_MODE) AND canShowControlInProject ("ImportDependencies") Then%>

   linkset[2]+='<div class="menuitems"><a href="javascript:;" onClick="MM_openBrWindow(\'_wform_import_dependency.asp?<%=objPMod.ComposeURL()%>\',\'ReleaseManager\',\'scrollbars=yes,resizable=yes,width=800,height=200\')">Import&nbsp;Dependencies</a></div>'

<%Else%>

   linkset[2]+='<div class="menuitemDisable">Import&nbsp;Dependencies</div>'

<%End If%>

<%If (ReleaseMode = enumDB_RELEASE_IN_OPEN_MODE) AND canShowControlInProject ("ImportDependencies") Then%>

   linkset[2]+='<div class="menuitems"><a href="javascript:;" onClick="MM_openBrWindow(\'_wform_import_daemonconfig.asp?<%=objPMod.ComposeURL()%>\',\'ReleaseManager\',\'scrollbars=yes,resizable=yes,width=800,height=200\')">Import&nbsp;Daemon&nbsp;Config</a></div>'

//   linkset[2]+='<div class="menuitems"><a href="import_daemonconfig.asp?rtag_id=<%=parRtag_id%>">Import&nbsp;Daemon&nbsp;Config</a></div>'

<%Else%>

   linkset[2]+='<div class="menuitemDisable">Import&nbsp;Daemon&nbsp;Config</div>'

<%End If%>

<%If canActionControlInProject ("CreateSdk") Then%>

    linkset[2]+='<hr>'

    linkset[2]+='<div class="menuitems"><a href="javascript:;" onclick="$(\'#popmenu\').load(\'sdk_version_add.asp\', {sdk_id : 1, rtag_id : <%=parRtag_id%>, proj_id : <%=DB_PROJ_ID%>} );">Create&nbsp;SDK</a></div>'

<%End If%>

linkset[2]+='<hr>'

linkset[2]+='<div class="menuitems"><a href="form_edit_release.asp?rtag_id=<%=parRtag_id%>">Release&nbsp;Properties</a></div>'

linkset[2]+='<div class="menuitems"><a href="diff.asp?rtagB=<%=parRtag_id%>" >Merge&nbsp;Manager</a></div>'

linkset[2]+='<div class="menuitems"><a href="build_order.asp?rtag_id=<%=parRtag_id%>">Build&nbsp;Order</a></div>'

linkset[2]+='<div class="menuitems"><a href="form_view_release_licencing.asp?rtag_id=<%=parRtag_id%>">View Licencing</a></div>'

linkset[2]+='<div class="menuitems"><a href="form_edit_release_licencing.asp?rtag_id=<%=parRtag_id%>">Edit Licencing</a></div>'

linkset[2]+='<div class="menuitems"><a href="javascript:;" onClick="MM_openBrWindow(\'wAddDaemonInstruction.asp?ToRtag_id=<%=parRtag_id%>&<%=objPMod.ComposeURL()%>\',\'ReleaseManager\',\'scrollbars=yes,resizable=yes,width=800,height=350\')">Add&nbsp;Daemon&nbsp;Instruction</a></div>'

   linkset[6]=''

   linkset[6]+='<div class="menuitems"><a href="admin_build_service.asp">Build&nbsp;Service</a></div>'

   linkset[6]+='<div class="menuitems"><a href="admin_build_test_page.asp">Release&nbsp;Manager&nbsp;Tests</a></div>'

<%If canActionControl("MSMaintainer") Then%>

   linkset[6]+='<div class="menuitems"><a href="admin_session_details.asp">Session&nbsp;Details</a></div>'

<%End If%>

<%If canActionControl("ConfigureBuildService") Then%>

   linkset[6]+='<hr>'

   linkset[6]+='<div class="menuitems"><a href="admin_gbe_machtype.asp">GBE&nbsp;MachType</a></div>'

   linkset[6]+='<div class="menuitems"><a href="admin_gbe_machclass.asp">GBE&nbsp;MachClass</a></div>'

   linkset[6]+='<div class="menuitems"><a href="admin_build_machine.asp">Build&nbsp;Machine</a></div>'

   linkset[6]+='<div class="menuitems"><a href="admin_licences.asp">Licences</a></div>'

   linkset[6]+='<div class="menuitems"><a href="admin_vcs_types.asp">Version&nbsp;Control&nbsp;Systems</a></div>'

<%End If%>

<%If (canActionControl("CreateNewProject")) Then%>

   linkset[6]+='<hr>'

   linkset[6]+='<div class="menuitems"><a href="javascript:;" onClick="MM_openBrWindow(\'_wform_new_project.asp\',\'ReleaseManager\',\'resizable=yes,width=400,height=200\')">New&nbsp;Project</a></div>'

   linkset[6]+='<div class="menuitems"><a href="admin_projects.asp">Project&nbsp;Info</a></div>'

   linkset[6]+='<div class="menuitems"><a href="admin_project_suffix.asp">Project&nbsp;Suffix</a></div>'

<%End If%>

<%If objAccessControl.UserLogedIn Then%>

   linkset[6]+='<hr>'

   linkset[6]+='<div class="menuitems"><a href="admin_package_properties.asp">Package&nbsp;Properties</a></div>'

<%End If%>

linkset[5]=''

<%If Not objAccessControl.UserLogedIn Then%>

   linkset[5]+='<div class="menuitems"><a href="Login.asp?rfile=<%=scriptName & QSTR_FullQuery%>">Login</a></div>'

<%Else%>

   linkset[5]+='<div class="menuitemDisable">Login</div>'

<%End If%>

<%If objAccessControl.UserLogedIn Then%>

   linkset[5]+='<div class="menuitems"><a href="_Logout.asp">Logout</a></div>'

<%Else%>

   linkset[5]+='<div class="menuitemDisable">Logout</div>'

<%End If%>

<!-- linkset[5]+='<div class="menuitems"><a href="sign_up.asp">Sign&nbsp;Up</a></div>' -->

linkset[5]+='<div class="menuitems"><a href="members_pkgs_followed.asp">Notifications</a></div>'

linkset[5]+='<div class="menuitems"><a href="members_personal_view.asp">Views</a></div>'

linkset[5]+='<div class="menuitems"><a href="members_my_details.asp">My&nbsp;Details</a></div>'

linkset[5]+='<div class="menuitems"><a href="members_my_roles.asp">My&nbsp;Roles</a></div>'

linkset[7]=''

linkset[7]+='<div class="menuitems"><a href="release_config.asp?rtag_id=<%=parRtag_id%>">Configuration</a></div>'

linkset[7]+='<div class="menuitems"><a href="build_status.asp?rtag_id=<%=parRtag_id%>">Status</a></div>'

linkset[7]+='<div class="menuitems"><a href="build_release_log.asp?rtag_id=<%=parRtag_id%>">Build Log</a></div>'

linkset[8]=''

linkset[8]+='<div class="menuitems"><a href="admin_build_status.asp">Daemon&nbsp;Status</a></div>'

linkset[8]+='<div class="menuitems"><a href="build_release_log.asp">Daemon&nbsp;Build&nbsp;Log</a></div>'

linkset[8]+='<div class="menuitems"><a href="admin_daemon_instructions.asp">Daemon&nbsp;Instructions</a></div>'

linkset[9]=''

linkset[9]+='<div class="menuitems"><a href="Wikiasp/wiki.asp" target="_blank">Release&nbsp;Notes</a></div>'

<%If (IsEmpty(Application("LiveSystem"))) Then%>

linkset[9]+='<div class="menuitems"><a href="Wikiasp/wiki.asp?db=ImplementationNotes" target="_blank">Development&nbsp;Notes</a></div>'

<%End If%>

linkset[9]+='<div class="menuitems"><a href="help/index.asp" target="_blank">Internal&nbsp;Help(old)</a></div>'

linkset[9]+='<div class="menuitems"><a href="_about.asp" target="_blank">About</a></div>'

</script>

<%

Sub Print_TopRight_Menu_ROW1

   Response.write "<table bgcolor='#ffffff' border='0' cellpadding='0' cellspacing='0' height='26'>"

   Response.write "  <tr> "

   If objAccessControl.UserLogedIn Then

      Response.write "    <td align=middle noWrap valign=center><a class=mmItem href='members_index.asp' onMouseover=""showmenu(event,linkset[5])"" onMouseout=""delayhidemenu()""><img src='images/i_user.gif' border='0' hspace='3'>"&  objAccessControl.FullName &"</a>&nbsp;&nbsp;</td>"

   Else

      Response.write "    <td align=middle noWrap valign=center><a class=mmItem href='members_index.asp' onMouseover=""showmenu(event,linkset[5])"" onMouseout=""delayhidemenu()"">My Account</a></td>"

   End If

   Response.write "   <td align=middle>|</td>"

   Response.write "    <td align=middle noWrap valign=center width='70'><a class=mmItem href='' onMouseover=""showmenu(event,linkset[1])"" onMouseout=""delayhidemenu()"">Suite</a></td>"

   Response.write "   <td align=middle>|</td>"

   If InStr(1,ScriptName,"sdk_", 1) <> 0 Then

   Response.write "    <td align=middle noWrap valign=center width='70'><a class=mmItem href='index.asp'>Releases</a></td>"

   Response.write "   <td align=middle>|</td>"

   Else

   Response.write "    <td align=middle noWrap valign=center width='70'><a class=mmItem href='sdk_main_page.asp#url=sdk_names_body.asp'>SDK</a></td>"

   Response.write "   <td align=middle>|</td>"

   End If

   Response.write "   <td align=middle noWrap valign=center width='70'><a class=mmItem href='index.asp' onMouseover=""showmenu(event,linkset[0])"" onMouseout=""delayhidemenu()"">Projects</a></td>"

   Response.write "   <td align=middle>|</td>"

   Response.write "    <td align=middle noWrap valign=center width='70'><a class=mmItem href='reports.asp'>Reports</a></td>"

   Response.write "   <td align=middle>|</td>"

   Response.write "    <td align=middle noWrap valign=center width='70'><a class=mmItem href='' onMouseover=""showmenu(event,linkset[8])"" onMouseout=""delayhidemenu()"">Build</a></td>"

   Response.write "   <td align=middle>|</td>"

   Response.write "    <td align=middle noWrap valign=center width='70'><a class=mmItem href='' onMouseover=""showmenu(event,linkset[6])"" onMouseout=""delayhidemenu()"">Admin</a></td>"

   Response.write "   <td align=middle>|</td>"

   Response.write "    <td align=middle noWrap valign=center width='70'><a class=mmItem href='' onMouseover=""showmenu(event,linkset[9])"" onMouseout=""delayhidemenu()"">Help</a></td>"

   Response.write "  </tr>"

   Response.write "</table>"

End Sub

Sub Print_TopRight_Menu_ROW2

   Response.write "<table bgcolor='#ffffff' border='0' cellpadding='0' cellspacing='0' height='35'>"

   Response.write "  <tr> "

   If QStrPar("rtag_id") <> "" Then

      Response.write "    <td align=middle noWrap valign=center width='70'><a class=mmItem href='#' onMouseover=""showmenu(event,linkset[2])"" onMouseout=""delayhidemenu()"">Release</a></td>"

      Response.write "   <td align=middle>|</td>"

      Response.write "    <td align=middle noWrap valign=center width='70'><a class=mmItem href='#' onMouseover=""showmenu(event,linkset[7])"" onMouseout=""delayhidemenu()"">Build</a></td>"

   Else

      Response.write "    <td align=middle noWrap valign=center  width='70'class=mmItemDisable>Release</td>"

      Response.write "   <td align=middle>|</td>"

      Response.write "    <td align=middle noWrap valign=center  width='70'class=mmItemDisable>Build</td>"

   End If

   Response.write "  </tr>"

   Response.write "</table>"

End Sub

Sub Print_TopLeft_Menu

   Dim rsTemp, Query_String

   Dim myProj, myRtag

   Dim HomeSTR, ProjSTR, RtagSTR,ModeSTR

   Dim ActionSTR

   myProj = QStrPar("proj_id")

   myRtag = QStrPar("rtag_id")

   HomeSTR = "<a class=mmItem href='index.asp'>HOME</a>"

   If myRtag <> "" Then

      OraDatabase.Parameters.Add "RTAG_ID", myRtag, ORAPARM_INPUT, ORATYPE_NUMBER

      Query_String = _

      " SELECT rel.rtag_id, rel.rtag_name, proj.proj_id, proj.proj_name, rel.official"&_

      " FROM release_tags rel, projects proj"&_

      " WHERE rel.proj_id = proj.proj_id AND rel.rtag_id = :RTAG_ID"

      Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))

      If ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF)) Then

         ProjSTR = " &gt; <a class=mmItem href='rtree.asp?proj_id="& rsTemp.Fields("proj_id") &"'>"& UCase(rsTemp.Fields("proj_name")) &"</a>"

         RtagSTR = " &gt; <a class=mmItem href='dependencies.asp?rtag_id="& rsTemp.Fields("rtag_id") &"'>"& rsTemp.Fields("rtag_name") &"</a>"

      End If

      OraDatabase.Parameters.Remove "RTAG_ID"

   ElseIf myProj <> "" Then

      OraDatabase.Parameters.Add "PROJ_ID", myProj, ORAPARM_INPUT, ORATYPE_NUMBER

      Query_String = _

      " SELECT proj.proj_name, proj.proj_id"&_

      " FROM projects proj"&_

      " WHERE proj.proj_id = :PROJ_ID"

      Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))

      If ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF)) Then

         ProjSTR = " &gt; <a class=mmItem href='rtree.asp?proj_id="& rsTemp.Fields("proj_id") &"'>"& UCase(rsTemp.Fields("proj_name")) &"</a>"

         RtagSTR = ""

      End If

      OraDatabase.Parameters.Remove "PROJ_ID"

   End If

   '-- Calculate authorisation state

   ActionSTR = ""

   If NOT canActionInProject Then

    ActionSTR = " [Not Authorised]"

    ActionSTR = "<img src='images/i_not_authorised.png' width='10' height='10' border='0' hspace='2' title='Not Authorised to make changes in this project'>" 

   End If

   '-- Append Mode indication

   ModeSTR = ""

   If ReleaseMode = enumDB_RELEASE_IN_RESTRICTIVE_MODE Then

      ModeSTR = " [Restrictive Mode]"

   ElseIf ReleaseMode = enumDB_RELEASE_IN_CCB_MODE Then

      ModeSTR = " [CCB Mode!]"

   ElseIf ReleaseMode = enumDB_RELEASE_IN_CLOSED_MODE Then

      ModeSTR = "<img src='images/i_locked.gif' width='7' height='10' border='0' hspace='2' >&nbsp;[Closed Mode]"

   ElseIf ReleaseMode = enumDB_RELEASE_IN_ARCHIVE_MODE Then

       ModeSTR = "<img src='images/i_archived.gif' width='7' height='10' border='0' hspace='2' >&nbsp;[Archived Mode]"

   End If

   '-- Render Menu --

   Response.write "<table width='100%' border='0' cellspacing='0' cellpadding='0'>"

   Response.write "  <tr>"

   Response.write "    <td width='1%'><img src='images/h_trsp_dot.gif' width='30' height='35'></td>"

   Response.write "    <td nowrap width='100%' class=mmItem>"& HomeSTR & ProjSTR & ActionSTR &  RtagSTR & ModeSTR & "</td>"

   Response.write "  </tr>"

   Response.write "</table>"

   rsTemp.Close()

   Set rsTemp = nothing

End Sub

REM Used when displaying package details outside the context of a Release

Sub Print_Package_TopLeft_Menu

   Dim PkgNameSTR, PkgVersionSTR, PkgLock

If IsObject(pkgInfoHash) Then

   PkgNameSTR = "<a class=mmItem href='view_by_version.asp?pkg_id="& pkgInfoHash.Item("pkg_id") &"&listby=1'>"& pkgInfoHash.Item("pkg_name")& "</a>"

   PkgVersionSTR = " &gt; <a class=mmItem href='#'>"& pkgInfoHash.Item("pkg_version") &"</a>"

   PkgLock = pkgInfoHash.Item("dlocked")

else

    Dim SSpkgID, SSpkgName, SSpkgVersion, SSsrc_path, SSpkgDesc, BBdlocked

    Call Get_Pkg_Short_Info( Request("pv_id"), SSpkgID, SSpkgName, SSpkgVersion, SSsrc_path, SSpkgDesc, BBdlocked )

   PkgNameSTR = "<a class=mmItem href='view_by_version.asp?pkg_id="& SSpkgID &"&listby=1'>"& SSpkgName& "</a>"

   PkgVersionSTR = " &gt; <a class=mmItem href='#'>"& SSpkgVersion &"</a>"

   PkgLock = BBdlocked

End If

   Response.write "<table width='100%' border='0' cellspacing='0' cellpadding='0'>"

   Response.write "  <tr>"

   Response.write "    <td width='1%'><img src='images/h_trsp_dot.gif' width='30' height='35'></td>"

   If (PkgLock= "Y") OR (PkgLock = "A") Then

       Response.write "    <td nowrap width='100%' class=mmItem>"& PkgNameSTR & PkgVersionSTR &"<img src='images/i_locked.gif' width='7' height='10' border='0' hspace='2' ></td>"

   Else

      Response.write "    <td nowrap width='100%' class=mmItem>"& PkgNameSTR & PkgVersionSTR &"</td>"

   End If

   Response.write "  </tr>"

   Response.write "</table>"

End Sub

Function Projects_Menu ( NNarrIndex )

   Dim rsTemp, Query_String, tempSTR

   tempSTR = ""

   Query_String = _

   " SELECT * FROM projects ORDER BY proj_name ASC"

   Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))

   While ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF))

      tempSTR = tempSTR & "linkset["& NNarrIndex &"]+='<div class=""menuitems""><a href=""rtree.asp?proj_id="& rsTemp.Fields("proj_id") &""">"& Replace(rsTemp.Fields("proj_name"), " ", "&nbsp;") &"</a></div>'"& VBNewLine

      rsTemp.MoveNext

   WEnd

   Projects_Menu = tempSTR

   rsTemp.Close

   Set rsTemp = nothing

End Function

'Function Get_Proj ( NNrtag_id, NNvtree_id )

'   Dim rsTemp, Query_String, tempRtag_id

'   If NNvtree_id = "" Then

'      If NNrtag_id = "" Then

'         tempRtag_id = -1

'      Else

'         tempRtag_id = NNrtag_id

'      End If

'      Query_String = _

'      " SELECT vt.vtree_id, vt.proj_id"&_

'        "   FROM release_tags rel, vtrees vt"&_

'       "   WHERE vt.vtree_id = rel.vtree_id AND rel.rtag_id = "& tempRtag_id

'   Else

'      Query_String = _

'      " SELECT vt.vtree_id, vt.proj_id"&_

'        "   FROM vtrees vt"&_

'       "   WHERE vt.vtree_id = "& NNvtree_id

'   End If

'

'   Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))

'

'   If ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF)) Then

'      Get_Proj = (rsTemp.Fields("proj_id"))

'      NNvtree_id = (rsTemp.Fields("vtree_id"))

'   Else

'      Get_Proj = -1

'      NNvtree_id = -1

'   End If

'

'   rsTemp.Close

'   Set rsTemp = nothing

'End Function

%>