item:" & item.name & ":" & item & "

Send_Email:SSfromName:" & SSfromName
'Response.write "
Send_Email:SSfrom:" & SSfrom
'Response.write "
Send_Email:SSto:" & SSto
'Response.write "
Send_Email:SSsubject:" & SSsubject
'Response.write "
Send_Email:SSbody:" & SSbody

   canSend = FALSE
   Set Mail = Server.CreateObject("Persits.MailSender")
   Mail.Host = MAIL_SERVER
   Mail.From = SSfrom
   Mail.FromName = SSfromName

   ' Send TO:
   ' Handle a Dictionary of names
   If IsObject(SSto) AND (TypeName(SSto) <> "IOraField") Then
      Keys = SSto.Keys
      For Each Key In Keys
         Mail.AddAddress Key, SSto.Item( Key )
      Next

      If SSto.Count > 0 Then canSend = TRUE
   Else

      Mail.AddAddress SSto
      If SSto <> "" Then canSend = TRUE
   End If

   Mail.Subject = SSsubject
   Mail.IsHTML = True
   Mail.Body = SSbody

   If NOT IsEmpty(oAttachments) AND NOT IsNull(oAttachments) Then
       ' Add Attachments     DDDDDDD  Sash,
       ' It appears as if AddEmbededImage is premium functionality that costs money, can we just do a normal add attachment?
       If IsObject( oAttachments ) Then
          Keys = oAttachments.Keys
          For Each Key In Keys
       '      Mail.AddEmbeddedImage rootPath & Key, oAttachments.Item( Key )
              Mail.AddAttachment oAttachments.Item( Key )
          Next
        Else
              Mail.AddAttachment oAttachments
       End If
    End If

   On Error Resume Next
   If canSend Then   Mail.Send   ' send message

End Sub

'-----------------------------------------------------------------------------------------------------------------
'   Record and Report a Release Manager event
'       Record in the machines Event Log
'       Report via email
'   Used to report error conditions that need to be bought to the attention of some sys admin
'   Args:   eventType       - one of enumEVENT_* ( ie:enumEVENT_ERROR)
'           SSlocation      - Indication of location/operation
'           SSvalues        - Values. Will be added into the message
'           SSerror_message - Error message
'
Sub Report_Event ( eventType, SSlocation, SSvalues, SSerror_message  )
    On Error Resume Next
    Dim WshNetwork, SSmsg
    Set WshNetwork = Server.CreateObject("WScript.Network")

   ' Compose Message
   SSmsg = _
   "-- User Info  --"& VBNewLine &_
   "Logged In: " & objAccessControl.UserLogedIn & VBNewLine &_
   "Domain: " & objAccessControl.Domain & VBNewLine &_
   "UserName: " & objAccessControl.UserName & VBNewLine &_
   "FullName: " & objAccessControl.FullName & VBNewLine &_
   "UserEmail: " & objAccessControl.UserEmail & VBNewLine &_
   "UserId: " & objAccessControl.UserId & VBNewLine &_
   VBNewLine &_
   "-- Script Info  --"& VBNewLine &_
   "Host Name: "& Request.ServerVariables("SERVER_NAME") & ":" & Request.ServerVariables("SERVER_PORT") & VBNewLine &_
   "Script Name: "& Request.ServerVariables("SCRIPT_NAME") & VBNewLine &_
   VBNewLine &_
   "-- Error Location --"& VBNewLine &_
   SSlocation & VBNewLine &_
   VBNewLine &_
   "-- Values --"& VBNewLine &_
   SSvalues & VBNewLine &_
   VBNewLine &_
   "-- Error Message --"& VBNewLine &_
   SSerror_message & VBNewLine

    '-- Raise this message at these places...
    '-- Create an event in the system event log
    '-- Send out an email
    Call Send_Event( eventType, SSmsg )
    Call Send_Email ( "Release Manager Notification", _
                       ADMIN_EMAIL, _
                       FAULT_EMAIL_LIST, _
                       "Release Manager Error", _
                       Replace(SSmsg,VBNewLine, "
"), _
                       null )

    '----------------------------------------
   Set WshNetwork = Nothing
End Sub

'-----------------------------------------------------------------------------------------------------------------------------
'   Record Event in OS log
'   Create an event in the system event log
'
'   Args:   eventType       - one of enumEVENT_* ( ie:enumEVENT_ERROR)
'           SSmsg           - Message Body
Sub Send_Event( eventType, SSmsg )
    On Error Resume Next
    Dim WshShell
    Set WshShell = Server.CreateObject("WScript.Shell")
    WshShell.LogEvent eventType, SSmsg
    Set WshShell = Nothing
End Sub

'-----------------------------------------------------------------------------------------------------------------------------
Sub Iterate_UP_the_tree ( NNrtag_id, HHstart_with, HHresult )
   Dim rsTemp, Query_String
   Dim seekPKGs, seekNOTpkgs

   seekPKGs = Join(HHstart_with.Keys, ",")
   If seekPKGs = "" Then seekPKGs = "-1"
   seekNOTpkgs = "-1"

   Do While seekPKGs <> "-1"
      Query_String = _
      " SELECT DISTINCT dep.pkg_id"&_
      "    FROM package_dependencies dep, release_content rel"&_
      "   WHERE rel.pv_id = dep.pv_id"&_
      "     AND rel.rtag_id = "& NNrtag_id &_
      "     AND dpkg_id IN ( "& seekPKGs &" ) "&_
      "     AND pkg_id NOT IN ( "& seekNOTpkgs &" )"
      '"     AND dep.dpv_id NOT IN ( SELECT iw.iw_id FROM ignore_warnings iw WHERE iw.rtag_id = "& NNrtag_id &" )"
      Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))

      If rsTemp.RecordCount < 1 Then Exit Do

      seekPKGs = "-1"
      While ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF))
         If NOT HHresult.Exists(Cstr(rsTemp.Fields("pkg_id"))) Then HHresult.Add Cstr(rsTemp.Fields("pkg_id")), ""
         seekPKGs = seekPKGs &","& rsTemp.Fields("pkg_id")
         rsTemp.MoveNext
      WEnd

      seekNOTpkgs = seekNOTpkgs &","& seekPKGs
   Loop

End Sub
'-----------------------------------------------------------------------------------------------------------------------------
Sub Iterate_DOWN_the_tree (   NNrtag_id, HHstart_with, HHresult )
   Dim rsTemp, Query_String
   Dim seekPKGs, seekNOTpkgs

   seekPKGs = Join(HHstart_with.Keys, ",")
   If seekPKGs = "" Then seekPKGs = "-1"
   seekNOTpkgs = "-1"

   Do While seekPKGs <> "-1"
      Query_String = _
      " SELECT DISTINCT dep.dpkg_id"&_
      "    FROM package_dependencies dep, release_content rel"&_
      "   WHERE rel.pv_id = dep.pv_id"&_
      "     AND rel.rtag_id = "& NNrtag_id &_
      "     AND pkg_id IN ( "& seekPKGs &" ) "&_
      "     AND dpkg_id NOT IN ( "& seekNOTpkgs &" )"
      Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))

      If rsTemp.RecordCount < 1 Then Exit Do

      seekPKGs = "-1"
      While ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF))
         If NOT HHresult.Exists(Cstr(rsTemp.Fields("dpkg_id"))) Then HHresult.Add Cstr(rsTemp.Fields("dpkg_id")), ""
         seekPKGs = seekPKGs &","& rsTemp.Fields("dpkg_id")
         rsTemp.MoveNext
      WEnd

      seekNOTpkgs = seekNOTpkgs &","& seekPKGs
   Loop

End Sub
'-----------------------------------------------------------------------------------------------------------------------------
Class TempSession
   Function Value ()
      Value = Session("RELEASEMANAGER_temp")
   End Function

   Sub Add ( SSstr )
      Session("RELEASEMANAGER_temp") = Session("RELEASEMANAGER_temp") & SSstr
   End Sub

   Sub Clean ()
      Session("RELEASEMANAGER_temp") = NULL
   End Sub
End Class
'-----------------------------------------------------------------------------------------------------------------------------
Sub DisplayInfo ( SSmsg, SSwidth )
   Dim msg
   If SSmsg = "" Then Exit Sub

   Select Case UCase( SSmsg )
   Case "ISSUES_IMPORTED"
      msg = "Import is complete. 
Click on Close button if you are finished."
   Case "MAKE_OFFICIAL_WARNING"
      msg = "Note that making a package official will prevent any further change to it."
   Case "APPLY_LABEL_TO_ALL_WARNING"
      msg = "This will overwrite any existing labels on selected packages."
   Case "BLANK_LABEL_WARNING"
      msg = "Some dependencies in the export list above, do not have a label!"
   Case "PERSONAL_VIEW_NOT_SETUP"
      msg = "Your View is not setup!

Either set your view using My Account > Views menu

OR

switch to Base view (Full view) by clicking on  icon above."
   Case "EMPTY_RELEASE_CONTENTS"
      msg = "Release content is empty!

Use + button to add packages to a release."
   Case "PKG_NAME_REQUIRED"
      msg = "Package Name required!
You are required to select at least one package name."
   Case "ADD_PATCH_WARNING"
      msg = "Note that patches cannot be used in your build dependencies."
   Case "NEW_PATCH_AVAILABLE"
      msg = "New Patch is Required
