<%@LANGUAGE="VBSCRIPT"%>
<%
Option explicit
Response.Expires = 0   ' always load the page, dont store
%>
<%
'=====================================================
'               Import Docs
'=====================================================
%>
<!--#include file="common/conf.asp"-->
<!--#include file="common/globals.asp"-->
<!--#include file="common/qstr.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/common_dbedit.asp"-->
<!--#include file="common/formating.asp"-->
<!--#include file="common/_popup_window_common.asp"-->
<%
'------------ ACCESS CONTROL ------------------
%>
<!--#include file="_access_control_login.asp"-->
<!--#include file="_access_control_general.asp"-->
<!--#include file="_access_control_project.asp"-->
<%
'------------ Variable Definition -------------
Dim parPv_id
Dim parDRdoc_title
Dim parDRdoc_id
Dim retVal
Dim rsDocReg
Dim parEdit
Dim cIsLatest
Dim parVersion_id
Dim parDoc_Num
'------------ Constants Declaration -----------
'------------ Variable Init -------------------
parPv_id = QStrPar("pv_id")
parRtag_id = QStrPar("rtag_id")
parEdit = Request("edit")
parVersion_id = Request("version_id")
parDoc_Num = Request("doc_num")
'-- CONDITIONS --------------------------------
'----------------------------------------------
%>
<%
'-------------------------------------------------------------------------------------------------------------------------------
Sub Import_Document ( nPv_id, nDRdoc_id )
   Dim doc_id, is_latest, sDocVersion

   is_latest = "'Y'"
   doc_id = nDRdoc_id
   sDocVersion = "Always Latest"

   If Request("version_id") <> "" Then
      Call Short_Document_Details ( Request("version_id"), NULL, sDocVersion, NULL  )
      doc_id = Request("version_id")
      is_latest = "NULL"

   End If

   objEH.TryORA ( OraSession )
   On Error Resume Next

   OraDatabase.ExecuteSQL _
      " DELETE FROM PACKAGE_DOCUMENTS "&_
      " WHERE pv_id = "& nPv_id&_
      "   AND doc_num = '"& SQLstring ( Request("doc_num") ) &"'"

   If Err.Number = 0 Then
      OraDatabase.ExecuteSQL _
         " INSERT INTO package_documents ( pv_id, doc_id, doc_num, is_latest  )"&_
         " VALUES ( "& nPv_id &", "& doc_id &", '"& SQLstring ( Request("doc_num") ) &"', "& is_latest &" )"
   End If

   objEH.CatchORA ( OraSession )

   If objEH.LastOraFailed = FALSE Then
      '/* Log Action */
      Call Log_Action ( nPv_id, "document_add", "Document number: "& Request("doc_num") &", Version: "& sDocVersion )
   End If

End Sub
'-------------------------------------------------------------------------------------------------------------------------------
Sub UpdatePackageDocument ( nPvId, nDocId, nVersionId )

   Dim cIsLatest, sDocVersion

   cIsLatest = "Y"
   sDocVersion = "Always Latest"

   If ( nVersionId <> "" ) Then
      Call Short_Document_Details ( nVersionId, NULL, sDocVersion, NULL  )
      cIsLatest = NULL
   Else
      nVersionId = nDocId
   End If

   OraDatabase.Parameters.Add "PV_ID", nPvId,    ORAPARM_INPUT, ORATYPE_NUMBER
   OraDatabase.Parameters.Add "DOC_ID", nVersionId,    ORAPARM_INPUT, ORATYPE_NUMBER
   OraDatabase.Parameters.Add "DOC_NUM", parDoc_Num,    ORAPARM_INPUT, ORATYPE_VARCHAR2
   OraDatabase.Parameters.Add "IS_LATEST", cIsLatest,    ORAPARM_INPUT, ORATYPE_VARCHAR2

   objEH.TryORA ( OraSession )
   On Error Resume Next

   OraDatabase.ExecuteSQL _
      " UPDATE PACKAGE_DOCUMENTS pd SET "&_
      "    pd.doc_id = :DOC_ID, "&_
      "    pd.doc_num = :DOC_NUM, "&_
      "    pd.IS_LATEST = :IS_LATEST"&_
      " WHERE pd.PV_ID = :PV_ID "&_
      "   AND UPPER( pd.DOC_NUM ) = UPPER( :DOC_NUM ) "

   objEH.CatchORA ( OraSession )

   OraDatabase.Parameters.Remove "PV_ID"
   OraDatabase.Parameters.Remove "DOC_ID"
   OraDatabase.Parameters.Remove "DOC_NUM"
   OraDatabase.Parameters.Remove "IS_LATEST"

   If objEH.LastOraFailed = FALSE Then
      '/* Log Action */
      Call Log_Action ( nPvId, "document_update", "Document number: "& Request("doc_num") &", Version: "& sDocVersion )
   End If

