Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>

<%

'=====================================================

'|                                                   |

'|			          wRevertProducts                |

'|                                                   |

'=====================================================

%>

<%

Option explicit

Response.Expires = 0

%>

<!--#include file="common/globals.asp"-->

<!--#include file="common/config.asp"-->

<!--#include file="common/common_subs.asp"-->

<!--#include file="common/_popup_window_common.asp"-->

<%

'------------ ACCESS CONTROL ------------------

%>

<!--#include file="_access_control_general.asp"-->

<%

'------------ VARIABLE DEFINITION -------------

Dim rsQry

Dim aProducts

Dim numOfRows

Dim rowNum

Dim objFormCollector

Dim currPkg_id

'------------ CONSTANTS DECLARATION -----------

'------------ VARIABLE INIT -------------------

parBom_id = Request("bom_id")

Set objFormCollector = CreateObject("Scripting.Dictionary")

'------------ CONDITIONS ----------------------

'----------------------------------------------

%>

<%

'----------------------------------------------------------------------------------------------------------------------------------

Sub GetFormDetails ( nBom_id, ByRef outobjDetails )

	Dim rsQry, query

	OraDatabase.Parameters.Add "BOM_ID", 		nBom_id,		ORAPARM_INPUT, ORATYPE_NUMBER 

	query = _

	"  SELECT rt.RTAG_ID, "&_

	"	      rt.RTAG_NAME, "&_

	"	      bo.PARENT_BOM_ID "&_

	"	 FROM RELEASE_TAGS rt,"&_

	"	 	   BOMS bo"&_

	"	WHERE bo.RTAG_ID_FK = rt.RTAG_ID"&_

	"	  AND bo.BOM_ID = :BOM_ID"

	Set rsQry = OraDatabase.DbCreateDynaset( query, ORADYN_DEFAULT )

	If (NOT rsQry.BOF) AND (NOT rsQry.EOF)Then

		outobjDetails.Item ("rtag_id_fk") = rsQry("rtag_id")

		outobjDetails.Item ("rtag_name") = rsQry("rtag_name")

		outobjDetails.Item ("parent_bom_id") = rsQry("parent_bom_id")

	End If

	OraDatabase.Parameters.Remove "BOM_ID"

	rsQry.Close

	Set rsQry = Nothing

End Sub

'----------------------------------------------------------------------------------------------------------------------------------

Sub RevertProducts()

	Dim aDiffList, numOfRows, rowNum, OraParameter

	Const os_id_column = 2

	Const old_prod_id_column = 1

	'/* Get Updated Versions from Previous BOM */

	OraDatabase.Parameters.Add "BOM_ID", parBom_id,		ORAPARM_INPUT, ORATYPE_NUMBER 

	OraDatabase.Parameters.Add "COMPARE_BOM_ID", objFormCollector.Item("parent_bom_id"), ORAPARM_INPUT, ORATYPE_NUMBER  

	Set rsQry = OraDatabase.DbCreateDynaset( GetQuery ("RevertProducts.sql"), ORADYN_DEFAULT )

	OraDatabase.Parameters.Remove "BOM_ID"

	OraDatabase.Parameters.Remove "COMPARE_BOM_ID"

	'-- Get Rows

	If rsQry.RecordCount > 0 Then

		aDiffList = rsQry.GetRows()

	Else

		'-- No differences compared to Previous BOM, hence exit

		Exit Sub

	End If

	'/* Revert Versions */

	On Error Resume Next

	OraDatabase.Parameters.Add "OLD_PROD_ID", 	0, 	ORAPARM_INPUT, ORATYPE_NUMBER 

	OraDatabase.Parameters.Add "NEW_PROD_ID", 	0, 	ORAPARM_INPUT, ORATYPE_NUMBER 

	OraDatabase.Parameters.Add "OS_ID", 		0, 	ORAPARM_INPUT, ORATYPE_NUMBER 

	OraDatabase.Parameters.Add "USER_ID", 		objAccessControl.UserId, 	ORAPARM_INPUT, ORATYPE_NUMBER 

	Set OraParameter = OraDatabase.Parameters

	objEH.TryORA ( OraSession )

	numOfRows = UBound( aDiffList, 2 )

	For rowNum = 0 To numOfRows

		If Request("revert_"& aDiffList( os_id_column, rowNum ) &"_"& aDiffList( old_prod_id_column, rowNum ) ) <> "" Then

			OraParameter("OLD_PROD_ID").Value = aDiffList( old_prod_id_column, rowNum )

			OraParameter("NEW_PROD_ID").Value = Request("revert_"& aDiffList( os_id_column, rowNum ) &"_"& aDiffList( old_prod_id_column, rowNum ) )

			OraParameter("OS_ID").Value = aDiffList( os_id_column, rowNum )

			OraDatabase.ExecuteSQL "BEGIN   pk_Product.Replace_Product ( :OLD_PROD_ID, :NEW_PROD_ID, :OS_ID, :USER_ID );   END;"

		End If

	Next

	'--- Log Action ---

	'objEH.LogAction  _

	'objAccessControl.UserId, _

	'enumAT_EVENT_COMMENT, _

	'"Sub UpdateProducts for OS list="& Request("spos_id_list"), _

	'SCRIPT_NAME, _

	'"Updated Products with new versions.", _

	'OraDatabase

	OraDatabase.Parameters.Remove "OLD_PROD_ID"

	OraDatabase.Parameters.Remove "NEW_PROD_ID"

	OraDatabase.Parameters.Remove "OS_ID"

	OraDatabase.Parameters.Remove "USER_ID"

	objEH.CatchORA ( OraSession )	