One or more Build Dependencies have been patched.
Please click Add button to create patch for this package."

   Case "NOT_FOUND_IN_PKG_ARCHIVE_RELEASE_NOTES"
      msg = "Regenerating release notes...
It may take a minute. Please try refreshing this page a bit later."
   Case "FAILED_GENERATING_RELEASE_NOTES"
      msg = "Failed generating release notes!"
   Case "GENERATING_RELEASE_NOTES"
      msg = "Generating release notes...
It may take a minute. Please try refreshing this page a bit later."
   Case "NO_PREVIOUS_VERSION_RELEASE_NOTES"
       msg = "Previous Version is Unknown!
Please specify previous version by clicking on 'Show Details...' above.
Release notes are not generated."
   Case "RELEASE_NOTES_PLACEHOLDER_PACKAGE"
       msg = "Place Holding Package!
This package is manually built, does not have a build standard and does not exist in dpkg_archive. It is used as a placeholder.
Release notes are not generated."

   Case "PACKAGE_FOUND_IN_OTHER_LOCATIONS"
      msg = "This package is also found in other locations."
   Case "DOC_NUMBER_NOTFOUND"
      msg = "Document number "& Request("doc_num") &" does not correspond to any document!"
   Case "DOC_NUMBER_FOUND"
      msg = "Document found. Click "Import" to link the document."
   Case "UNIT_TEST_NOT_DONE"
      msg = "Unit test is Not Done!
Click here to supply/edit reason."
   Case "PACKAGE_NOT_PART_OF_RELEASE"
      msg = "Package is Not Part of This Release Anymore!
This package cannot be found in the list on the left-hand side.
You can use 'lookup:' on the left-hand side to find the package inside this release. "

   Case "NOT_FOUND_IN_PKG_ARCHIVE_FILE_GENERATE"
      msg = "This package is not found in dpkg_archive!
Files and folders are not captured."
   Case "NO_PRODUCT_FILES_CAPTURED"
      msg = "Files and Folders not found for this product!
Capture of product components can only be done during the build time."

   Case "MASS REF REFERENCE"
      msg = "New Version can only be created in the Release's associated MASS REF: "& pkgInfoHash.Item("pkg_name") &" "& pkgInfoHash.Item("pkg_version") &""

   Case "REPEAT_SCHEDULE_NOT_SELECTED"
      msg = "YOU MUST SELECT A VALUE FOR REPEAT SCHEDULED DOWNTIME"

   Case "PKG_NAME_INVALID"
      msg = "Package Name Invalid!
This package name is invalid. Package names must only consist of alpha-numeric characters, underscores and dashes (A-Z 0-9 _ -), and cannot include spaces or any other symbols."

   Case "PKG_NAME_EXISTS"
      msg = "Package Name Already Exists!
This package name already exists, please try again."

   End Select
%>

  

    

     

        

          

          
<%=msg%>
        
      
  



<%

End Sub
'-----------------------------------------------------------------------------------------------------------------------------
Sub Messenger ( sMessage, nMessageType, sWidth )
   Dim msgTemplate, Img

   If (sMessage = "") OR IsNull(sMessage) Then Exit Sub

   Select Case CStr(nMessageType)
      Case "1"
         Img = "s_critical.gif"
      Case "2"
         Img = "s_warning.gif"
      Case "3"
         Img = "s_note.gif"
      Case Else
         Img = nMessageType
   End Select


   msgTemplate = ReadFile( APP_ROOT &"\scripts\message_style.html" )
   msgTemplate = Replace( msgTemplate, "%WIDTH%", sWidth )
   msgTemplate = Replace( msgTemplate, "%IMAGE%", Img )
   msgTemplate = Replace( msgTemplate, "%MESSAGE%", sMessage )

   Response.write msgTemplate
End Sub
'-----------------------------------------------------------------------------------------------------------------------------
Function Default_Label ( SSpv_id, SSbuild_type, SSchange_type, SSpkg_name, SSpkg_version, SSv_ext )
    If SSbuild_type = "A" Then
        If  SSchange_type = "F" Then
            Default_Label = SSpkg_name & "_" & SSpkg_version & ".WIP"
        else
            Default_Label = UCase(SSpkg_name & "." & SSpv_id & SSv_ext) & ".WIP"
        End If
    Else
        Default_Label = SSpkg_name & "_" & SSpkg_version
    End If
End Function
'-----------------------------------------------------------------------------------------------------------------------------
Function Format_Version ( SSpkg_version, SSv_ext )
   Dim tempArr, tempVersion, patchArr, seg, myVersion
   myVersion = SSpkg_version

   If NOT IsNull(SSv_ext) Then
      myVersion = Left ( myVersion, Len(myVersion) - Len(SSv_ext) )
   End If

   tempArr = Split (myVersion, ".")
   For Each seg In tempArr
      If Len(seg) < 2 Then
         ' single digit number
         tempVersion = tempVersion &"0"& seg

      Else
         seg = Replace(seg, "_", "-")   ' make sure that there is no _ in segment
         If InStr( seg, "-" ) > 0 Then
            ' patch version supplied
            patchArr = Split(seg, "-")
            If Len(patchArr(0)) < 2 Then
               ' single digit number
               tempVersion = tempVersion &"0"& patchArr(0) &"_0"& patchArr(1)
            Else
               ' double digit number
               tempVersion = tempVersion & patchArr(0) &"_0"& patchArr(1)
            End If

         Else
            ' double digit no patch
            tempVersion = tempVersion & seg
         End If

      End If

   Next

   Format_Version = tempVersion
End Function
'-----------------------------------------------------------------------------------------------------------------------------
Function DefineStateIcon ( NNpkg_state, CCdlocked, sIgnoreWarnings, cIsPatchIgnore, cBuildType, bForEnvironment )
	
   If IsNull(NNpkg_state) Then
	  DefineStateIcon = ""
	  Exit Function
   End If

   If NOT IsNull(sIgnoreWarnings) Then
      '-- Ignore Warning is on
      If IsNull(cIsPatchIgnore) Then
         DefineStateIcon = enum_imgIgnoring
      Else
         DefineStateIcon = enum_imgPatchIgnoring
      End If

   Else
      Select Case CInt( NNpkg_state )
         Case enumPKG_STATE_OK
            If (CCdlocked = "N") OR (CCdlocked = "R") Then
               DefineStateIcon = enum_imgBuilding
            ElseIf (CCdlocked = "P") Then
               DefineStateIcon = enum_imgPending
            ElseIf (CCdlocked = "A") Then
               DefineStateIcon = enum_imgApproved
            Else
               DefineStateIcon = enum_imgBlank
            End If

         Case enumPKG_STATE_MAJOR
            DefineStateIcon = enum_imgCritical

         Case enumPKG_STATE_MINOR
            DefineStateIcon = enum_imgWarning

         Case enumPKG_STATE_MAJOR_READY
            DefineStateIcon = enum_imgCReady

         Case enumPKG_STATE_MINOR_READY
            DefineStateIcon = enum_imgWReady

         Case enumPKG_NOT_FOUND
            DefineStateIcon = enum_imgNotFound

         Case enumPKG_STATE_NEW_PATCH
            DefineStateIcon = enum_imgPatchAvailable

         Case enumPKG_STATE_DEPRECATED
            DefineStateIcon = enum_imgDeprecated

         Case enumPKG_STATE_DEPRECATED_DEPENDENT
            DefineStateIcon = enum_imgDeprecatedDependent

         Case enumPKG_ADVISORY_RIPPLE
            DefineStateIcon = enum_imgAR

         Case enumPKG_ADVISORY_RIPPLE_DEPENDENT
            DefineStateIcon = enum_imgARD

         Case enumPKG_PEGGED_VERSION
            DefineStateIcon = enum_imgGreenPin

         Case enumPKG_SDK_IMPORT
            DefineStateIcon = enum_imgSdkImport

         Case enumPKG_SDK_DEPENDENCY
            DefineStateIcon = enum_imgSdkDep

         Case enumPKG_UNBUILDABLE
            DefineStateIcon = enum_imgUnBuildable

         Case enumPKG_BUILDING
             DefineStateIcon = enum_imgCompiling

         Case enumPKG_SCHEDULED
             DefineStateIcon = enum_imgScheduled

        Case enumPKG_BUILDFAIL
             DefineStateIcon = enum_imgBuildFail

        Case enumPKG_BUILDEXCLUDE
             DefineStateIcon = enum_imgBuildExclude

      End Select

      If (NOT bForEnvironment) AND _
         (cBuildType = "A") AND _
         (CCdlocked <> "Y") AND _
         (DefineStateIcon <> enum_imgBlank) AND _
         (DefineStateIcon <> enum_imgBuilding)  AND  _
         (DefineStateIcon <> enum_imgNotFound) OR _
         ( Request("rtag_id") = ""  AND  Request("FRrtag_id") = "")  _
         Then

         DefineStateIcon = ""

       End If
   End If
