<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'|                                                   |
'|			   _SetUserOverridePermissions	 	 	 |
'|                                                   |
'=====================================================
%>
<%
Option explicit
Response.Expires = 0
%>
<!--#include file="common/globals.asp"-->
<!--#include file="common/config.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/_code_behind_common.asp"-->
<%
'------------ ACCESS CONTROL ------------------
%>
<!--#include file="_access_control_general.asp"-->
<%
'------------ VARIABLE DEFINITION -------------
'------------ CONSTANTS DECLARATION -----------
'------------ VARIABLE INIT -------------------
'------------ CONDITIONS ----------------------
'----------------------------------------------
%>
<%
'--------------------------------------------------------------------------------------------------------------------------
'   Process Form Data
'   Bulk of the data is of the form:
'       VIS_<OBJ_ID> <IS_VISIBLE>
'       ACT_<OBJ_ID> <IS_ACTIVE>
'
Sub SetRoleVariationPermissions ()
	Dim rsQry, query, aControlObjects, ObjId, OraParameter
	
	'On Error Resume Next
	
	OraDatabase.Parameters.Add "APP_ID", 	Request("app_id"), 		ORAPARM_INPUT, ORATYPE_NUMBER 
	OraDatabase.Parameters.Add "USER_ID", 	Request("user_id"), 	ORAPARM_INPUT, ORATYPE_NUMBER 
	OraDatabase.Parameters.Add "ROLE_ID", 	Request("role_id"), 	                ORAPARM_INPUT, ORATYPE_NUMBER 
	OraDatabase.Parameters.Add "OBJ_ID", 	NULL, 					ORAPARM_INPUT, ORATYPE_NUMBER 
	OraDatabase.Parameters.Add "IS_VISIBLE",NULL, 					ORAPARM_INPUT, ORATYPE_VARCHAR2
	OraDatabase.Parameters.Add "IS_ACTIVE", NULL, 					ORAPARM_INPUT, ORATYPE_VARCHAR2
	Set OraParameter = OraDatabase.Parameters
	
	'--- Get All Control Objects for this Application ---
	query = _
	" SELECT co.OBJ_ID"&_
	"   FROM CONTROL_OBJECTS co"&_
	"  WHERE co.APP_ID = :APP_ID"
	
	Set rsQry = OraDatabase.DbCreateDynaset( query , ORADYN_DEFAULT )
	aControlObjects = rsQry.GetRows()
	rsQry.Close
	Set rsQry = Nothing
	
	'--- Set Role Permissions ---
	On Error Resume Next
	objEH.TryORA ( OraSession )
		
		For Each ObjId In aControlObjects

			OraParameter("OBJ_ID").Value = CInt(ObjId)
			OraParameter("IS_VISIBLE").Value = Request( "VIS_" & ObjId )
			OraParameter("IS_ACTIVE").Value =  Request( "ACT_" & ObjId )
			
			OraDatabase.ExecuteSQL _
			"BEGIN   pk_Role.Set_Role_Variation_Permissions ( :USER_ID, :APP_ID, :ROLE_ID, :OBJ_ID, :IS_VISIBLE, :IS_ACTIVE );   END;"

		Next
		
	objEH.CatchORA ( OraSession )
	
	OraDatabase.Parameters.Remove "APP_ID"
	OraDatabase.Parameters.Remove "USER_ID"
	OraDatabase.Parameters.Remove "ROLE_ID"
	OraDatabase.Parameters.Remove "OBJ_ID"
	OraDatabase.Parameters.Remove "IS_VISIBLE"
	OraDatabase.Parameters.Remove "IS_ACTIVE"

End Sub
'--------------------------------------------------------------------------------------------------------------------------
%>
<%
'**************************** M  A  I  N ******************************
' --- Form is Valid ---
Call SetRoleVariationPermissions()

If objEH.Finally Then
	Call OpenInWindow ( Request("rfile") &"?"& objPMod.ComposeURL() )
End If
'**********************************************************************
%>
<%
'------------ RUN AFTER CODE RUN --------------
'----------------------------------------------
%><!--#include file="common/globals_destructor.asp"-->