Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>

<%

'=====================================================

'|                                                   |

'|            RequestProjectRelease.asp              |

'|                                                   |

'=====================================================

%>

<%

Option explicit

' Good idea to set when using redirect

Response.Expires = 0   ' always load the page, dont store

%>

<!--#include file="common/conf.asp"-->

<!--#include file="common/globals.asp"-->

<!--#include file="common/formating.asp"-->

<!--#include file="common/qstr.asp"-->

<!--#include file="common/common_subs.asp"-->

<%

'------------ Variable Definition -------------

Dim rsTemp

Dim PageInfoHash

Dim Query_String

Dim Auto

'------------ Constants Declaration -----------

'------------ Variable Init -------------------

Set PageInfoHash = CreateObject("Scripting.Dictionary")

'----------------------------------------------

%>

<%

'------------------------------------------------------------------------------------------------------------------------

' This code is temporary and can be taken out at some point in the future (eg. 3 months from now. ie. Dec2008). Its purpose

' is to ensure that the release level metrics are up-to-date when a user expands the project link on the Release Metrics. The

' SQL queries and database PK_RMAPI update_release_metrics function have been updated to fix errors in the original solution

' but we would have to wait for the build tool to build at least one package in each release in each project before the

' release level metrics would be correct. So, instead, we force the re-computation of those metrics now. It doesn't  take long

' even on a large project like Stockholm, so it is no big deal.

Sub UpdateReleaseMetrics

   Dim rsQry

   Dim rsQuery_String

   Dim rtagid

   On Error Resume Next

   OraDatabase.Parameters.Add "PROJ_ID", Request("proj_id"),    ORAPARM_INPUT, ORATYPE_NUMBER

   rsQuery_String = "SELECT rm.rtag_id"&_

                    "  FROM projects p,"&_

                    "       release_metrics rm,"&_

                    "       release_tags rt"&_

                    " WHERE p.proj_id = rt.proj_id"&_

                    "   AND rm.rtag_id = rt.rtag_id"&_

                    "   AND p.proj_id = :PROJ_ID"

   Set rsQry = OraDatabase.DbCreateDynaset( rsQuery_String, cint(0))

   While (NOT rsQry.BOF) AND (NOT rsQry.EOF)

      OraDatabase.Parameters.Add "RTAG_ID",         rsQry("rtag_id"), ORAPARM_INPUT, ORATYPE_NUMBER

      objEH.TryORA ( OraSession )

      OraDatabase.ExecuteSQL "BEGIN  PK_RMAPI.UPDATE_RELEASE_METRICS ( :RTAG_ID ); END;"

      objEH.CatchORA ( OraSession )

      OraDatabase.Parameters.Remove "RTAG_ID"

      rsQry.MoveNext

   WEnd

   OraDatabase.Parameters.Remove "PROJ_ID"

   rsQry.Close

   Set rsQry = nothing

End Sub

'------------------------------------------------------------------------------------------------------------------------

%>

<%

'------------------------ MAIN LINE ---------------------------------

Call UpdateReleaseMetrics

'--------------------------------------------------------------------

%>

<table width="100%" border="0" cellspacing="1" cellpadding="1">

   <tr>

      <td background="images/bg_form_lightbluedark.gif">

         <table width="100%" border="0" cellspacing="1" cellpadding="3">

            <tr>

               <td nowrap class="body_txt" valign="top" background="images/bg_form_lightbluedark.gif">Release</td>

               <td nowrap class="body_txt" valign="top" background="images/bg_form_lightbluedark.gif">Last Autobuild<br>Completed</td>

               <td nowrap class="body_txt" valign="top" background="images/bg_form_lightbluedark.gif">Autobuilt Packages</td>

               <td nowrap class="body_txt" valign="top" background="images/bg_form_lightbluedark.gif">Lines Of Code</td>

               <td nowrap class="body_txt" valign="top" background="images/bg_form_lightbluedark.gif">Unit Tested</td>

               <td nowrap class="body_txt" valign="top" background="images/bg_form_lightbluedark.gif">Autotested</td>

            </tr>

            <%

            OraDatabase.Parameters.Add "PROJ_ID", Request("proj_id"),    ORAPARM_INPUT, ORATYPE_NUMBER

            Set rsTemp = OraDatabase.DbCreateDynaset( GetQuery("ReleaseMetrics.sql"), cint(0))

            OraDatabase.Parameters.Remove "PROJ_ID"

            If rsTemp.RecordCount < 1 Then%>

               <tr>

                  <td background="images/bg_form_lightgray.gif" nowrap>&nbsp;</td>

               </tr>

            <%Else

               While ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF))

                  Auto=FormatPercent(rsTemp("autobuilt")/rsTemp("total_packages"), 2)

                  %>

                  <tr>

                     <td background="images/bg_form_lightgray.gif" nowrap class="body_txt">

                        <SPAN id="IMG_EXPAND_RTAG_<%=rsTemp("rtag_id")%>" style="display:block;">

                           <a href="javascript:;" class="txt_linked" onClick="RequestReleasePackages('?rtag_id=<%=rsTemp("rtag_id")%>', '<%=rsTemp("rtag_id")%>');">

                              <img src="images/bt_plus.gif" border="0" align="absmiddle" hspace="3">

                              <img src="images/i_world.gif" border="0" align="absmiddle" hspace="3">

                              <%=rsTemp("rtag_name")%>

                           </a>

                        </SPAN>

                        <SPAN id="IMG_COLLAPSE_RTAG_<%=rsTemp("rtag_id")%>" style="display:none;">

                           <a href="javascript:;" class="txt_linked" onClick="ToggleDisplay( 'DIVRTAG_<%=rsTemp("rtag_id")%>', 'IMG_EXPAND_RTAG_<%=rsTemp("rtag_id")%>', 'IMG_COLLAPSE_RTAG_<%=rsTemp("rtag_id")%>');">

                              <img src="images/bt_minus.gif" border="0" align="absmiddle" hspace="3">

                              <img src="images/i_world.gif" border="0" align="absmiddle" hspace="3">

                              <%=rsTemp("rtag_name")%>

                           </a>

                        </SPAN>

                     </td>

                     <td nowrap class="body_txt" background="images/bg_form_lightgray.gif"><%=rsTemp("last_build_time")%></td>

                     <td nowrap class="body_txt" background="images/bg_form_lightgray.gif"><%=rsTemp("autobuilt")%>/<%=rsTemp("total_packages")%> (<%=Auto%>)</td>

                     <td nowrap class="body_txt" background="images/bg_form_lightgray.gif"><%=rsTemp("lines_of_code")%></td>

                     <td nowrap class="body_txt" background="images/bg_form_lightgray.gif"><%=rsTemp("unit_tested")%></td>

                     <td nowrap class="body_txt" background="images/bg_form_lightgray.gif"><%=rsTemp("autotested")%></td>

                  </tr>

                  <tr>

                     <td nowrap class="body_txt" colspan="6">

                        <DIV id="DIVRTAG_<%=rsTemp("rtag_id")%>" style="display:none;"><%=enumLOADING%></DIV>

                     </td>

                  </tr>

                  <%rsTemp.MoveNext

               WEnd

               rsTemp.Close

               Set rsTemp = nothing

            End If%>

         </table>

    </td>

  </tr>

</table>

<br>

<%

Call Destroy_All_Objects

%>