End Function
'-----------------------------------------------------------------------------------------------------------------------------
Function DefineStateIconSimple ( NNpkg_state, CCdlocked)

      DefineStateIconSimple = ""
      Select Case CInt( NNpkg_state )
         Case enumPKG_STATE_OK
            If (CCdlocked = "R") OR (CCdlocked = "A") Then
               DefineStateIconSimple = enum_imgBuilding
            ElseIf (CCdlocked = "P") Then
               DefineStateIconSimple = enum_imgPending
            ElseIf (CCdlocked = "Y") Then
               DefineStateIconSimple = enum_imgReleasedLocked
            ElseIf (CCdlocked = "N") Then
               DefineStateIconSimple = enum_imgReleasedUnlocked
            Else
               DefineStateIconSimple = enum_imgBlank
            End If

         Case enumPKG_STATE_MAJOR
            DefineStateIconSimple = enum_imgCritical

         Case enumPKG_STATE_MINOR
            DefineStateIconSimple = enum_imgWarning

         Case enumPKG_STATE_MAJOR_READY
            DefineStateIconSimple = enum_imgCReady

         Case enumPKG_STATE_MINOR_READY
            DefineStateIconSimple = enum_imgWReady

         Case enumPKG_NOT_FOUND
            DefineStateIconSimple = enum_imgNotFound

         Case enumPKG_STATE_NEW_PATCH
            DefineStateIconSimple = enum_imgPatchAvailable

         Case enumPKG_STATE_DEPRECATED
            DefineStateIconSimple = enum_imgDeprecated

         Case enumPKG_STATE_DEPRECATED_DEPENDENT
            DefineStateIconSimple = enum_imgDeprecatedDependent

         Case enumPKG_ADVISORY_RIPPLE
            DefineStateIconSimple = enum_imgAR

         Case enumPKG_ADVISORY_RIPPLE_DEPENDENT
            DefineStateIconSimple = enum_imgARD

         Case enumPKG_PEGGED_VERSION
            DefineStateIconSimple = enum_imgGreenPin

         Case enumPKG_SDK_IMPORT
            DefineStateIconSimple = enum_imgSdkImport

         Case enumPKG_SDK_DEPENDENCY
            DefineStateIconSimple = enum_imgSdkDep

      End Select
End Function
'-----------------------------------------------------------------------------------------------------------------------------
Function DefineStateSmallIcon ( NNpkg_state, CCdlocked )
   Select Case CInt( NNpkg_state )
   Case enumPKG_STATE_OK
      If CCdlocked = "N" Then
         DefineStateSmallIcon = enum_SMALL_imgBuilding
      Else
         DefineStateSmallIcon = enum_SMALL_imgOK
      End If

   Case enumPKG_STATE_MAJOR
      DefineStateSmallIcon = enum_SMALL_imgCritical

   Case enumPKG_STATE_MINOR
      DefineStateSmallIcon = enum_SMALL_imgWarning

   Case enumPKG_STATE_MAJOR_READY
      DefineStateSmallIcon = enum_SMALL_imgCReady

   Case enumPKG_STATE_MINOR_READY
      DefineStateSmallIcon = enum_SMALL_imgWReady

   End Select
End Function
'-----------------------------------------------------------------------------------------------------------------------------
Function PatchIcon ( cIsPatch, cIsPatchObsolete )
   If IsNull(cIsPatch) Then
      PatchIcon = ""
   Else
      If IsNull(cIsPatchObsolete) Then
         PatchIcon = ""
      Else
         PatchIcon = ""
      End If
   End If
End Function
'-----------------------------------------------------------------------------------------------------------------------------
' Function that returns true of false if the item exists in the array
'-----------------------------------------------------------------------------------------------------------------------------
Function inArray(item, aItems)
   Dim element
   inArray = false
   for each element in aItems
      If element = item Then
         inArray=true
      End If
   next
End Function
'-----------------------------------------------------------------------------------------------------------------------------
' Function:     GetCurrentParameters    
' Description:  Setup some very basic data that is common to (almost) pages
'               Uses Request("proj_id"), Request("rtag_id") and Request("pv_id")
'
'               Given an rtag_id it will determine the enclosing project
'
'               If a valid Release will also fill in releaseInfoHash
'                   Done here as its info we will need any way and its better to have
'                   one database access than two ( or three )
'
' Returns:      nProjId     proj_id of rtag_id
'               sProjName
'               nRtagId     rtag_id
'               sRtagName
'               nPvid       pv_id
'
'               releaseInfoHash - Populates
'
Function GetCurrentParameters( nProjId, sProjName, nRtagId, sRtagName, nPvId )
   Dim rsQry,query

   ' Set defaults
   nProjId    = -1
   sProjName  = ""
   nRtagId    = -1
   sRtagName  = ""
   nPvId      = -1

   ' Set the ID values from the url
   If Request("pv_id") <> ""   Then nPvId   = CDbl(Request("pv_id"))
   If Request("proj_id") <> "" Then nProjId = CDbl(Request("proj_id"))
   If Request("rtag_id") <> "" Then nRtagId = CDbl(Request("rtag_id"))


   ' Get parameters from database

   If Request("rtag_id") <> "" Then
       GetReleaseInfo (nRtagId)
       sProjName = UCase(releaseInfoHash("proj_name"))
       nProjId = CDbl(releaseInfoHash("proj_id")) 
       sRtagName = releaseInfoHash("rtag_name")

   ElseIf Request("proj_id") <> "" Then
      OraDatabase.Parameters.Add "PROJ_ID",       Request("proj_id"),   ORAPARM_INPUT, ORATYPE_VARCHAR2

      query = _
      " SELECT proj.proj_name, proj.proj_id"&_
      " FROM projects proj"&_
      " WHERE proj.proj_id = :PROJ_ID"

      Set rsQry = OraDatabase.DbCreateDynaset( query, cint(0))
      If ((NOT rsQry.BOF) AND (NOT rsQry.EOF)) Then
         sProjName = UCase(rsQry.Fields("proj_name"))
      End If
      rsQry.Close()
      Set rsQry = nothing
      OraDatabase.Parameters.Remove "PROJ_ID"
    
   End If


End Function
'-----------------------------------------------------------------------------------------------------------------------------
Function GetEnvName ( nEnvTab )
   Select Case CInt( nEnvTab )
      Case enumENVTAB_WORK_IN_PROGRESS
         GetEnvName = "Work In Progress"

      Case enumENVTAB_PLANNED
         GetEnvName = "Pending"

      Case enumENVTAB_RELEASED
         GetEnvName = "Released"

   End Select

End Function
'-----------------------------------------------------------------------------------------------------------------------------
Function Title (rtagId)
   Dim rsQry

   If rtagId = "" Then
      Title = "Release Manager"
   Else
      Set rsQry = OraDatabase.DbCreateDynaset( "SELECT RT.RTAG_NAME, P.PROJ_NAME FROM PROJECTS P, RELEASE_TAGS RT WHERE RT.PROJ_ID = P.PROJ_ID AND RT.RTAG_ID="& rtagId, ORADYN_DEFAULT )
      Title = rsQry("proj_name")&">"&rsQry("rtag_name")
      rsQry.Close()
      Set rsQry = Nothing
   End If

End Function
'-------------------------------------------------------------------------------------
Function Check_Package_WIP_Already_Exists(NNrtag_id, NNpv_id)
   Dim Query_String, rsQry

   Query_String = _
   "   SELECT * "&_
   "   FROM planned pl, package_versions pv "&_
   "   WHERE pl.rtag_id = "& NNrtag_id &_
   "   AND pv.pv_id = pl.pv_id "&_
   "   AND pv.dlocked = 'A' "&_
   "   AND pv.pkg_id = (SELECT pkg_id "&_
       "                  FROM package_versions "&_
       "                 WHERE pv_id = "& NNpv_id &") "&_
   "   AND pv.v_ext = (SELECT v_ext "&_
   "                  FROM package_versions "&_
       "                 WHERE pv_id = "& NNpv_id &")"


   Set rsQry = OraDatabase.DbCreateDynaset( Query_String , cint(0) )

   Check_Package_WIP_Already_Exists = rsQry.RecordCount

   rsQry.Close()
   Set rsQry = Nothing
End Function
'-----------------------------------------------------------------------------------------------------------------------------
Function ValidateCodeReviewURL ( sCodeReviewURL )
  Dim isValid
  Dim sTempBaseURL
  Dim httpRegEx
   Set httpRegEx = new RegExp

   httpRegEx.Pattern = "^https?:\/\/"

   ' Removes ending slash from project's base URL for ease of comparison.
   sTempBaseURL = Left(baseURL, Len(baseURL)-1)
   ' Removes the project's base URL from the URL specified (if it's present).
   codeReviewURL = Replace(sCodeReviewURL, sTempBaseURL, "")
   ' Removes the slash from the beginning of the resulting URL (if it's present).
   If InStr(codeReviewURL, "/") = 1 Then
     codeReviewURL = Replace(codeReviewURL, "/", "", 1, 1)
   End If

   ' If the URL doesn't contain the http:// prefix, assume that it's correct.
   If NOT httpRegEx.Test(codeReviewURL) AND Len(codeReviewURL) > 0 Then
     isValid = True
   Else
     ' If the URL still contains the http:// prefix and is longer than the base
     ' URL, assume that it is an invalid URL because of a differing base URL.
     If Len(sCodeReviewURL) > Len(baseURL) Then
       Response.Write("")
     Else
     ' If the URL still contains the http:// prefix and is shorter than the base
     ' URL, assume that it is incomplete.
       Response.Write("")
     End If
     ' Otherwise, the URL matches the base URL exactly, which is also invalid.
     codeReviewURL = sCodeReviewURL
     isValid = False
   End If
   ValidateCodeReviewURL = isValid
