<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'|                                                   |
'|			          wEditBom					 	 |
'|                                                   |
'=====================================================
%>
<%
Option explicit
Response.Expires = 0
%>
<!--#include file="common/globals.asp"-->
<!--#include file="common/config.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/_popup_window_common.asp"-->
<%
'------------ ACCESS CONTROL ------------------
%>
<!--#include file="_access_control_general.asp"-->
<%
'------------ VARIABLE DEFINITION -------------
Dim objFormCollector
'------------ CONSTANTS DECLARATION -----------
'------------ VARIABLE INIT -------------------
Call GetMainDBParameters ( dbPARproj_id, dbPARbranch_id, dbPARbom_id, dbPARnode_id, dbPARos_id, dbPARprod_id )
parBom_id = Request("bom_id")
Set objFormCollector = CreateObject("Scripting.Dictionary")
'------------ CONDITIONS ----------------------
'----------------------------------------------
%>
<%
'--------------------------------------------------------------------------------------------------------------------------
Sub GetFormDetails ( nBomId, ByRef outobjDetails )
	
	Call GetBomDetails ( nBomId, outobjDetails )
	
	outobjDetails.Item("bom_full_version") = outobjDetails.Item("bom_version") &"."& outobjDetails.Item("bom_lifecycle")
	
End Sub
'--------------------------------------------------------------------------------------------------------------------------
Function GetDMReleaseList ( nRtagId, nProjId )
	Dim rsQry, query
	
	Set rsQry = OraDatabase.DbCreateDynaset( "select * from dm_projects where proj_id="&nProjId, ORADYN_DEFAULT )
	
	
	OraDatabase.Parameters.Add "BRANCH_ID", nRtagId,		ORAPARM_INPUT, ORATYPE_NUMBER 
	OraDatabase.Parameters.Add "PROJ_ID", rsQry("rm_projects_fk"),		ORAPARM_INPUT, ORATYPE_NUMBER 
	
	Set rsQry = OraDatabase.DbCreateDynaset( GetQuery ("DMReleasesCombo.sql"), ORADYN_DEFAULT )
	
	If rsQry.RecordCount > 0 Then
		GetDMReleaseList = rsQry.GetRows()
		
	Else
		GetDMReleaseList = NULL
		
	End If
	
	OraDatabase.Parameters.Remove "RTAG_ID"
	OraDatabase.Parameters.Remove "PROJ_ID"
	
	rsQry.Close
	Set rsQry = Nothing
End Function
'--------------------------------------------------------------------------------------------------------------------------
Sub UpdateBom ()
	On Error Resume Next
	
	OraDatabase.Parameters.Add "BOM_ID", 		Request("bom_id"), 			ORAPARM_INPUT, ORATYPE_NUMBER 
	OraDatabase.Parameters.Add "RTAG_ID", 		Request("rtag_id_fk"), 		ORAPARM_INPUT, ORATYPE_NUMBER 
	OraDatabase.Parameters.Add "BOM_COMMENTS",  Request("bom_comments"), 	ORAPARM_INPUT, ORATYPE_VARCHAR2
	OraDatabase.Parameters.Add "USER_ID", 		objAccessControl.UserId, 	ORAPARM_INPUT, ORATYPE_NUMBER 
	
	
	objEH.TryORA ( OraSession )
	
	OraDatabase.ExecuteSQL _
	"BEGIN pk_Bom.Update_ProdBom ( :BOM_ID, :RTAG_ID, :BOM_COMMENTS, :USER_ID ); END;"	
	
	objEH.CatchORA ( OraSession )
	
	
	OraDatabase.Parameters.Remove "BOM_ID"
	OraDatabase.Parameters.Remove "RTAG_ID"
	OraDatabase.Parameters.Remove "BOM_COMMENTS"
	OraDatabase.Parameters.Remove "USER_ID"
End Sub
'--------------------------------------------------------------------------------------------------------------------------
%>
<%
'------------ RUN BEFORE PAGE RENDER ----------
' --- Get Form details from DB ---
Call GetFormDetails ( parBom_id, objFormCollector )

' --- Load Validation Rules ---
Call objForm.LoadValidationRules ( Array("bom_comments"), OraDatabase )		' Load Validation Rules