End Sub

'----------------------------------------------------------------------------------------------------------------------------------

Function Get_Bom_Name( nBomId )

	OraDatabase.Parameters.Add "BOM_ID", 	nBomId, 	ORAPARM_INPUT, ORATYPE_NUMBER 

	Set rsQry = OraDatabase.DbCreateDynaset( GetQuery ("BomDetails.sql"), ORADYN_DEFAULT )

	Get_Bom_Name = rsQry("bom_name") + VBNewLine + rsQry("bom_version") + "." + rsQry("bom_lifecycle")

	rsQry.Close()

	Set rsQry = Nothing

	OraDatabase.Parameters.Remove "BOM_ID"

End Function

'----------------------------------------------------------------------------------------------------------------------------------

%>

<%

'------------ RUN BEFORE PAGE RENDER ----------

Call GetFormDetails ( parBom_id, objFormCollector )

If Request("action") <> "" Then	

	' --- Form is Valid ---

	Call RevertProducts()

	If objEH.Finally Then

		Call OpenInParentWindow ( Request("rfile") &"?UPDATED=OK"& objPMod.ComposeURLWithout("rfile") )

		Call CloseWindow()

	End If

End If

'----------------------------------------------

%>

<html>

<head>

<SCRIPT LANGUAGE="JavaScript">

<!-- Begin

var checkflag = "false";

function check(field) {

if (checkflag == "false") {

  for (i = 0; i < field.length; i++) {

  field[i].checked = true;}

  checkflag = "true";

  return "Uncheck all"; }

else {

  for (i = 0; i < field.length; i++) {

  field[i].checked = false; }

  checkflag = "false";

  return "Check all"; }

}

//  End -->

</script>

<title>Deployment Manager</title>

<link rel="shortcut icon" href="<%=FavIcon%>"/>

<meta HTTP-EQUIV="Pragma" CONTENT="no-cache">

<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">

<link href="scripts/deployment_manager.css" rel="stylesheet" type="text/css">

<script language="JavaScript" src="scripts/common.js"></script>

<style type="text/css">

<!--

.style8 {font-size: 12px}

-->

</style>

</head>

<body background="images/bg_bage_0.gif" leftmargin="0" topmargin="0" onLoad="self.focus();">

<table width="100%"  border="0" cellspacing="0" cellpadding="10">

  <tr>

    <td bgcolor="#FFFFFF" class="body_txt"><span class="body_h1"><img src="icons/i_linkarrow_black.gif" width="11" height="11" align="absmiddle">&nbsp;Revert Products </span> <br>

    Revert Products, selecting the latest from the Parent BOM.

    </td>

  </tr>	

<%

'-- FROM START --------------------------------------------------------------------------------------------------------------

objFormComponent.FormName = "FormName"

objFormComponent.Action = SCRIPT_NAME

objFormComponent.OnSubmit = "ShowProgress();"

Call objFormComponent.FormStart()

%>    

  <tr>

    <td background="images/bg_login.gif"><table width="100%"  border="0" cellspacing="0" cellpadding="0">

      <tr>

        <td><%=ProgressBar()%>

          <input name="btn" type="submit" class="form_btn" value="Revert">

          <input name="btn" type="reset" class="form_btn" value="Cancel" onClick="self.close();"></td>

        <td align="left">&nbsp;        </td>

      </tr>

    </table></td>

  </tr>

  <tr>

    <td>