End Function
'----------------------------------------------------------------------------------------------------------------------------------------
Function Is_Page_Editable ( cDlocked )
   ' Editable if (   (unlocked OR rejected)
   '              OR ( NOT released/locked AND EditReleaseNotesInPending allowed)
   '              OR (released/locked AND EditNonCriticalInfoForLockedPackage allowed)
   '             )
   '             AND user logged in
   If (((cDlocked = "N") OR (cDlocked = "R")) OR ((cDlocked <> "Y") AND (canActionControlInProject("EditReleaseNotesInPending"))) OR ((cDlocked = "Y") AND (canActionControlInProject("EditNonCriticalInfoForLockedPackage")))) AND objAccessControl.UserLogedIn Then
      Is_Page_Editable = TRUE
   Else
      Is_Page_Editable = FALSE
   End If
End Function
'----------------------------------------------------------------------------------------------------------------------------------------
Function Is_Section_Editable ( )
   If scriptName = "fixed_issues.asp" AND objAccessControl.UserLogedIn Then
      Is_Section_Editable = TRUE
   Else
      Is_Section_Editable = FALSE
   End If
End Function
'----------------------------------------------------------------------------------------------------------------------------------------
Function Is_Critical_Section_Editable ( cDlocked )
   ' Editable if (   (unlocked OR rejected)
   '              OR ( NOT released/locked AND EditReleaseNotesInPending allowed)
   '              OR (released/locked AND EditCriticalInfoForLockedPackage allowed)
   '             )
   '             AND user logged in
   If (((cDlocked = "N") OR (cDlocked = "R")) OR ((cDlocked <> "Y") AND (canActionControlInProject("EditReleaseNotesInPending"))) OR ((cDlocked = "Y") AND (canActionControlInProject("EditCriticalInfoForLockedPackage")))) AND objAccessControl.UserLogedIn Then
      Is_Critical_Section_Editable = TRUE
   Else
      Is_Critical_Section_Editable = FALSE
   End If
End Function

'---------------------------------------------------------------
' Function: getLastNonRippleVersionPVID
'
' Purpose: returns the last non-ripple version of the package
'
' Arguments: this_pv_id : string
'
' Notes: In the past, users used to manually perform ripple builds.
'        This function does not detect those as ripples. It could be
'        made to do so but it would not be reliable. For example, it
'        could check to see if the word "ripple" appears in the
'        comments field of the record set of the SWL query.  That
'        might catch some of those records, but assumes the user
'        wrote the wor ripple into the comments (reason for version).
'
Function getLastNonRippleVersionPVID( this_pv_id, ByRef rippleBasePvid, ByRef lastNonRipplePvid )
   Dim queryResult
   Dim queryString
   Dim lastNonRipple

   ' default return value in case don't find anything
   getLastNonRippleVersionPVID = this_pv_id
   lastNonRipple = this_pv_id

   ' Get a list of all previous non-ripple builds starting with the current pvid
   '    The first entry will be the base entry of the current ripple
   '    The second entry will be the previous significant entry
   queryString = _
        "SELECT pv_id,last_pv_id,pkg_version,v_ext,build_type " &_
        "FROM " &_
        "  (SELECT build_type,last_pv_id,pv_id,pkg_version,v_ext " &_
        "  FROM " &_
        "    (SELECT pv.build_type,pv.last_pv_id AS raw_last_pvid ,pv_id,pv.pkg_version,pv.v_ext,DECODE(pv.pv_id, pv.last_pv_id, NULL, pv.last_pv_id) AS last_pv_id " &_
        "    FROM release_manager.package_versions pv " &_
        "    WHERE pv.PKG_ID IN " &_
        "      (SELECT pkg_id " &_
        "      FROM release_manager.package_versions pv " &_
        "      WHERE pv.pv_id = " & this_pv_id &_
        "      ) " &_
        "    ) " &_
        "    START WITH pv_id                    = " & this_pv_id &_
        "    CONNECT BY nocycle prior last_pv_id = pv_id " &_
        "  ) " &_
        "WHERE build_type != 'Y' "


   Set queryResult = OraDatabase.DbCreateDynaset( queryString, cint(0))

   ' First entry - Base of the current ripple (may be myself)
   If ((NOT queryResult.BOF) AND (NOT queryResult.EOF)) Then
         getLastNonRippleVersionPVID = queryResult("pv_id")
         lastNonRipple = queryResult("pv_id")

        ' Second entry - Previous Non Ripple Entry
        queryResult.MoveNext
        If ((NOT queryResult.BOF) AND (NOT queryResult.EOF)) Then
            getLastNonRippleVersionPVID = queryResult("pv_id")
        End If
   End If

   queryResult.Close()
   Set queryResult = nothing

   If Not isNull(rippleBasePvid) Then rippleBasePvid = lastNonRipple 
   If Not isNull(lastNonRipplePvid) Then lastNonRipplePvid = getLastNonRippleVersionPVID

End Function


Function getLastNonRippleVersionPVIDLimitedByDate( this_pv_id, limitDate )
   Dim queryResult
   Dim queryString

   ' default return value in case don't find anything
   getLastNonRippleVersionPVIDLimitedByDate = this_pv_id

   ' Get a list of all previous non-ripple builds starting with the cuurent pvid
   '    The first entry will be the base entry of the current ripple
   '    The second entry will be the previous significant entry
   queryString = _
            "SELECT last_pv_id, pv_id, pkg_version, v_ext,MODIFIED_STAMP " &_
            "FROM " &_
            "  (SELECT pv.build_type, pv.last_pv_id, pv_id, pv.pkg_version, pv.v_ext, pv.MODIFIED_STAMP" &_
            "  FROM release_manager.package_versions pv" &_
            "    START WITH pv.pv_id = " + this_pv_id &_
            "    CONNECT BY nocycle prior pv.last_pv_id = pv.pv_id" &_
            "  ) where build_type != 'Y' " &_
            "    AND MODIFIED_STAMP >= TO_DATE('" & limitDate & "','DY DD-MON-YYYY')"

   Set queryResult = OraDatabase.DbCreateDynaset( queryString, cint(0))

   ' First entry - Base of the current ripple (may be myself)
   If ((NOT queryResult.BOF) AND (NOT queryResult.EOF)) Then
         getLastNonRippleVersionPVIDLimitedByDate = queryResult("pv_id")

        ' Second entry - Previous Non Ripple Entry
        queryResult.MoveNext
        If ((NOT queryResult.BOF) AND (NOT queryResult.EOF)) Then
            getLastNonRippleVersionPVIDLimitedByDate = queryResult("pv_id")
        End If
   End If

   queryResult.Close()
   Set queryResult = nothing
End Function

'---------------------------------------------------------------
' Function: getPreviousVersionPVID
'
' Purpose: returns the immediate predecssor version of the given
'          package version
'
' Arguments: this_pv_id : string
'
' Notes:
'
Function getPreviousVersionPVID( this_pv_id )
   Dim queryResult
   Dim queryString

   getPreviousVersionPVID = ""

   queryString = "SELECT last_pv_id FROM package_versions WHERE pv_id = " & this_pv_id

   Set queryResult = OraDatabase.DbCreateDynaset( queryString, cint(0))

    If ((NOT queryResult.BOF) AND (NOT queryResult.EOF)) Then
      getPreviousVersionPVID = queryResult("last_pv_id")
   End If

   queryResult.Close()
   Set queryResult = nothing

End Function

'---------------------------------------------------------------
' Function: getLastSignificantPVID
'
' Purpose: Returns the last significant (man-made) version (PV_ID) that
'          is a predecessor to the specified pv_id
'
' Arguments: pv_id       : Uniquely identifies this package version
'            last_pv_id  : Uniquely identifies the predecssor of this package version
' Notes:
'
Function getLastSignificantPVID (pv_id, last_pv_id)

   getLastSignificantPVID = ""

   If( (NOT IsNull(last_pv_id)) AND (last_pv_id <> pv_id) ) Then

      ' Get the pv_id for the current version, and if necessary, work back through any ripple versions as necessary
      ' to get a non-ripple version ancestor
        pv_id = getLastNonRippleVersionPVID( pv_id , NULL, NULL)
        If (pv_id <> "") Then
            getLastSignificantPVID = pv_id
        End If
   End If

End Function

'---------------------------------------------------------------
' Function: getLastSignificantVersions
'
' Purpose: Returns the last significant (man-made) version (PV_ID) that
'          is a predecessor to the specified pv_id
'
' Arguments: pv_id              : Uniquely identifies this package version
'            RefRippleBase      : Ref to store riple base PVID
'            RefPrevNonRipple   : Ref to store previous non ripple PVID
' Notes:
'
Sub getLastSignificantVersions (pv_id, ByRef RefRippleBase, ByRef RefPrevNonRipple)
    Dim rv
        rv = getLastNonRippleVersionPVID( pv_id , RefRippleBase, RefPrevNonRipple)
End Sub

