Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>

<%

'=====================================================

'|                                                   |

'|			          wEditBaseEnv				 	 |

'|                                                   |

'=====================================================

%>

<%

Option explicit

Response.Expires = 0

%>

<!--#include file="common/globals.asp"-->

<!--#include file="common/config.asp"-->

<!--#include file="common/common_subs.asp"-->

<!--#include file="common/_popup_window_common.asp"-->

<%

'------------ ACCESS CONTROL ------------------

%>

<!--#include file="_access_control_general.asp"-->

<%

'------------ VARIABLE DEFINITION -------------

Dim rsQry

Dim parBos_id

Dim parBase_env_id

Dim objFormCollector

'------------ CONSTANTS DECLARATION -----------

'------------ VARIABLE INIT -------------------

parBos_id = Request("bos_id")

parBase_env_id = Request("base_env_id")

Set objFormCollector = CreateObject("Scripting.Dictionary")

'------------ CONDITIONS ----------------------

'----------------------------------------------

%>

<%

'--------------------------------------------------------------------------------------------------------------------------

Sub GetFormDetails ( nBaseEnvId, ByRef outobjDetails )

	Dim rsQry, query

	If nBaseEnvId = "" Then Exit Sub

	OraDatabase.Parameters.Add "BASE_ENV_ID", nBaseEnvId,	ORAPARM_INPUT, ORATYPE_NUMBER 

	Set rsQry = OraDatabase.DbCreateDynaset( GetQuery("BaseEnvDetails.sql") , ORADYN_DEFAULT )

	If ((NOT rsQry.BOF) AND (NOT rsQry.EOF)) Then

		outobjDetails.Item ("base_env_id")   = rsQry("base_env_id")

		outobjDetails.Item ("base_env_name") = rsQry("base_env_name")

		outobjDetails.Item ("bom_id") = rsQry("bom_id")

		outobjDetails.Item ("bos_id") = rsQry("bos_id")

	Else

		Err.Raise 8, "Sub GetFormDetails", "Empty record set returned. nBaseEnvId="& nBaseEnvId

	End If

	OraDatabase.Parameters.Remove "BASE_ENV_ID"

	rsQry.Close

	Set rsQry = Nothing

End Sub

'--------------------------------------------------------------------------------------------------------------------------

Function GetBaseOsTypes( nBos_id )

	Dim rsQry, query

	OraDatabase.Parameters.Add "BOS_ID", nBos_id,		ORAPARM_INPUT, ORATYPE_NUMBER 

	Set rsQry = OraDatabase.DbCreateDynaset( GetQuery ("OsTypesCombo.sql"), ORADYN_DEFAULT )

	If rsQry.RecordCount > 0 Then

		GetBaseOsTypes = rsQry.GetRows()

	Else

		GetBaseOsTypes = NULL

	End If

	OraDatabase.Parameters.Remove "BOS_ID"

	rsQry.Close

	Set rsQry = Nothing

End Function

'--------------------------------------------------------------------------------------------------------------------------

Sub UpdateBaseEnv ()

	On Error Resume Next

	OraDatabase.Parameters.Add "BASE_ENV_ID", 	Request("base_env_id"), 	ORAPARM_INPUT, ORATYPE_NUMBER 

	OraDatabase.Parameters.Add "BASE_ENV_NAME", Request("base_env_name"), 	ORAPARM_INPUT, ORATYPE_VARCHAR2

	OraDatabase.Parameters.Add "BOS_ID", 		Request("bos_id"), 			ORAPARM_INPUT, ORATYPE_NUMBER 

	objEH.TryORA ( OraSession )

	OraDatabase.ExecuteSQL _

	"BEGIN   pk_Base_Env.Update_Base_Env ( :BASE_ENV_ID, :BASE_ENV_NAME, :BOS_ID );   END;"

	objEH.CatchORA ( OraSession )

	OraDatabase.Parameters.Remove "BASE_ENV_ID"

	OraDatabase.Parameters.Remove "BASE_ENV_NAME"

	OraDatabase.Parameters.Remove "BOS_ID"

End Sub

'--------------------------------------------------------------------------------------------------------------------------

Sub AddBaseEnv ()

	On Error Resume Next

	OraDatabase.Parameters.Add "BASE_ENV_NAME", Request("base_env_name"), 	ORAPARM_INPUT, ORATYPE_VARCHAR2

	OraDatabase.Parameters.Add "BOS_ID", 		Request("bos_id"), 			ORAPARM_INPUT, ORATYPE_NUMBER 

	OraDatabase.Parameters.Add "BOM_ID", 		Request("bom_id"), 			ORAPARM_INPUT, ORATYPE_NUMBER 

	OraDatabase.Parameters.Add "OS_ID", 		Request("os_id"), 			ORAPARM_INPUT, ORATYPE_NUMBER 

	objEH.TryORA ( OraSession )

	OraDatabase.ExecuteSQL _

	"BEGIN   pk_Base_Env.Add_Base_Env ( :BASE_ENV_NAME, :BOS_ID, :BOM_ID, :OS_ID );   END;"

	objEH.CatchORA ( OraSession )

	OraDatabase.Parameters.Remove "BASE_ENV_NAME"

	OraDatabase.Parameters.Remove "BOS_ID"

	OraDatabase.Parameters.Remove "BOM_ID"

	OraDatabase.Parameters.Remove "OS_ID"