End Sub
'-------------------------------------------------------------------------------------------------------------------------------
Sub GetPackageDocument ( nPvId, nDocId, outcIsLatest )
   Dim query, rsTemp

   OraDatabase.Parameters.Add "PV_ID", nPvId,    ORAPARM_INPUT, ORATYPE_NUMBER
   OraDatabase.Parameters.Add "DOC_ID", nDocId,    ORAPARM_INPUT, ORATYPE_NUMBER

   query = _
   " SELECT pd.*"&_
   "  FROM PACKAGE_DOCUMENTS pd"&_
   " WHERE pd.PV_ID = :PV_ID"&_
   "   AND pd.DOC_ID = :DOC_ID"

   Set rsTemp = OraDatabase.DbCreateDynaset( query, cint(0))

   If rsTemp.RecordCount > 0 Then
      outcIsLatest = "N"
      If rsTemp("is_latest") = "Y" Then
         outcIsLatest = "Y"
      End If
   End If

   rsTemp.Close()
   Set rsTemp = nothing

   OraDatabase.Parameters.Remove "PV_ID"
   OraDatabase.Parameters.Remove "DOC_ID"

End Sub
'-------------------------------------------------------------------------------------------------------------------------------
%>
<%
'Process submition
If CBool(Request("action"))  AND  objAccessControl.UserLogedIn  Then


   If (parEdit = "true") Then
      Call GetPackageDocument ( parPv_id, parVersion_id, cIsLatest )
   End If


   retVal = Lookup_Document ( Request("doc_num"), parDRdoc_title, parDRdoc_id, Empty, Empty  )

   If Request("btn") = "Import" Then
      Call Import_Document ( parPv_id, parDRdoc_id )
      Call OpenInParentWindow ("documentation.asp?pv_id="& parPv_id &"&rtag_id="& parRtag_id)
      Call CloseWindow()

   ElseIf Request("btn") = "Update" Then
      Call UpdatePackageDocument ( parPv_id, parDRdoc_id, parVersion_id )
      Call OpenInParentWindow ("documentation.asp?pv_id="& parPv_id &"&rtag_id="& parRtag_id)
      Call CloseWindow()

   End If


End If