'---------------------------------------------------------------
' Function: get_Pkg_Label
'
' Purpose: Returns the package label for the specified pv_id
'
' Arguments: pv_id       : Uniquely identifies this package version
'
Function get_Pkg_Label (pv_id)
   Dim queryResult
   Dim queryString

   get_Pkg_Label = ""

   ' Get the package label from the package versions table
   queryString = "SELECT pkg_label FROM package_versions WHERE pv_id = " & pv_id
   Set queryResult = OraDatabase.DbCreateDynaset( queryString, cint(0))
   If ((NOT queryResult.BOF) AND (NOT queryResult.EOF)) Then
      get_Pkg_Label = queryResult("pkg_label")
   End If
   queryResult.Close()
   Set queryResult = nothing
End Function
'---------------------------------------------------------------
' Function: get_Src_Path
'
' Purpose: Returns the source path for the specified pv_id
'
' Arguments: pv_id       : Uniquely identifies this package version
'
Function get_Src_Path (pv_id)
   Dim queryResult
   Dim queryString

   get_Src_Path = ""

   ' Get the source path from package versions table
   queryString = "SELECT src_path FROM package_versions WHERE pv_id = " & pv_id
   Set queryResult = OraDatabase.DbCreateDynaset( queryString, cint(0))
   If ((NOT queryResult.BOF) AND (NOT queryResult.EOF)) Then
      get_Src_Path = queryResult("src_path")
   End If
   queryResult.Close()
   Set queryResult = nothing
End Function

'---------------------------------------------------------------
' Function: getOldLabel
'
' Purpose: Returns the previous label; if none then returns empty string
'
'          Since this operation is designed to fulfil the generation of
'          diff commands, there is no point in considering ripple
'          versions, since the only differences we find there are in
'          the build.pl files (for example). So, this function uses
'          some underlying methods that ignore ripple built versions
'          therefore concentrating on versions that someone has manually
'          gone and labelled, presumably because they changed some
'          source file other than build.pl.
'
' Arguments: pv_id       : Uniquely identifies this package version
'            last_pv_id  : Uniquely identifies the predecssor of this package version
' Notes:
'
Function getOldLabel (pv_id, last_pv_id)
   Dim lastSignificantPVID

   getOldLabel = ""

   lastSignificantPVID = getLastSignificantPVID(pv_id, last_pv_id)
   If (lastSignificantPVID <> "") Then
      getOldLabel = get_Pkg_Label(lastSignificantPVID)
   End If
End Function
'---------------------------------------------------------------
' Function: getOldSrcPath
'
' Purpose: Returns the previous src path; if none then returns empty string
'
'          Since this operation is designed to fulfil the generation of
'          diff commands, there is no point in considering ripple
'          versions, since the only differences we find there are in
'          the build.pl files (for example). So, this function uses
'          some underlying methods that ignore ripple built versions
'          therefore concentrating on versions that someone has manually
'          gone and labelled, presumably because they changed some
'          source file other than build.pl.
'
'          NOTE: With SubVersion, the src_path column in the package_versions
'                table will be used to hold the Subversion tag. This function
'                will therefore be used mostly when a package version is
'                controlled under subversion.
'
' Arguments: pv_id       : Uniquely identifies this package version
'            last_pv_id  : Uniquely identifies the predecssor of this package version
' Notes:
'
Function getOldSrcPath (pv_id, last_pv_id)
   Dim lastSignificantPVID

   getOldSrcPath = ""

   lastSignificantPVID = getLastSignificantPVID(pv_id, last_pv_id)
   If (lastSignificantPVID <> "") Then
      getOldSrcPath = get_Src_Path(lastSignificantPVID)
   End If
End Function
'----------------------------------------------------------------------------------------------------------------------
Sub vcs_info_from_vcs_tag( nVcs_tag, ByRef objDetails )
   Dim rsTemp, Query_String

   Query_String = " SELECT * FROM vcs_type WHERE tag = '"& nVcs_tag &"'"
   Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))
   If (NOT rsTemp.BOF ) AND (NOT rsTemp.EOF) Then
      objDetails.Item("vcs_type_id") = rsTemp("vcs_type_id")
      objDetails.Item("vcs_name") = rsTemp("name")
      objDetails.Item("vcs_tag") = rsTemp("tag")
   Else
      Call RaiseMsg(enum_MSG_ERROR, "Database does not contain a record of the VCS tag : " & nVcs_tag )
   End If
   rsTemp.Close()
   set rsTemp = nothing
End Sub
'----------------------------------------------------------------------------------------------------------------------
Sub vcs_info_from_vcs_type_id( nVcs_type_id, ByRef objDetails )
   Dim rsTemp, Query_String

   If NOT IsNull(nVcs_type_id) Then
      Query_String = " SELECT * FROM vcs_type WHERE vcs_type_id = "& nVcs_type_id
      Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))
      If (NOT rsTemp.BOF ) AND (NOT rsTemp.EOF) Then
         objDetails.Item("vcs_type_id") = rsTemp("vcs_type_id")
         objDetails.Item("vcs_name") = rsTemp("name")
         objDetails.Item("vcs_tag") = rsTemp("tag")
      Else
         Call RaiseMsg(enum_MSG_ERROR, "Database does not contain a record of the VCS type ID : " & nVcs_type_id )
      End If
      rsTemp.Close()
      set rsTemp = nothing
   Else
      ' default to returning Subversion info, assuming it exists in the data
      Call vcs_info_from_vcs_tag( enum_VCS_SUBVERSION_TAG, objDetails )
   End If
End Sub
'----------------------------------------------------------------------------------------------------------------------
Sub get_vcs_info_for_package( nPkgLabel, nBuildType, nVcsTypeId, nDLocked, ByRef objDetails )
   ' lots of patch versions exist with N/A as their pkg_label and null as vcs_type_id. These are all uncontrolled
   ' packages published directly into dpkg_archive with no controlled source under clearcase, so we want to treat
   ' them as uncontrolled if possible.
   If nDLocked = "Y" AND ((nPkgLabel = "N/A") OR IsNull(nPkgLabel)) AND nBuildType = "M" AND IsNull(nVcsTypeId) Then
      Call vcs_info_from_vcs_tag( enum_VCS_UNCONTROLLED_TAG, objDetails )
   Else
      ' Otherwise, try and decode the VCS from the package's vcs_type_id entry from the package version table
      ' NOTE: A null vcs_type_id entry will default to ClearCase. That is all we have been using up til now so
      ' it should be safe.
      Call vcs_info_from_vcs_type_id( nVcsTypeId, objDetails )
   End If
End Sub
'----------------------------------------------------------------------------------------------------------------------
Sub get_vcs_info_for_pv_id( nPv_id, ByRef objDetails )
   Dim rsTemp, Query_String

   Query_String = _
   " SELECT pv.pkg_label, pv.build_type, pv.vcs_type_id, pv.dlocked "&_
   "   FROM PACKAGE_VERSIONS pv"&_
   "  WHERE pv.pv_id = "& nPv_id

   Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))
   If (NOT rsTemp.BOF ) AND (NOT rsTemp.EOF) Then
      Call get_vcs_info_for_package( rsTemp("pkg_label"), rsTemp("build_type"), rsTemp("vcs_type_id"), rsTemp("dlocked"), objDetails )
   Else
      Call RaiseMsg(enum_MSG_ERROR, "PV_ID (" & nPv_id & ") Not Found")
   End If
   rsTemp.Close()
   set rsTemp = nothing
End Sub
'----------------------------------------------------------------------------------------------------------------------
Function get_vcs_tag( nPv_id )
   Dim tempVcsInfoCollector
   Set tempVcsInfoCollector = CreateObject("Scripting.Dictionary")

   Call get_vcs_info_for_pv_id( nPv_id, tempVcsInfoCollector )
   get_vcs_tag = tempVcsInfoCollector.Item("vcs_tag")

   Set tempVcsInfoCollector = nothing
End Function
'----------------------------------------------------------------------------------------------------------------------
Function isInDoNotRippleTable( NNrtag_id, NNpv_id )
   Dim rsTemp, Query_String

   isInDoNotRippleTable = FALSE

   If NNrtag_id <> "" AND NNpv_id <> "" Then
      Query_String = " SELECT dnr.pv_id FROM DO_NOT_RIPPLE dnr WHERE dnr.RTAG_ID ="& NNrtag_id &" AND dnr.PV_ID ="& NNpv_id

      Set rsTemp = OraDatabase.DbCreateDynaset(Query_String, cint(0))
      If rsTemp.RecordCount <> 0  Then
         isInDoNotRippleTable = TRUE
      End If
      rsTemp.Close()
      set rsTemp = nothing
   End If
End Function
'----------------------------------------------------------------------------------------------------------------------
' Number of active (Not paused, Not Disabled) daemon configured for a given Release 
Function activeDaemonCount ( NNrtag_id )
   Dim rsTemp, Query_String

   activeDaemonCount = 0

   If NNrtag_id <> ""  Then
      Query_String = "SELECT count(*) as Count FROM release_config rc, run_level rl WHERE rc.rtag_id = " & NNrtag_id &  " AND rc.RCON_ID = rl.rcon_id(+) AND NVL(rl.pause, 0 ) = 0"

      Set rsTemp = OraDatabase.DbCreateDynaset(Query_String, cint(0))
      If rsTemp.RecordCount <> 0  Then
         activeDaemonCount = rsTemp("Count")
      End If
      rsTemp.Close()
      set rsTemp = nothing
   End If