' --- Enter Form Validation Rule Changes here... ----
'----------------------------------------------------

If CBool(Request("action")) Then
	If objForm.IsValidOnPostBack Then
		' --- Form is Valid ---
		Call UpdateBom()
		
		If objEH.Finally Then
			Call OpenInParentWindow ( Request("rfile") &"?DONE=OK"& objPMod.ComposeURLWithout("rfile") )
			Call CloseWindow()
		End If
		
	End If
End If

'----------------------------------------------
%>
<html>
<head>
<title>Deployment Manager</title>
<meta HTTP-EQUIV="Pragma" CONTENT="no-cache">
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
<link href="scripts/deployment_manager.css" rel="stylesheet" type="text/css">
<script language="JavaScript" src="scripts/common.js"></script>
</head>

<body background="images/bg_bage_0.gif" leftmargin="0" topmargin="0" onLoad="self.focus();FormName.bom_comments.focus();">
<table width="100%"  border="0" cellspacing="0" cellpadding="10">
  <tr>
    <td bgcolor="#FFFFFF" class="body_txt"><span class="body_h1"><img src="icons/i_linkarrow_black.gif" width="11" height="11" align="absmiddle">&nbsp;BOM</span> <br>
    Enter optional comments. 
    </td>
  </tr>
  <%
  '-- FROM START ---------------------------------------------------------------------------------------------------------
  objFormComponent.FormName = "FormName"
  objFormComponent.Action = SCRIPT_NAME
  objFormComponent.OnSubmit = "ShowProgress();"
  Call objFormComponent.FormStart()
  %> 
  <tr>
    <td background="images/bg_login.gif"><table width="100%"  border="0" cellspacing="0" cellpadding="0">
      <tr>
        <td><%=ProgressBar%></td>
        <td align="right"><input name="btn" type="submit" class="form_btn" value="Submit">
          <input name="btn" type="reset" class="form_btn" value="Cancel" onClick="self.close();"></td>
      </tr>
    </table></td>
  </tr>
  <tr>
    <td>
	<!-- MESSAGE +++++++++++++++++++++++++++++++++++++++++++++++++++ -->	
	<!--#include file="messages/_msg_inline.asp"-->
    <!-- +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->
	<table width="100%"  border="0" cellspacing="2" cellpadding="0">
      <tr>
        <td nowrap class="form_iname" valign="top">Bom Version </td>
        <td valign="top"><%=objFormComponent.TextBox ( "bom_full_version", objFormCollector.Item("bom_full_version"), "size='60' class='form_ivalue' disabled" )%></td>
		<td valign="top"></td>
      </tr>
	  <tr>
        <td nowrap class="form_iname" valign="top">Deployment Manager Reference</td>
        <td valign="top"><%=objFormComponent.Combo ( "rtag_id_fk", GetDMReleaseList( objForm.GetValue( "rtag_id_fk", objFormCollector.Item("rtag_id_fk") ), dbPARproj_id ), TRUE, "class='form_ivalue'" )%></td>
		<td valign="top"></td>
      </tr>
      <tr>
        <td valign="top" nowrap class="form_iname">Bom Comments</td>
        <td valign="top"><%=objFormComponent.TextArea ( "bom_comments", objForm.GetValue( "bom_comments", objFormCollector.Item("bom_comments") ), 10, 60, "class='form_ivalue'" )%></td>
		<td valign="top"><%=objForm.Validate ("bom_comments")%></td>
      </tr>
      <tr>
        <td width="10%" class="form_iname">&nbsp;</td>
        <td width="1%">&nbsp;</td>
		<td width="90%" class="val_err"></td>
      </tr>
    </table></td>
  </tr>
  <%=objPMod.ComposeHiddenTags()%>
  <input type="hidden" name="action" value="true">
  <%
  Call objFormComponent.FormEnd()
  '-- FROM END ----------------------------------------------------------------------------------------------------------------
  %>
</table>
</body>
</html>
<%
'------------ RUN AFTER PAGE RENDER -----------
Set objFormCollector = Nothing
'----------------------------------------------
%><!--#include file="common/globals_destructor.asp"-->