<!-- PRODUCT NAME RESULTS ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->		

	<table width="100%"  border="0" cellspacing="10" cellpadding="0">

      <tr>

        <td width="100%" valign="top" nowrap class="body_txt">

		  <!-- MESSAGE +++++++++++++++++++++++++++++++++++++++++++++++++++ -->	

		  <!--#include file="messages/_msg_inline.asp"-->

		  <!-- +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->

		  <%

		  If objFormCollector.Item("parent_bom_id") = "" Then

			Call Messenger ( "This BOM does not have Parent BOM Reference release.", 1, "100%" )

		  End If

		  %>

		  <!-- REVERT PRODUCTS +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->

		  Select Products and click Revert.

          <table width="100%"  border="0" cellspacing="3" cellpadding="0">

            <tr>

			  <td width="1%" nowrap background="images/bg_bage_0h.gif" class="body_col">Revert</td>

              <td width="40%" align="right" nowrap background="images/bg_bage_0h.gif" class="body_col"><div align="left">Location</div></td>

              <td width="20%" align="right" nowrap background="images/bg_bage_0h.gif" class="body_col"><div align="left">Current Version</div></td>

              <td align="right" background="images/bg_bage_0h.gif" class="body_col"><div align="left"><img src="images/spacer.gif" width="1" height="18" align="absmiddle"><%=Get_Bom_Name(objFormCollector.Item("parent_bom_id"))%></div>                <div align="left"></div></td>

              </tr>	  

			<%

			OraDatabase.Parameters.Add "BOM_ID", parBom_id,		ORAPARM_INPUT, ORATYPE_NUMBER 

			OraDatabase.Parameters.Add "COMPARE_BOM_ID", objFormCollector.Item("parent_bom_id"), ORAPARM_INPUT, ORATYPE_NUMBER 

			Set rsQry = OraDatabase.DbCreateDynaset( GetQuery ("RevertProducts.sql"), ORADYN_DEFAULT )

			currPkg_id = 0

			%>

			<%If rsQry.RecordCount < 1 Then%>

			<tr>

              <td colspan="5" class="body_row">No Products to Revert.                 </td>

            </tr>

			<%End If%>

			<%

			While (NOT rsQry.BOF) AND (NOT rsQry.EOF)

			%>

			<%If currPkg_id <> rsQry("pkg_id") Then%>

            <tr>

			  <td nowrap><div align="left"><span class="body_row"><img src="icons/i_product.gif" width="19" height="19" hspace="2" align="absmiddle"><%=rsQry("prod_name")%>                                                                     				   </span></div></td>

              <td nowrap></td>

              <td nowrap class="body_row">&nbsp;</td>

              <td nowrap class="body_row"><div align="center"></div></td>

              <td nowrap class="body_row"></td>

              </tr>

			<tr>

              <td colspan="5" background="images/bg_table_border.gif"><img src="images/spacer.gif" width="1" height="1"></td>

            </tr>

			<%currPkg_id = rsQry("pkg_id")%>

			<%End If%>

            <tr>

              <td align="center" nowrap><input type="checkbox" name="revert_<%=rsQry("os_id") &"_"& rsQry("prod_id")%>" value="<%=rsQry("old_prod_id")%>"> </td>

              <td nowrap class="body_row"><img hspace="2" src="icons/<%=rsQry("node_icon")%>" align="absmiddle" border="0"><%=rsQry("prod_location")%></td>

              <td nowrap class="body_row"><%=rsQry("prod_version")%></td>

              <td nowrap class="body_row"><span class="body_txtr"><%=rsQry("old_pkg_version")%></span></td>

              </tr>

			<tr>

              <td colspan="5" background="images/bg_table_border.gif"><img src="images/spacer.gif" width="1" height="1"></td>

            </tr>			

            <%rsQry.MoveNext

			Wend

			%>

			<tr>

              <td colspan="5" background="images/bg_table_border.gif"><img src="images/spacer.gif" width="1" height="3"></td>

            </tr>

          </table>

		  <%

		  OraDatabase.Parameters.Remove "COMPARE_BOM_ID"

		  OraDatabase.Parameters.Remove "BOM_ID"

		  rsQry.Close

		  Set rsQry = Nothing

		  %>		  </td>

        </tr>

    </table>

	<!-- ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->

    </td>

  </tr>

  <%=objPMod.ComposeHiddenTags()%>

  <input type="hidden" name="action" value="true">

<%

Call objFormComponent.FormEnd()

'-- FROM END ----------------------------------------------------------------------------------------------------------------

%>

</table>

</body>

</html>

<!--#include file="common/globals_destructor.asp"-->