End Function
'----------------------------------------------------------------------------------------------------------------------
Function hasFutureBuild( NNrtag_id, NNpv_id )
   Dim rsTemp, Query_String

   hasFutureBuild = FALSE

   If NNrtag_id <> "" AND NNpv_id <> "" Then

      Query_String = " SELECT * FROM DAEMON_INSTRUCTIONS di WHERE di.RTAG_ID ="& NNrtag_id &" AND di.PV_ID ="& NNpv_id & " AND OP_CODE = " & OP_CODE_2_FUTURE_BUILD

      Set rsTemp = OraDatabase.DbCreateDynaset(Query_String, cint(0))
      If rsTemp.RecordCount <> 0  Then
         hasFutureBuild = TRUE
      End If
      rsTemp.Close()
      set rsTemp = nothing
   End If
End Function

'----------------------------------------------------------------------------------------------------------------------
Function isBuilding( NNpv_id )
   Dim rsTemp, Query_String

   isBuilding = FALSE

   If  NNpv_id <> "" Then
      Query_String = _
            "SELECT unique rl.CURRENT_PV_ID" &_
            " FROM RELEASE_CONFIG rc, RELEASE_TAGS rt, RUN_LEVEL rl " &_
            " WHERE rt.RTAG_ID = rc.RTAG_ID " &_
            "   AND rc.bmcon_id is not null" &_
            "   AND rt.OFFICIAL in ( 'N', 'R', 'C')" &_
            "   AND rl.RCON_ID(+) = rc.RCON_ID" &_
            "   AND rl.CURRENT_PKG_ID_BEING_BUILT is not null" &_
            "   AND NVL(rl.PAUSE,0) < 2" &_
            "   AND rl.CURRENT_PV_ID = " & NNpv_id 

      Set rsTemp = OraDatabase.DbCreateDynaset(Query_String, cint(0))
      If rsTemp.RecordCount <> 0  Then
         isBuilding = TRUE
      End If
      rsTemp.Close()
      set rsTemp = nothing
   End If
End Function

'----------------------------------------------------------------------------------------------------------------------
Function pv_id_exists( nPv_id )
   Dim rsTemp, Query_String

   If NOT IsNull( nPv_id ) AND nPv_id <> "" Then
      Query_String = _
      " SELECT pv.pv_id "&_
      "   FROM PACKAGE_VERSIONS pv"&_
      "  WHERE pv.pv_id = "& nPv_id
      Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))
      If (NOT rsTemp.BOF ) AND (NOT rsTemp.EOF) Then
         pv_id_exists = TRUE
      Else
         pv_id_exists = FALSE
      End If
      rsTemp.Close()
      set rsTemp = nothing
   Else
      pv_id_exists = FALSE
   End If
End Function
'----------------------------------------------------------------------------------------------------------------------
Function is_daemon_enabled_release( NNrtag_id, defaultReturnValue )
   Dim rsTemp, Query_String

   If NOT IsNull( NNrtag_id ) AND NNrtag_id <> "" Then

      Query_String = _
      " SELECT rc.bmcon_id "&_
      "   FROM RELEASE_CONFIG rc"&_
      "  WHERE rc.rtag_id = "& NNrtag_id
      Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))

      is_daemon_enabled_release = FALSE
      While ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF) AND (is_daemon_enabled_release = FALSE))
         If (NOT IsNull(rsTemp("bmcon_id"))) AND (rsTemp("bmcon_id") <> "") Then
            is_daemon_enabled_release = TRUE
         End If
         rsTemp.MoveNext
      WEnd

      rsTemp.Close()
      set rsTemp = nothing
   Else
      is_daemon_enabled_release = defaultReturnValue
   End If
End Function
'--------------------------------------------------------------------------------------------------------------------------
' Convert release state into a meaningful string
Function Get_Official( nOfficial )
   If nOfficial = "N" Then
      Get_Official = "Open"
   ElseIf nOfficial = "A" Then
      Get_Official = "Archive"
   ElseIf nOfficial = "C" Then
      Get_Official = "CCB"
   ElseIf nOfficial = "R" Then
      Get_Official = "Restricted"
   ElseIf nOfficial = "Y" Then
      Get_Official = "Closed"
   ElseIf nOfficial = "P" Then
      Get_Official = "Preserved"
   Else
      Get_Official = "?"
   End If
End Function
'-----------------------------------------------------------------------------------------------------------------------------
Function Get_Pkg_Id_For_Pv_Id ( NNpv_id )
   Dim rsTemp, Query_String

   Get_Pkg_Id_For_Pv_Id = ""

   If NOT IsNull(NNpv_id) AND NNpv_id <> "" Then
      Query_String = _
      "SELECT pkg_id FROM package_versions WHERE pv_id = "& NNpv_id

      Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))

      If ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF)) Then
         Get_Pkg_Id_For_Pv_Id = rsTemp("pkg_id")
      End If
      rsTemp.Close
      Set rsTemp = nothing
   End If

End Function

'-----------------------------------------------------------------------------------------------------------------------------
Function iif(bFlag, sTrueStr, sFalseStr)
  if bFlag then
    iif = sTrueStr
  else 
    iif = sFalseStr
  end if
End Function

'-----------------------------------------------------------------------------------------------------------------------------
Function EmptyToNull (sVal)
    If isNull(sVal) Then
        EmptyToNull = NULL
    ElseIf sval <> "" Then
        EmptyToNull = sVal
    Else
        EmptyToNull = NULL
    End If
End Function

'-----------------------------------------------------------------------------------------------------------------------------
Function EmptyToNullString ( sName, sVal)
    If isNull(sVal) Then
        EmptyToNullString = sName & " is NULL"
    ElseIf sval <> "" Then
        EmptyToNullString = sName & "='" & sVal & "'"
    Else
        EmptyToNullString = sName & " is NULL"
    End If
End Function

'--------------------------------------------------------------------------------------------------------------------------
' Sets the state of all build daemons of the specified release
Sub SetDaemonStates (artag_id,astate)
	On Error Resume Next
	OraDatabase.Parameters.Add "RTAG_ID", 			artag_id, 	ORAPARM_INPUT, ORATYPE_NUMBER 
	OraDatabase.Parameters.Add "NSTATE", 			astate, 	ORAPARM_INPUT, ORATYPE_NUMBER 
		
	objEH.TryORA ( OraSession )
	
	OraDatabase.ExecuteSQL _
        "BEGIN PK_BUILDAPI.SET_DAEMON_STATES(:RTAG_ID,:NSTATE);   END;"
		
	objEH.CatchORA ( OraSession )

	OraDatabase.Parameters.Remove "RTAG_ID"
	OraDatabase.Parameters.Remove "NSTATE"	
End Sub

'----------------------------------------------
'Returns true if the specified package version exists in the specified table
Function PackageExists(RtagId, pvId, stable)
  Dim rsTemp
  Dim sqry
  If RtagId = "" Then
    PackageExists = False
  Else
    sqry = "SELECT * FROM " & stable & " WHERE rtag_id = " & RtagId & " AND pv_id = " & pvId
    Set rsTemp = OraDatabase.DbCreateDynaset(sqry,CInt(0))
    PackageExists = rsTemp.RecordCount > 0  
    rsTemp.Close()
    Set rsTemp = Nothing
  End If
End Function

'----------------------------------------------
' Test that specified package/version exists in dpkg_archive
' Can also test presence of the archive
'   Use http interface as it does not require authetication
Function testArchiveAccessPkg(pkgName, pkgVersion)
  Dim oXMLHTTP
  Dim testUrl

  testArchiveAccessPkg = False
  testUrl = HTTP_PKG_ARCHIVE

  testUrl = testUrl & "/cgi-bin/testPackage.pl"
  If pkgName <> "" Then
      testUrl = testUrl & "?path=" &  pkgName & "/" & pkgVersion
  End If
  Set oXMLHTTP = CreateObject("MSXML2.ServerXMLHTTP.3.0")

  ' Use error handling in case dpkg_archive is not available
  ' Use HEAD to test existence
  Err.Clear
  On Error Resume Next
  oXMLHTTP.Open "GET", testUrl, False
  oXMLHTTP.Send

  ' Do not combine the next two If statments - it will not work
  If Err.Number = 0  Then
    If oXMLHTTP.Status = 200 Then 
        If InStr(1,oXMLHTTP.responseText, "::FOUND::", 1) = 1 Then
            testArchiveAccessPkg = True
        End If
    End If
  End If

  On Error Goto 0
End Function

'--------------------------------------------------------------------------------------------------------------------------
' Like Cint, but handles NULL by replacing it with a default value
Function NiceInt( val, def)
   If val <> ""  AND IsNumeric(val) Then
       NiceInt = CInt(val)
   Else
       NiceInt = def
   End If
End Function

'--------------------------------------------------------------------------------------------------------------------------
' Like CLng, but handles NULL by replacing it with a default value
Function NiceCLng( val, def)
   If val <> ""  AND IsNumeric(val) Then
       NiceCLng = CLng(val)
   Else
       NiceCLng = def
   End If
End Function

