<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'           Update Unit Tets Accepted State
'               --- PROCESS FORM ---
'=====================================================
%>
<%
Option explicit
' Good idea to set when using redirect
Response.Expires = 0   ' always load the page, dont store
%>
<!--#include file="common/conf.asp"-->
<!--#include file="common/globals.asp"-->
<!--#include file="common/formating.asp"-->
<!--#include file="common/qstr.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/common_dbedit.asp"-->
<%
' Set rfile parameter. This is a return page after Login
Call objPMod.StoreParameter ( "rfile", "fixed_issues.asp" )
'------------ ACCESS CONTROL ------------------
%>
<!--#include file="_access_control_login.asp"-->
<!--#include file="_access_control_general.asp"-->
<!--#include file="_access_control_project.asp"-->
<%
'------------ Variable Definition -------------
Dim parPv_id
Dim parFRfixed
'------------ Constants Declaration -----------
'------------ Variable Init -------------------
parPv_id = QStrPar("pv_id")
parRtag_id = QStrPar("rtag_id")
parFRfixed = Request("FRfixed")
'----------------------------------------------
%>
<%
'-----------------------------------------------------------------------------------------------------------------------
Sub Update_Unit_Test_Accepted_State ( nPv_id, aTestIdList )
   Dim TestId, sReviewDate, nReviewedBy, sAccepted

   OraDatabase.Parameters.Add "PV_ID",       nPv_id,                  ORAPARM_INPUT, ORATYPE_NUMBER
   OraDatabase.Parameters.Add "REVIEW_DATE", EuroDate (Date),         ORAPARM_INPUT, ORATYPE_VARCHAR2
   OraDatabase.Parameters.Add "ACCEPTED_BY", objAccessControl.UserId, ORAPARM_INPUT, ORATYPE_NUMBER

   objEH.TryORA ( OraSession )
   On Error Resume Next

   For Each TestId In aTestIdList
      sReviewDate = "'"& EuroDate (Date) &"'"
      nReviewedBy = objAccessControl.UserId
      sAccepted = "'"& Request( "acc"& TestId ) &"'"
      'sReviewComments = NULL

      If sAccepted = "''" Then
         sReviewDate = "NULL"
         nReviewedBy = "NULL"
         sAccepted = "NULL"
      End If

      If Err.Number = 0 Then
         OraDatabase.ExecuteSQL _
         "BEGIN  Update_Unit_Test_Acceptance  ( "& TestId &","&_
         "                                     :PV_ID,"&_
         "                                    "& sAccepted &","&_
         "                                    "& sReviewDate &","&_
         "                                    "& nReviewedBy &","&_
         "                                     NULL,"&_
         "                                     'Y'"&_
         "                                    );  END;"
      End If

   Next

   objEH.CatchORA ( OraSession )

   OraDatabase.Parameters.Remove "PV_ID"
   OraDatabase.Parameters.Remove "REVIEW_DATE"
   OraDatabase.Parameters.Remove "ACCEPTED_BY"

End Sub
'-----------------------------------------------------------------------------------------------------------------------
Function GetUnitTestList ( nPv_id )
   Dim Query_String, oRS, arrTemp(), currDim
   Query_String = " SELECT ut.test_id  FROM UNIT_TESTS ut  WHERE ut.pv_id = "& nPv_id

   Set oRS = OraDatabase.CreateDynaset( Query_String, cint(0))

   currDim = 0
   While (NOT oRS.BOF) AND (NOT oRS.EOF)
      ReDim Preserve arrTemp( currDim )
      arrTemp ( currDim ) = oRS("test_id")

      currDim = currDim + 1
      oRS.MoveNext
   WEnd

   GetUnitTestList = arrTemp

   oRS.Close
   Set oRS = Nothing
End Function
'-----------------------------------------------------------------------------------------------------------------------
%>
<%
'-----------------------  MAIN LINE  ---------------------------
'--- Process submition ---
If (parPv_id <> "") AND (parRtag_id <> "")Then
   ' All mandatory parameters FOUND

   Call Update_Unit_Test_Accepted_State ( parPv_id, GetUnitTestList(parPv_id) )

   Call Destroy_All_Objects
   Response.Redirect("fixed_issues.asp?pv_id="& Request("pv_id") &"&rtag_id="& Request("rtag_id"))
Else
   Response.write "Some mandatory parameters are missing!" & "<br>" 'TODO
   Response.write QSTR_FullQuery
End If
%>
<!-- DESTRUCTOR ------->
<!--#include file="common/destructor.asp"-->