End Sub

'--------------------------------------------------------------------------------------------------------------------------

%>

<%

'------------ RUN BEFORE PAGE RENDER ----------

' --- Get Form details from DB ---

Call GetFormDetails ( parBase_env_id, objFormCollector )

' --- Load Validation Rules ---

Call objForm.LoadValidationRules ( Array("base_env_name"), OraDatabase )		' Load Validation Rules

' --- Enter Form Validation Rule Changes here... ----

'----------------------------------------------------

' --- RUN onPostBack ---

If Request("action") <> "" Then

	If objForm.IsValidOnPostBack Then

		' --- Form is Valid ---

		If parBase_env_id <> "" Then

			Call UpdateBaseEnv()

		Else

			Call AddBaseEnv()

		End If

		If objEH.Finally Then

			Call OpenInParentWindow ( Request("rfile") &"?ADD=OK"& objPMod.ComposeURLWithout("rfile") )

			Call CloseWindow()

		End If

	End If

End If

'----------------------------------------------

%>

<html>

<head>

<title>Deployment Manager</title>

<meta HTTP-EQUIV="Pragma" CONTENT="no-cache">

<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">

<link href="scripts/deployment_manager.css" rel="stylesheet" type="text/css">

<script language="JavaScript" src="scripts/common.js"></script>

</head>

<body background="images/bg_bage_0.gif" leftmargin="0" topmargin="0" onLoad="self.focus();FormName.bos_id.focus();">

<table width="100%"  border="0" cellspacing="0" cellpadding="10">

  <tr>

    <td bgcolor="#FFFFFF" class="body_txt"><span class="body_h1"><img src="icons/i_linkarrow_black.gif" width="11" height="11" align="absmiddle">&nbsp;Base Configuration</span> <br>

    Enter OS type and Base Configuration Name. 

      </td>

  </tr>

  <%

  '-- FROM START ---------------------------------------------------------------------------------------------------------

  objFormComponent.FormName = "FormName"

  objFormComponent.Action = SCRIPT_NAME

  objFormComponent.OnSubmit = "ShowProgress();"

  Call objFormComponent.FormStart()

  %>   

  <tr>

    <td background="images/bg_login.gif"><table width="100%"  border="0" cellspacing="0" cellpadding="0">

      <tr>

        <td><%=ProgressBar()%></td>

        <td align="right"><input name="btn" type="submit" class="form_btn" value="Submit">

          <input name="btn" type="reset" class="form_btn" value="Cancel" onClick="self.close();"></td>

      </tr>

    </table></td>

  </tr>

  <tr>

    <td>

	<!-- MESSAGE +++++++++++++++++++++++++++++++++++++++++++++++++++ -->	

	<!--#include file="messages/_msg_inline.asp"-->

    <!-- +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->

	<table width="100%"  border="0" cellspacing="2" cellpadding="0">

	  <tr>

        <td valign="top" nowrap class="form_iname">Operating System Type</td>

        <td valign="top" class="body_txt"><%=objFormComponent.Combo ( "bos_id", GetBaseOsTypes( objForm.GetValue( "bos_id", objFormCollector.Item("bos_id") )  ), FALSE, "class='form_ivalue'" )%></td>

		<td valign="top"></td>

      </tr>

	  <tr>

        <td nowrap class="form_iname" valign="top">Base Configuration Name </td>

        <td valign="top"><%=objFormComponent.TextBox ( "base_env_name", objForm.GetValue( "base_env_name", objFormCollector.Item("base_env_name") ), "size='50' class='form_ivalue'" )%></td>

        <td valign="top"><%=objForm.Validate ("base_env_name")%></td>

      </tr>

      <tr>

        <td width="10%" class="form_iname">&nbsp;</td>

        <td width="1%">&nbsp;</td>

		<td width="90%" class="val_err"></td>

      </tr>

    </table></td>

  </tr>

  <%=objPMod.ComposeHiddenTags()%>

  <input type="hidden" name="base_env_id" value="<%=parBase_env_id%>">

  <input type="hidden" name="action" value="true">

  <%

  Call objFormComponent.FormEnd()

  '-- FROM END ----------------------------------------------------------------------------------------------------------------

  %>

</table>

</body>

</html>

<%

'------------ RUN AFTER PAGE RENDER -----------

'----------------------------------------------

%><!--#include file="common/globals_destructor.asp"-->