'--------------------------------------------------------------------------------------------------------------------------
' Like CStr, but handles NULL by replacing it with a default value
Function NiceCStr( val, def)
   If IsNull(val) Then
       NiceCStr = def
   ElseIf IsEmpty(val) Then
       NiceCStr = def
   Else
       NiceCStr = CStr(val)
   End If
End Function

'--------------------------------------------------------------------------------------------------------------------------
' Convert a duration(seconds) into days,hours and seconds. eg 10d 3h 13m 15s
Function NiceDuration(nDuration)
    NiceDuration = ""
    Dim joiner : joiner = ""
    Dim unit
    Dim duration : duration = nDuration
    If duration > (60 * 60 * 24) Then
        unit = Int(duration / (60 * 60 * 24))
        duration = duration MOD (60 * 60 * 24) 
        NiceDuration = NiceDuration & joiner & unit & "d"
        joiner = " "
    End If

    If duration > (60 * 60) Then
        unit = Int(duration / (60 * 60))
        duration = duration MOD (60 * 60) 
        NiceDuration = NiceDuration & joiner & unit & "h"
        joiner = " "
    End If

        If duration > (60) Then
        unit = Int(duration / (60))
        duration = duration MOD (60) 
        NiceDuration = NiceDuration & joiner & unit & "m"
        joiner = " "
    End If

    NiceDuration = NiceDuration & joiner & duration & "s"
End Function

'--------------------------------------------------------------------------------------------------------------------------
' Quick and ugly code to attempt to remove nasty characters from strings
' In particular some unicode characters that mess with the json decoder
Function CleanUpJson (input)
      Dim objRegExp, outputStr
      Set objRegExp = New Regexp

      objRegExp.IgnoreCase = True
      objRegExp.Global = True
      objRegExp.Pattern = "((?![\[\]\(\)\{\}\$-_?/""';:.,a-zA-Z0-9]).)+"
      outputStr = objRegExp.Replace(input, " ")

      CleanUpJson = outputStr
    End Function

'--------------------------------------------------------------------------------------------------------------------------
'   Test if package can be added to a release
'       Really tests if a a package of this packages alias can be
'       manipulated in this release
'   True: Package alias can be added/replaced in release
Function canAddToRelease ( nRtagId, nPvId )

    ' If we don't enough parameters then assume we can add package
    If nRtagId = "" OR nPvId = "" Then
        canAddToRelease = TRUE
        Exit Function
    End If

	On Error Resume Next
	OraDatabase.Parameters.Add "RTAG_ID", 			nRtagId, 	ORAPARM_INPUT, ORATYPE_NUMBER 
	OraDatabase.Parameters.Add "PV_ID", 			nPvId, 	    ORAPARM_INPUT, ORATYPE_NUMBER 
	OraDatabase.Parameters.Add "RETURN_CODE", 		null, 	    ORAPARM_OUTPUT, ORATYPE_NUMBER 
		
	objEH.TryORA ( OraSession )
	
	OraDatabase.ExecuteSQL _
        "BEGIN :RETURN_CODE := PK_RELEASE.CAN_ADD_PKG_TO_RELEASE(:RTAG_ID,:PV_ID);   END;"

    If CInt(OraDatabase.Parameters("RETURN_CODE").Value) = 0 Then
        canAddToRelease = FALSE
    Else
        canAddToRelease = TRUE
    End If
		
	objEH.CatchORA ( OraSession )

	OraDatabase.Parameters.Remove "RETURN_CODE"
	OraDatabase.Parameters.Remove "RTAG_ID"
	OraDatabase.Parameters.Remove "PV_ID"	
End Function
'--------------------------------------------------------------------------------------------------------------------------
'   Returns either the value of the Request('tag') or the default value       
Function RequestDefault(stag, sdefault)
   If Request(stag) <> "" Then
       RequestDefault = Request(stag)
   Else 
       RequestDefault = sdefault
   End If
End Function
'--------------------------------------------------------------------------------------------------------------------------
'   Returns either the value of the Request('tag') or the default value       
Function RequestBool(stag, sdefault)
    Dim val
    If Request(stag) <> "" Then
        RequestBool = FALSE
        val = UCase( Request(stag))
        If val = "Y" or val = "TRUE" Then
            RequestBool = TRUE
        ElseIf IsNumeric(val) Then
            If val > 0 Then
                RequestBool = TRUE
            End If
        End If
   Else 
       RequestBool = sdefault
   End If
End Function

'--------------------------------------------------------------------------------------------------------------------------
'   Data structure to assist in the Release Mode Transition Check
'   Tuples (FromCondition, ToCondition)  '-' == Always
'   Order matches ReleaseModeAccessCheck
'
Dim RMTD_Data
RMTD_Data = Array(Array("-"                        ,"-"), _
                  Array("ChangeModeFromRestrictive","-"), _
                  Array("ChangeModeFromRestrictive","-"), _
                  Array("ChangeModeFromClosed"     ,"ChangeModeToClosed"), _
                  Array("ChangeModeFromClosed"     ,"ChangeModeToPreserved"), _
                  Array("ChangeModeFromArchived"   ,"ChangeModeToArchived") _
                  )
'-------------------------------------------------
' Function: ReleaseMode2Index    
' Description: Convert a enumDB_RELEASE_IN_*** into an index into the above array
'
Function ReleaseMode2Index( eReleaseMode )
    If eReleaseMode = enumDB_RELEASE_IN_OPEN_MODE Then
        ReleaseMode2Index = 0
    ElseIf eReleaseMode = enumDB_RELEASE_IN_RESTRICTIVE_MODE Then
        ReleaseMode2Index = 1
    ElseIf eReleaseMode = enumDB_RELEASE_IN_CCB_MODE Then
        ReleaseMode2Index = 2
    ElseIf eReleaseMode = enumDB_RELEASE_IN_CLOSED_MODE Then
        ReleaseMode2Index = 3
    ElseIf eReleaseMode = enumDB_RELEASE_IN_PRESERVE_MODE Then
        ReleaseMode2Index = 4
    ElseIf eReleaseMode = enumDB_RELEASE_IN_ARCHIVE_MODE Then
        ReleaseMode2Index = 5
    Else
        ReleaseMode2Index = -1
    End If
End Function

'-------------------------------------------------
' Function:     ReleaseModeAccessCheck    
' Description:  Determine if the user can change the Release Mode
'               from - Start at this Release Mode
'               to   - Can the user transition to this mode
' Returns:      True - yes they can
'
Function ReleaseModeAccessCheck( from, toMode )
    Dim fromIndex : fromIndex = ReleaseMode2Index(from)
    Dim toIndex   : toIndex = ReleaseMode2Index(toMode)
    ReleaseModeAccessCheck = False

    ' Can't Change to same mode
    If from = toMode Then
        Exit Function
    End If

    On Error Resume Next
    Dim fromAccess : fromAccess = ""
    Dim toAccess   : toAccess = ""

    ' Get access type from table
    '   ""      - No access (internal error)
    '   "-"     - All Access allowed (if user is logged in )
    '   Else    - Name of a canActionControlInProject
    fromAccess = RMTD_Data(fromIndex)(0)
    toAccess = RMTD_Data(toIndex)(1)

    ' Check From Condition
    If fromAccess = "-" Then
        ReleaseModeAccessCheck = canActionInProject()
    ElseIf fromAccess <> "" Then
        ReleaseModeAccessCheck = canActionControlInProject(fromAccess)
    End If

    If NOT ReleaseModeAccessCheck  Then
        Exit Function
    End If

    ' Check to Condition
    If toAccess = "-" Then
        ReleaseModeAccessCheck = canActionInProject()
    ElseIf toAccess <> "" Then 
        ReleaseModeAccessCheck = canActionControlInProject(toAccess)
    End If

End Function

'-------------------------------------------------
' Function:    releaseIsClosed
' Description: Determine if a release can be modified at all
' Returns:     True: Release cannot be modified
'                    ie: it is NOT in a state that allows modification
'
Function releaseIsClosed(eReleaseMode)
    If eReleaseMode = enumDB_RELEASE_IN_OPEN_MODE Then
        releaseIsClosed = False
    ElseIf eReleaseMode = enumDB_RELEASE_IN_RESTRICTIVE_MODE Then
        releaseIsClosed = False
    ElseIf eReleaseMode = enumDB_RELEASE_IN_CCB_MODE Then
        releaseIsClosed = False
    ElseIf eReleaseMode = enumDB_RELEASE_IN_CLOSED_MODE Then
        releaseIsClosed = True
    ElseIf eReleaseMode = enumDB_RELEASE_IN_PRESERVE_MODE Then
        releaseIsClosed = True
    ElseIf eReleaseMode = enumDB_RELEASE_IN_ARCHIVE_MODE Then
        releaseIsClosed = True
    Else
        releaseIsClosed = True
    End If
End Function