%>
<html>
<head>
<title>Release Manager</title>
<link rel="shortcut icon" href="<%=FavIcon%>"/>
<meta HTTP-EQUIV="Pragma" CONTENT="no-cache">
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
<link rel="stylesheet" href="images/release_manager_style.css?ver=<%=VixVerNum%>" type="text/css">
<link rel="stylesheet" href="images/navigation.css?ver=<%=VixVerNum%>" type="text/css">
<script language="JavaScript" src="images/common.js?ver=<%=VixVerNum%>"></script>
</head>
<body bgcolor="#FFFFFF" text="#000000" leftmargin="0" topmargin="0" onload="self.focus();FormName.doc_num.focus();">
   <table border="0" cellspacing="0" cellpadding="2">
   <form class="form_tight" name="FormName" method="get" action="<%=scriptName%>">
      <tr>
         <td valign="top" nowrap colspan="3" class="wform_ttl" background="images/bg_form_lightgray.gif">
            <table width="100%" border="0" cellspacing="1" cellpadding="2">
               <tr>
                  <td nowrap background="images/bg_form_lightbluedark.gif" class="form_field">Document Number </td>
                  <td nowrap background="images/bg_form_lightbluedark.gif" class="form_txt">
                     <input name="doc_num" type="text" class="form_item" value="<%=Request("doc_num")%>" size="20" maxlength="50" <%If parEdit <> "" Then%>readonly<%End If%>>
                     <input tabindex="1" name="btn" type="submit" class="form_btn_comp" value="Lookup" <%If parEdit <> "" Then%>disabled<%End If%>>
                  </td>
               </tr>
               <%If parDRdoc_title <> "" Then%>
                  <tr>
                     <td nowrap background="images/bg_form_lightbluedark.gif" class="form_field">Document Title</td>
                     <td nowrap background="images/bg_form_lightbluedark.gif" class="form_txt"><a href="<%=DocRepositiryLink%><%=Request("doc_num")%>" class="txt_linked" target="_blank"><%=parDRdoc_title%></a></td>
                  </tr>
                  <tr>
                     <td nowrap background="images/bg_form_lightbluedark.gif" class="form_field">Version</td>
                     <td nowrap background="images/bg_form_lightbluedark.gif" class="form_txt">
                        <%
                        Set rsDocReg = Server.CreateObject("ADODB.Recordset")
                        rsDocReg.ActiveConnection = DOCREP_conn

                        rsDocReg.Source = "EXEC docregister.dbo.sp_RM_getDocumentFiles '"& Request("doc_num") &"';"
                        rsDocReg.CursorType = 0
                        rsDocReg.CursorLocation = 2
                        rsDocReg.LockType = 3
                        rsDocReg.Open()

                        %>
                        <select name="version_id" class="form_txt">
                           <option value="">Always Latest</option>
                           <%While (NOT rsDocReg.BOF) AND (NOT rsDocReg.EOF)%>
                           <option value="<%=rsDocReg("id")%>" <%If ( parVersion_id = CStr(rsDocReg("id"))  AND  ( cIsLatest <> "Y" ) ) Then%>selected<%End If%>><%=FormatVersion(rsDocReg("version"))%></option>
                           <%rsDocReg.MoveNext()
                           WEnd
                           %>
                        </select>

                        <%
                        rsDocReg.Close
                        Set rsDocReg = Nothing
                        %>
                     </td>
                  </tr>
               <%End If%>
               <tr>
                  <td width="1%" nowrap class="form_field"><img src="images/h_trsp_dot.gif" width="100" height="10"></td>
                  <td nowrap width="100%">
                     <%
                     If retVal <> 0 Then
                           Response.write enumMSSQL_ERROR
                     Else
                        If (parEdit = "") Then
                           If (Request("doc_num") <> "") AND  IsNull(parDRdoc_id) Then
                              Call DisplayInfo ( "DOC_NUMBER_NOTFOUND", 350 )

                           ElseIf (Request("doc_num") <> "") AND  NOT IsNull(parDRdoc_id) Then
                              Call DisplayInfo ( "DOC_NUMBER_FOUND", 350 )

                           End If
                        End If
                     End If
                     %>
                  </td>
               </tr>
               <input name="pv_id" type="hidden" value="<%=parPv_id%>">
               <input name="rtag_id" type="hidden" value="<%=parRtag_id%>">
               <input name="edit" type="hidden" value="<%=parEdit%>">
               <input name="lookup" type="hidden" value="true">
               <input name="action" type="hidden" value="true">
            </table>
         </td>
      </tr>
      <tr>
         <td align="right" width="50%">
            <%If parEdit = "" Then%>
               <input tabindex="10" type="submit" name="btn" value="Import" class="form_btn_comp" <%If (parDRdoc_id = "") OR IsNull(parDRdoc_id) Then%>disabled<%End If%>>
            <%Else%>
               <input tabindex="10" type="submit" name="btn" value="Update" class="form_btn_comp">
            <%End If%>
            <input type="reset" name="btn" value="Close" class="form_btn_comp" onclick="parent.closeIFrame();">
         </td>
      </tr>
     </form>
   </table>
</body>
</html>
<!-- DESTRUCTOR ------->
<!--#include file="common/destructor.asp"-->