5 KEY OFF
10 CLOSE
20 ON ERROR GOTO 260
30 OPEN "COM2:1200,M,7,1,RS,CS,DS,CD" AS #2 LEN=128
40 EOL$=CHR$(13)+CHR$(10)
50 CLOSE #1
60 CLS:LOCATE 10,1:PRINT TAB(20);"TIMING SERIAL UPLOADER"
65 PRINT TAB(20) "======================":PRINT
70 PRINT TAB(16):INPUT "What LEG please .. (X to end) ";LEG$
75 IF LEG$ = "" THEN 60
80 IF LEG$ = "X" OR LEG$ = "x" THEN 280
82 OPEN "leg"+LEG$ FOR INPUT AS #1
83 PRINT:INPUT "File allready exists, OK to add data ";OK$
84 IF OK$ = "Y" OR OK$ = "y" THEN 88
86 GOTO 50
88 CLOSE #1
90 OPEN "leg"+LEG$ FOR APPEND AS #1
100 CLS:LOCATE 10,20:PRINT "WAITING FOR INPUT......"
110 PRINT #2,
120 A$=""
130 WHILE NOT EOF(2)
140 A$=A$+INPUT$(LOC(2),2)
150 IF INSTR(A$,EOL$)<>0 THEN GOTO 180
160 WEND
170 GOTO 130
180 IF INSTR(A$,"X")<>0 THEN GOTO 50
190 TEAM=VAL(MID$(A$,1,3))
200 HOURS=VAL(MID$(A$,5,2))
210 MINS=VAL(MID$(A$,8,2))
220 SECS=VAL(MID$(A$,11,2))
230 PRINT "TEAM #..";TEAM;:PRINT TAB(20);"    ";HOURS;":";MINS;":";SECS
240 PRINT #1,A$;
250 GOTO 110
260 IF ERR = 53 THEN RESUME 88
265 PRINT "** ERROR NUMBER ";ERR
266 PRINT:INPUT "Return to continue";C$
270 RESUME 50
280 CLOSE
290 system