'-------------------------------------------------
' Function:    releaseIsWritable
' Description: Determine if a release can be modified
' Returns:     True: Release can be modified
'                    ie: it is in a state that allows modification
'
Function releaseIsWritable(eReleaseMode)
    If eReleaseMode = enumDB_RELEASE_IN_OPEN_MODE AND canActionInProject() Then
        releaseIsWritable = True
    ElseIf eReleaseMode = enumDB_RELEASE_IN_RESTRICTIVE_MODE AND canActionControlInProject("AlterReleaseContentsInRestrictiveMode") Then
        releaseIsWritable = True
    ElseIf eReleaseMode = enumDB_RELEASE_IN_CCB_MODE AND canActionControlInProject("AlterReleaseContentsInRestrictiveMode")Then
        releaseIsWritable = True
    ElseIf eReleaseMode = enumDB_RELEASE_IN_CLOSED_MODE Then
        releaseIsWritable = False
    ElseIf eReleaseMode = enumDB_RELEASE_IN_PRESERVE_MODE Then
        releaseIsWritable = False
    ElseIf eReleaseMode = enumDB_RELEASE_IN_ARCHIVE_MODE Then
        releaseIsWritable = False
    Else
        releaseIsWritable = False
    End If
End Function

'-------------------------------------------------
' Function:    releaseIsMergable
' Description: Determine if the user can 'Merge' into the release
' Returns:     True: Release can be modified
'                    ie: it is in a state that allows modification
'
Function releaseIsMergable(eReleaseMode)
    If eReleaseMode = enumDB_RELEASE_IN_OPEN_MODE AND canActionInProject() Then
        releaseIsMergable = True
    ElseIf eReleaseMode = enumDB_RELEASE_IN_RESTRICTIVE_MODE AND canActionControlInProject("MergeRelease")  Then
        releaseIsMergable = True
    ElseIf eReleaseMode = enumDB_RELEASE_IN_CCB_MODE AND canActionControlInProject("MergeReleaseForCCB") Then
        releaseIsMergable = True
    Else
        releaseIsMergable = False
    End If
End Function
'-------------------------------------------------
' Function:         RenderLxrStateString   
' Description:      Return a string to show the current LXR state
Function RenderLxrStateString(rtagid, lxr, lxrState, official, txt)
    If lxr = "N" AND lxrState = "N" Then
        RenderLxrStateString = ""
    Else
        Dim lxrUrl : lxrUrl = LXR_URL & "/" & rtagid
        Dim image, hover, isClosed

        If lxrState = "N" Then
            If releaseIsClosed(official) Then lxrState = "A"
        End If

        Select Case lxrState
            Case "I"
                image = "LXRlogo64.jpeg"
                hover = "LXR Index available"
            Case "C"
                image = "LXRlogo64_off.jpeg"
                hover = "LXR Index available, but no longer updated"
            Case "N"
                image = "LXRlogo64_progress.jpeg"
                hover = "LXR Requested, but not yet available"
            Case "A"
                image = "LXRlogo64_off.jpeg"
                hover = "LXR no longer available. Release is no longer open"
            Case Else
                image = "LXRlogo64_progress.jpeg"
                hover = "LXR Requested, unknown State:(" & lxrState &")"
        End Select
        RenderLxrStateString = "" & txt &""
    End If
End Function
 
'-------------------------------------------------
' Function:         RenderS3ManifestStateString   
' Description:      Return a string to show the current S3 Manifest Processing state
Function RenderS3ManifestStateString(rtagid, s3Manifest, official, txt)
    If s3Manifest = "N" Then
        RenderS3ManifestStateString = ""
    Else
        Dim image, hover, iClass, iStyle
        iClass = ""
        iStyle = ""
        If releaseIsClosed(official) Then s3Manifest = "A"

        Select Case s3Manifest
            Case "Y"
                image = "AmazonS3.png"
                hover = "Manifest Generation to S3 Active"
            Case "N"
                image = "AmazonS3.png"
                hover = "Manifest Generation to S3 Active not enabled"
            Case "A"
                image = "AmazonS3.png"
                hover = "Manifest Generation to S3 Active not active. Release is no longer open"
                iClass = "class=lessOpacity"
            Case Else
                image = "AmazonS3.png"
                hover = "Manifest Generation unknown State:(" & s3Manifest &")"
                iStyle = " filter: grayscale(1);"
        End Select
        RenderS3ManifestStateString = "" & txt & ""
    End If
End Function 
 

'-------------------------------------------------
' Function:         rippleFieldName   
' Description:      Return a string to convert a ripple field state to a text name
'                   bFlag is set to false if the state is unknown.
Dim rippleFieldValues
rippleFieldValues = Array ("M", "m", "p", "b", "L")
Function rippleFieldName ( rstate, ByRef bFlag )
    If isNULL(rstate) Then
        rstate = "b"
    End If

    bFlag = TRUE
    Select Case rstate
            Case "M" 
                rippleFieldName = "Major Number"
            Case "m" 
                rippleFieldName = "Minor Number"
            Case "p" 
                rippleFieldName = "Patch Number"
            Case "b" 
                rippleFieldName = "Build Number"
            Case "L" 
                rippleFieldName = "Limited"
            Case Else 
                rippleFieldName = "Invalid State"
                bFlag = FALSE
        End Select
End Function
'----------------------------------------------------
' Function: emailField
' Description: Generate a 'span' with email information
' The mailto class is picked up the jquery for processing
Function emailField(sName, sEmail)
    emailField = "" & sName & ""
End Function
Function emailField3(sName, sEmail,sUname)
    emailField3 = "" & sName & ""
End Function

'-----------------------------------------------------------------------------------------------------------------------------

Function ReleaseIcon ( cOfficial )
	
	If cOfficial = "N" Then
		' Open Mode
		ReleaseIcon = LIMG_OPEN_MODE
		
	ElseIf cOfficial = "R" Then
		' Restrictive Mode
		ReleaseIcon = LIMG_RESTRICTIVE_MODE
	
	ElseIf cOfficial = "C" Then
		'CCB Mode
		ReleaseIcon = LIMG_CCB_MODE
		
	ElseIf cOfficial = "Y" Then
		'Closed Mode
		ReleaseIcon = LIMG_CLOSED_MODE

	ElseIf cOfficial = "O" Then
		'Closed Mode - With warning (aged)
		ReleaseIcon = LIMG_CLOSED_MODE_WARN
		
	ElseIf cOfficial = "P" Then
		'Closed Mode - Archived, but don't purge
		ReleaseIcon = LIMG_PRESERVE_MODE

	ElseIf cOfficial = "A" Then
		'Archive Mode
		ReleaseIcon = LIMG_ARCHIVE_MODE	

	ElseIf cOfficial = "S" Then
		'Snapshot Mode
		ReleaseIcon = LIMG_SNAPSHOT_MODE	

	End If
	
End Function
'-----------------------------------------------------------------------------------------------------------------
Function SdkIcon (cState)
    If cState = "R" Then
        ' Released - available for use
        SdkIcon = LIMG_CLOSED_MODE
    ElseIf cState = "D" Then
        ' Deprecated - Cannot be added to a Release any more
        SdkIcon = LIMG_ARCHIVE_MODE
    ElseIf cState = "U" Then
        ' Work in progress - Still being constructed. Cannot be added to a Release yet
        SdkIcon = LIMG_OPEN_MODE
    End If
End Function
'-----------------------------------------------------------------------------------------------------------------
'
'   Helper rountien to create a button that will be wired into JavaScript
'
Sub BuildJsButton (bState, sClass, sTitle, sImage)%>
    <%If bState Then%>
		>
    <%Else%>
		 class="lessOpacity">
    <%End If%>
<%End Sub
'------------------------------------------------------------------------------
'   Helper routine to create buttons and disabled buttons
'   Treat the action an href - link the user can see and potentially open in another tab
'
Sub BuildActionButtonLink(bState, sText, sTitle, sImage, sRef)
 %>

    <%If bState Then%>
     ><%=sText%>
    <%Else%>
     class="lessOpacity"><%=sText%>
    <%End If%>

<%End Sub
'------------------------------------------------------------------------------
'   Helper routine to create buttons and disabled buttons
'   Treat the ref as a page to goto, but don't use href
'
Sub BuildActionButton(bState, sText, sTitle, sImage, sRef)
 %>

    <%If bState Then%>
     ><%=sText%>
    <%Else%>
     class="lessOpacity"><%=sText%>
    <%End If%>

<%End Sub
'------------------------------------------------------------------------------
'   Helper routine to create buttons and disabled buttons
'   Tack a onClick operation
'
Sub BuildActionButtonClickRaw(bState, sText, sTitle, isBlue, sImage, sClick)
    Dim sStyle : sStyle = ""
    If Left(sImage,4) = "
     ><%=sText%>
    <%Else%>
    <%If isBlue Then sStyle = "color:#0000ee66; text-decoration:none"%>
     class="lessOpacity"><%=sText%>
    <%End If
End Sub

Sub BuildActionButtonClick(bState, sText, sTitle, isBlue, sImage, sClick)%>

    <%BuildActionButtonClickRaw bState, sText, sTitle, isBlue, sImage, sClick %>

<%End Sub

'------------------------------------------------------------------------------
'   Helper routine to create Text with a button that follows
'   Tack a onClick operation
'
Sub BuildEditButtonRaw(bState, sText, sTitle, isBlue, sImage, sClick)
    Dim sStyle : sStyle = "font-weight:bold;"
    Dim sClass : sClass = ""
    If Left(sImage,4) = "
    <%=sText%> >
    <%Else%>
    <%If isBlue Then sClass = "txt_linked_dis" : sStyle = ""%>
    <%=sText%>  class="lessOpacity">
    <%End If
End Sub%>